[C#] ما هو NullReferenceException ، وكيف يمكنني إصلاحه؟


Answers

NullReference Exception - Visual Basic

لا يختلف NullReference Exception لـ Visual Basic عن واحد في C # . بعد كل شيء ، يتم الإعلام عن نفس الاستثناء المعرّف في .NET Framework الذي يستخدمه كلاهما. الأسباب فريد إلى Visual Basic نادرة (ربما واحد فقط).

تستخدم هذه الإجابة عبارات Visual Basic وصياغتها وسياقها. تأتي الأمثلة المستخدمة من عدد كبير من الأسئلة السابقة حول Stack Overflow. هذا هو تعظيم الصلة باستخدام أنواع المواقف التي غالباً ما يتم رؤيتها في المشاركات. يتم تقديم تفسير أكثر قليلاً أيضًا لأولئك الذين قد يحتاجون إليها. من المحتمل جدًا وجود مثال مشابه لك هنا.

ملحوظة:

  1. يعتمد هذا على المفهوم: لا يوجد رمز لك لصقه في مشروعك. الغرض منه هو مساعدتك على فهم أسباب NullReferenceException (NRE) وكيفية العثور عليها وكيفية إصلاحها وكيفية تجنبها. يمكن أن يكون سبب NRE العديد من الطرق لذلك فمن غير المحتمل أن يكون هذا اللقاء الوحيد الخاص بك.
  2. الأمثلة (من منشورات Stack Overflow) لا تعرض دائمًا أفضل طريقة لعمل شيء ما في المقام الأول.
  3. عادة ، يتم استخدام أبسط علاج.

المعنى الأساسي

تعني الرسالة "الكائن غير مضبوط على مثيل كائن" أنك تحاول استخدام كائن لم تتم تهيئته. هذا يتلخص في واحدة من هذه:

  • أعلنت التعليمة البرمجية الخاصة بك عن متغير كائن ، ولكنها لم تقم بتهيئته (إنشاء مثيل أو " إنشاء مثيل " له)
  • شيء ما افترض شفرتك تهيئة كائن ، لم يفعل ذلك
  • ربما ، رمز آخر يبطل قبل الأوان كائن ما زال قيد الاستخدام

العثور على السبب

نظرًا لأن المشكلة هي مرجع كائن Nothing ، فإن الإجابة هي فحصها لمعرفة أي منها. ثم حدد سبب عدم تهيئتها. أمسك الماوس فوق المتغيرات المختلفة وسيظهر Visual Studio (VS) قيمها - لن يكون السبب هو الجاني.

يجب عليك أيضًا إزالة أي كتل تجريبية / تلقائية من الشفرة ذات الصلة ، خصوصًا تلك التي لا يوجد بها شيء في كتلة Catch. سيؤدي ذلك إلى تعطل التعليمات البرمجية الخاصة بك عند محاولة استخدام كائن غير Nothing . هذا ما تريده لأنه يحدد الموقع الدقيق للمشكلة ، ويسمح لك بتحديد الكائن الذي يسببه.

MsgBox في Catch الذي يعرض Error while... سيكون من المساعدة قليلاً. تؤدي هذه الطريقة أيضًا إلى أسئلة Stack Overflow سيئة للغاية ، لأنه لا يمكنك وصف الاستثناء الفعلي أو الكائن المتضمن أو حتى سطر الشفرة حيث يحدث.

يمكنك أيضًا استخدام Locals Window ( Debug -> Windows -> Localals ) لفحص الكائنات الخاصة بك.

بمجرد معرفة ما وأين المشكلة ، يكون من السهل عادة إصلاحها وبسرعة أكبر من نشر سؤال جديد.

أنظر أيضا:

أمثلة وسبل الانتصاف

كائنات فئة / إنشاء مثيل

Dim reg As CashRegister
...
TextBox1.Text = reg.Amount         ' NRE

المشكلة هي أن Dim لا يقوم بإنشاء كائن CashRegister؛ يعلن فقط متغير يدعى reg من هذا النوع. يعتبر تعريف متغير كائن وإنشاء مثيل شيئين مختلفين.

علاج

يمكن استخدام عامل التشغيل New كثير من الأحيان لإنشاء المثيل عند التصريح به:

Dim reg As New CashRegister        ' [New] creates instance, invokes the constructor

' Longer, more explicit form:
Dim reg As CashRegister = New CashRegister

عندما يكون من المناسب فقط إنشاء المثيل لاحقًا:

Private reg As CashRegister         ' Declare
  ...
reg = New CashRegister()            ' Create instance

ملاحظة: لا تستخدم Dim مرة أخرى في الإجراء ، بما في ذلك المُنشئ ( Sub New ):

Private reg As CashRegister
'...

Public Sub New()
   '...
   Dim reg As New CashRegister
End Sub

سيؤدي ذلك إلى إنشاء متغير محلي ، reg ، موجود فقط في هذا السياق (sub). لا يزال متغير reg مع Scope المستوى الوحدة النمطية الذي ستستخدمه في أي مكان آخر لا Nothing .

يعتبر فقدان عامل التشغيل New هو سبب # 1 NullReference Exceptions رؤيتها في الأسئلة الخاصة بـ Stack Overflow التي تمت مراجعتها.

يحاول Visual Basic جعل العملية بشكل واضح مرارا وتكرارا باستخدام New : يؤدي استخدام New Operator إلى إنشاء كائن جديد واستدعاء Sub New - المنشئ - حيث يمكن للعنصر تنفيذ أي تهيئة أخرى.

لكي تكون واضحًا ، فإن Dim (أو Private ) فقط تعلن عن متغير Type . يتم تحديد نطاق المتغير - سواء كان موجودًا للوحدة / الفصل بالكامل أو محليًا لإجراء ما - حسب مكان الإعلان عنه. Private | Friend | Public يحدد Private | Friend | Public مستوى الوصول ، وليس النطاق .

لمزيد من المعلومات، راجع:

المصفوفات

يجب أيضًا إنشاء صفائف:

Private arr as String()

تم الإعلان عن هذه المجموعة فقط ، ولم يتم إنشاؤها. هناك عدة طرق لتهيئة مصفوفة:

Private arr as String() = New String(10){}
' or
Private arr() As String = New String(10){}

' For a local array (in a procedure) and using 'Option Infer':
Dim arr = New String(10) {}

ملاحظة: بدايةً من VS 2010 ، عند تهيئة صفيف محلي باستخدام حرفي و Option Infer ، تكون عناصر As <Type> و New اختيارية:

Dim myDbl As Double() = {1.5, 2, 9.9, 18, 3.14}
Dim myDbl = New Double() {1.5, 2, 9.9, 18, 3.14}
Dim myDbl() = {1.5, 2, 9.9, 18, 3.14}

يتم استنتاج نوع البيانات وحجم الصفيف من البيانات التي يتم تعيينها. لا تزال تصاريح مستوى الفئة / الوحدة النمطية تتطلب As <Type> مع Option Strict :

Private myDoubles As Double() = {1.5, 2, 9.9, 18, 3.14}

مثال: صفيف كائنات الفئة

Dim arrFoo(5) As Foo

For i As Integer = 0 To arrFoo.Count - 1
   arrFoo(i).Bar = i * 10       ' Exception
Next

لقد تم إنشاء المصفوفة ، لكن كائنات Foo لا تحتوي عليها.

علاج

For i As Integer = 0 To arrFoo.Count - 1
    arrFoo(i) = New Foo()         ' Create Foo instance
    arrFoo(i).Bar = i * 10
Next

استخدام List(Of T) سيجعل من الصعب الحصول على عنصر بدون كائن صالح:

Dim FooList As New List(Of Foo)     ' List created, but it is empty
Dim f As Foo                        ' Temporary variable for the loop

For i As Integer = 0 To 5
    f = New Foo()                    ' Foo instance created
    f.Bar =  i * 10
    FooList.Add(f)                   ' Foo object added to list
Next

لمزيد من المعلومات، راجع:

القوائم والمجموعات

يجب أيضًا إنشاء مجموعات .NET (التي يوجد بها العديد من الأنواع - القوائم والقاموس وما إلى ذلك) أو إنشاءها.

Private myList As List(Of String)
..
myList.Add("ziggy")           ' NullReference

تحصل على نفس الاستثناء لنفس السبب - تم الإعلان عن myList فقط ، ولكن لم يتم إنشاء مثيل. العلاج هو نفسه:

myList = New List(Of String)

' Or create an instance when declared:
Private myList As New List(Of String)

الإشراف العام هو فئة تستخدم Type المجموعة:

Public Class Foo
    Private barList As List(Of Bar)

    Friend Function BarCount As Integer
        Return barList.Count
    End Function

    Friend Sub AddItem(newBar As Bar)
        If barList.Contains(newBar) = False Then
            barList.Add(newBar)
        End If
    End Function

سينتج عن أي من الإجراءين NRE ، لأن barList يتم الإعلان عنه فقط ، ولا يتم إنشاء مثيل له. لن ينشئ إنشاء نسخة Foo أيضًا barList الداخلي. ربما كان هذا هو النية للقيام بذلك في المُنشئ:

Public Sub New         ' Constructor
    ' Stuff to do when a new Foo is created...
    barList = New List(Of Bar)
End Sub

كما كان من قبل ، هذا غير صحيح:

Public Sub New()
    ' Creates another barList local to this procedure
     Dim barList As New List(Of Bar)
End Sub

لمزيد من المعلومات ، انظر List(Of T) فئة .

كائنات موفر البيانات

يوفر العمل مع قواعد البيانات العديد من الفرص لـ NullReference لأنه يمكن أن يكون هناك العديد من الكائنات (أمر ، Connection ، Transaction ، Dataset ، DataTable ، DataRows ....) قيد الاستخدام في وقت واحد. ملاحظة: لا يهم موفر البيانات الذي تستخدمه - MySQL و SQL Server و OleDB وما إلى ذلك - المفاهيم هي نفسها.

مثال 1

Dim da As OleDbDataAdapter
Dim ds As DataSet
Dim MaxRows As Integer

con.Open()
Dim sql = "SELECT * FROM tblfoobar_List"
da = New OleDbDataAdapter(sql, con)
da.Fill(ds, "foobar")
con.Close()

MaxRows = ds.Tables("foobar").Rows.Count      ' Error

كما كان من قبل ، تم الإعلان عن كائن Dsaset ds ، ولكن لم يتم إنشاء مثيل. سيقوم DataAdapter بتعبئة DataSet موجودة ، وليس إنشاء واحد. في هذه الحالة ، نظرًا لأن ds هو متغير محلي ، يحذرك IDE من احتمال حدوث ذلك:

عندما يتم تعريفه كمتغير مستوى وحدة نمطية / فئة ، كما يبدو أن الحالة مع con ، لا يستطيع المحول البرمجي معرفة ما إذا كان الكائن قد تم إنشاؤه بواسطة إجراء ما قبل المنبع. لا تتجاهل التحذيرات.

علاج

Dim ds As New DataSet

مثال 2

ds = New DataSet
da = New OleDBDataAdapter(sql, con)
da.Fill(ds, "Employees")

txtID.Text = ds.Tables("Employee").Rows(0).Item(1)
txtID.Name = ds.Tables("Employee").Rows(0).Item(2)

الخطأ المطبعي هو مشكلة هنا: Employees مقابل Employee . لم يكن هناك DataTable المسمى "الموظف" الذي تم إنشاؤه ، لذلك نتائج NullReferenceException تحاول الوصول إليه. هناك مشكلة محتملة أخرى هي افتراض وجود Items قد لا تكون كذلك عندما يتضمن SQL جملة WHERE.

علاج

بما أن هذا يستخدم جدول واحد ، فإن استخدام Tables(0) سوف يتجنب الأخطاء الإملائية. يمكن أن يساعد اختبار Rows.Count أيضًا على:

If ds.Tables(0).Rows.Count > 0 Then
    txtID.Text = ds.Tables(0).Rows(0).Item(1)
    txtID.Name = ds.Tables(0).Rows(0).Item(2)
End If

Fill هي دالة تعيد عدد Rows المتأثرة التي يمكن اختبارها أيضًا:

If da.Fill(ds, "Employees") > 0 Then...

مثال 3

Dim da As New OleDb.OleDbDataAdapter("SELECT TICKET.TICKET_NO,
        TICKET.CUSTOMER_ID, ... FROM TICKET_RESERVATION AS TICKET INNER JOIN
        FLIGHT_DETAILS AS FLIGHT ... WHERE [TICKET.TICKET_NO]= ...", con)
Dim ds As New DataSet
da.Fill(ds)

If ds.Tables("TICKET_RESERVATION").Rows.Count > 0 Then

سيوفر DataAdapter TableNames كما هو موضح في المثال السابق ، ولكنه لا يقوم بتحليل الأسماء من جدول SQL أو قاعدة البيانات. نتيجة لذلك ، تشير ds.Tables("TICKET_RESERVATION") إلى جدول غير موجود.

العلاج هو نفسه ، الرجوع إلى الجدول حسب الفهرس:

If ds.Tables(0).Rows.Count > 0 Then

انظر أيضا فئة DataTable .

مسارات الكائن / متداخل

If myFoo.Bar.Items IsNot Nothing Then
   ...

الرمز هو اختبار Items فقط بينما قد يكون كل من myFoo و Bar myFoo كذلك. يتمثل الحل في اختبار السلسلة بأكملها أو مسار الكائنات في وقت واحد:

If (myFoo IsNot Nothing) AndAlso
    (myFoo.Bar IsNot Nothing) AndAlso
    (myFoo.Bar.Items IsNot Nothing) Then
    ....

AndAlso مهم. لن يتم تنفيذ الاختبارات اللاحقة بمجرد مواجهة أول حالة False . هذا يسمح للشفرة بأمان 'الحفر' في الكائن (الكائنات) واحد 'المستوى' في كل مرة ، تقييم myFoo.Bar فقط بعد (وإذا) تم تحديد myFoo لتكون صالحة. يمكن أن تحصل سلاسل أو مسارات الكائنات على وقت طويل عند ترميز كائنات معقدة:

myBase.myNodes(3).Layer.SubLayer.Foo.Files.Add("somefilename")

ليس من الممكن الإشارة إلى أي شيء 'في اتجاه مجرى النهر' من كائن null . ينطبق هذا أيضًا على عناصر التحكم:

myWebBrowser.Document.GetElementById("formfld1").InnerText = "some value"

هنا ، قد يكون myWebBrowser أو Document لا شيء أو قد لا يتواجد العنصر formfld1 .

ضوابط واجهة المستخدم

Dim cmd5 As New SqlCommand("select Cartons, Pieces, Foobar " _
     & "FROM Invoice where invoice_no = '" & _
     Me.ComboBox5.SelectedItem.ToString.Trim & "' And category = '" & _
     Me.ListBox1.SelectedItem.ToString.Trim & "' And item_name = '" & _
     Me.ComboBox2.SelectedValue.ToString.Trim & "' And expiry_date = '" & _
     Me.expiry.Text & "'", con)

من بين أشياء أخرى ، لا يتوقع هذا الرمز أن المستخدم ربما لم يختار شيئًا في عنصر تحكم واحد أو أكثر من عناصر واجهة المستخدم. ListBox1.SelectedItem قد يكون جيدا Nothing ، لذلك سوف ListBox1.SelectedItem.ToString سيؤدي إلى NRE.

علاج

التحقق من صحة البيانات قبل استخدامها (أيضًا استخدام معلمات Option Strict و SQL):

Dim expiry As DateTime         ' for text date validation
If (ComboBox5.SelectedItems.Count > 0) AndAlso
    (ListBox1.SelectedItems.Count > 0) AndAlso
    (ComboBox2.SelectedItems.Count > 0) AndAlso
    (DateTime.TryParse(expiry.Text, expiry) Then

    '... do stuff
Else
    MessageBox.Show(...error message...)
End If

بدلا من ذلك ، يمكنك استخدام (ComboBox5.SelectedItem IsNot Nothing) AndAlso...

نماذج بصرية أساسية

Public Class Form1

    Private NameBoxes = New TextBox(5) {Controls("TextBox1"), _
                   Controls("TextBox2"), Controls("TextBox3"), _
                   Controls("TextBox4"), Controls("TextBox5"), _
                   Controls("TextBox6")}

    ' same thing in a different format:
    Private boxList As New List(Of TextBox) From {TextBox1, TextBox2, TextBox3 ...}

    ' Immediate NRE:
    Private somevar As String = Me.Controls("TextBox1").Text

هذه طريقة شائعة للحصول على NRE. في C # ، اعتماداً على كيف يتم ترميزه ، سيقوم IDE بالإبلاغ عن وجود Controls غير موجودة في السياق الحالي ، أو "لا يمكن الرجوع إلى عضو غير ثابت". لذلك ، إلى حد ما ، هذا وضع VB فقط. كما أنه معقد لأنه يمكن أن يؤدي إلى تتالي فشل.

لا يمكن تهيئة المصفوفات والمجموعات بهذه الطريقة. سيتم تشغيل رمز التهيئة هذا قبل إنشاء منشئ Form أو Controls . كنتيجة لــ:

  • القوائم والمجموعة ستكون فارغة
  • سيحتوي Array خمسة عناصر Nothing
  • somevar التعيين somevar NRE مباشرة لأنه لا يوجد شيء خاصية .Text

الإشارة إلى مجموعة عناصر في وقت لاحق سيؤدي إلى NRE. إذا قمت بذلك في Form_Load ، بسبب خطأ فردي ، قد لا IDE تقرير الاستثناء عند حدوثه. ستظهر الاستثناءات لاحقًا عندما تحاول التعليمة البرمجية الخاصة بك استخدام الصفيف. تم توضيح هذا "الاستثناء الصامت" في هذا المنشور . لأغراضنا ، المفتاح هو أنه عندما يحدث شيء كارثي أثناء إنشاء نموذج (حدث Sub New أو Form Load ) ، قد لا يتم الإبلاغ عن الاستثناءات ، يخرج الرمز من الإجراء ويعرض النموذج فقط.

نظرًا لأنه لن يتم تشغيل أي رمز آخر في الحدث Sub New أو Form Load بعد NRE ، فيمكن ترك الكثير من الأشياء الأخرى غير مهيأة.

Sub Form_Load(..._
   '...
   Dim name As String = NameBoxes(2).Text        ' NRE
   ' ...
   ' More code (which will likely not be executed)
   ' ...
End Sub

لاحظ أن هذا ينطبق على أي وجميع عناصر التحكم والمكونات التي تجعلها غير قانونية في مكانها:

Public Class Form1

    Private myFiles() As String = Me.OpenFileDialog1.FileName & ...
    Private dbcon As String = OpenFileDialog1.FileName & ";Jet Oledb..."
    Private studentName As String = TextBox13.Text

علاج جزئي

من الغريب أن VB لا يوفر تحذيراً ، ولكن العلاج هو الإعلان عن الحاويات على مستوى النموذج ، ولكن قم بتهيئتها في معالج أحداث تحميل النموذج عند وجود عناصر التحكم. يمكن القيام بذلك في Sub New طالما أن التعليمات البرمجية الخاصة بك بعد استدعاء InitializeComponent :

' Module level declaration
Private NameBoxes as TextBox()
Private studentName As String

' Form Load, Form Shown or Sub New:
'
' Using the OP's approach (illegal using OPTION STRICT)
NameBoxes = New TextBox() {Me.Controls("TextBox1"), Me.Controls("TestBox2"), ...)
studentName = TextBox32.Text           ' For simple control references

قد لا يكون رمز المصفوفة خارج الغابة بعد. لن يتم العثور على أي عناصر تحكم موجودة في عنصر تحكم حاوية (مثل GroupBox أو Panel ) في Me.Controls ؛ سيكونون في مجموعة عناصر التحكم الخاصة بهذه اللوحة أو GroupBox. ولن يتم إرجاع عنصر تحكم عندما يكون خطأ في اسم عنصر التحكم ( "TeStBox2" ). في مثل هذه الحالات ، لن يتم تخزين Nothing مرة أخرى في عناصر الصفيف هذه وستحدث نتيجة NRE عندما تحاول الرجوع إليها.

من المفترض أن يكون من السهل العثور على هذه الميزات الآن لمعرفة ما الذي تبحث عنه:

"Button2" يتواجد على Panel

علاج

بدلاً من المراجع غير المباشرة بالاسم باستخدام مجموعة Controls بالنموذج ، استخدم مرجع التحكم:

' Declaration
Private NameBoxes As TextBox()

' Initialization -  simple and easy to read, hard to botch:
NameBoxes = New TextBox() {TextBox1, TextBox2, ...)

' Initialize a List
NamesList = New List(Of TextBox)({TextBox1, TextBox2, TextBox3...})
' or
NamesList = New List(Of TextBox)
NamesList.AddRange({TextBox1, TextBox2, TextBox3...})

وظيفة العودة لا شيء

Private bars As New List(Of Bars)        ' Declared and created

Public Function BarList() As List(Of Bars)
    bars.Clear
    If someCondition Then
        For n As Integer = 0 to someValue
            bars.Add(GetBar(n))
        Next n
    Else
        Exit Function
    End If

    Return bars
End Function

هذه حالة حيث سيقوم IDE بتحذيرك من " عدم إرجاع كافة المسارات لقيمة وقد ينتج عن NullReferenceException ". يمكنك منع التحذير ، عن طريق استبدال Exit Function بـ Return Nothing ، لكن ذلك لا يحل المشكلة. أي شيء يحاول استخدام الإرجاع عند someCondition = False في NRE:

bList = myFoo.BarList()
For Each b As Bar in bList      ' EXCEPTION
      ...

علاج

استبدل Exit Function في الوظيفة باستخدام Return bList . لا يعد إرجاع List فارغة نفس إرجاع Nothing . إذا كان هناك احتمال بأن يكون الكائن المرتجع لا Nothing ، فاختبره قبل استخدامه:

 bList = myFoo.BarList()
 If bList IsNot Nothing Then...

سيئة المنفذة محاولة / الصيد

يمكن أن يؤدي تطبيق Try / Catch الذي تم تنفيذه بشكل سيئ إلى إخفاء مكان المشكلة والنتيجة الجديدة:

Dim dr As SqlDataReader
Try
    Dim lnk As LinkButton = TryCast(sender, LinkButton)
    Dim gr As GridViewRow = DirectCast(lnk.NamingContainer, GridViewRow)
    Dim eid As String = GridView1.DataKeys(gr.RowIndex).Value.ToString()
    ViewState("username") = eid
    sqlQry = "select FirstName, Surname, DepartmentName, ExtensionName, jobTitle,
             Pager, mailaddress, from employees1 where username='" & eid & "'"
    If connection.State <> ConnectionState.Open Then
        connection.Open()
    End If
    command = New SqlCommand(sqlQry, connection)

    'More code fooing and barring

    dr = command.ExecuteReader()
    If dr.Read() Then
        lblFirstName.Text = Convert.ToString(dr("FirstName"))
        ...
    End If
    mpe.Show()
Catch

Finally
    command.Dispose()
    dr.Close()             ' <-- NRE
    connection.Close()
End Try

This is a case of an object not being created as expected, but also demonstrates the counter usefulness of an empty Catch .

There is an extra comma in the SQL (after 'mailaddress') which results in an exception at .ExecuteReader . After the Catch does nothing, Finally tries to perform clean up, but since you cannot Close a null DataReader object, a brand new NullReferenceException results.

An empty Catch block is the devil's playground. This OP was baffled why he was getting an NRE in the Finally block. In other situations, an empty Catch may result in something else much further downstream going haywire and cause you to spend time looking at the wrong things in the wrong place for the problem. (The "silent exception" described above provides the same entertainment value.)

Remedy

Don't use empty Try/Catch blocks - let the code crash so you can a) identify the cause b) identify the location and c) apply a proper remedy. Try/Catch blocks are not intended to hide exceptions from the person uniquely qualified to fix them - the developer.

DBNull is not the same as Nothing

For Each row As DataGridViewRow In dgvPlanning.Rows
    If Not IsDBNull(row.Cells(0).Value) Then
        ...

The IsDBNull function is used to test if a value equals System.DBNull : From MSDN:

The System.DBNull value indicates that the Object represents missing or non-existent data. DBNull is not the same as Nothing, which indicates that a variable has not yet been initialized.

Remedy

If row.Cells(0) IsNot Nothing Then ...

As before, you can test for Nothing, then for a specific value:

If (row.Cells(0) IsNot Nothing) AndAlso (IsDBNull(row.Cells(0).Value) = False) Then

مثال 2

Dim getFoo = (From f In dbContext.FooBars
               Where f.something = something
               Select f).FirstOrDefault

If Not IsDBNull(getFoo) Then
    If IsDBNull(getFoo.user_id) Then
        txtFirst.Text = getFoo.first_name
    Else
       ...

FirstOrDefault returns the first item or the default value, which is Nothing for reference types and never DBNull :

If getFoo IsNot Nothing Then...

Controls

Dim chk As CheckBox

chk = CType(Me.Controls(chkName), CheckBox)
If chk.Checked Then
    Return chk
End If

If a CheckBox with chkName can't be found (or exists in a GroupBox ), then chk will be Nothing and be attempting to reference any property will result in an exception.

Remedy

If (chk IsNot Nothing) AndAlso (chk.Checked) Then ...

The DataGridView

The DGV has a few quirks seen periodically:

dgvBooks.DataSource = loan.Books
dgvBooks.Columns("ISBN").Visible = True       ' NullReferenceException
dgvBooks.Columns("Title").DefaultCellStyle.Format = "C"
dgvBooks.Columns("Author").DefaultCellStyle.Format = "C"
dgvBooks.Columns("Price").DefaultCellStyle.Format = "C"

If dgvBooks has AutoGenerateColumns = True , it will create the columns, but it does not name them, so the above code fails when it references them by name.

Remedy

Name the columns manually, or reference by index:

dgvBooks.Columns(0).Visible = True

Example 2 — Beware of the NewRow

xlWorkSheet = xlWorkBook.Sheets("sheet1")

For i = 0 To myDGV.RowCount - 1
    For j = 0 To myDGV.ColumnCount - 1
        For k As Integer = 1 To myDGV.Columns.Count
            xlWorkSheet.Cells(1, k) = myDGV.Columns(k - 1).HeaderText
            xlWorkSheet.Cells(i + 2, j + 1) = myDGV(j, i).Value.ToString()
        Next
    Next
Next

When your DataGridView has AllowUserToAddRows as True (the default), the Cells in the blank/new row at the bottom will all contain Nothing . Most attempts to use the contents (for example, ToString ) will result in an NRE.

Remedy

Use a For/Each loop and test the IsNewRow property to determine if it is that last row. This works whether AllowUserToAddRows is true or not:

For Each r As DataGridViewRow in myDGV.Rows
    If r.IsNewRow = False Then
         ' ok to use this row

If you do use a For n loop, modify the row count or use Exit For when IsNewRow is true.

My.Settings (StringCollection)

Under certain circumstances, trying to use an item from My.Settings which is a StringCollection can result in a NullReference the first time you use it. The solution is the same, but not as obvious. يعتبر:

My.Settings.FooBars.Add("ziggy")         ' foobars is a string collection

Since VB is managing Settings for you, it is reasonable to expect it to initialize the collection. It will, but only if you have previously added an initial entry to the collection (in the Settings editor). Since the collection is (apparently) initialized when an item is added, it remains Nothing when there are no items in the Settings editor to add.

Remedy

Initialize the settings collection in the form's Load event handler, if/when needed:

If My.Settings.FooBars Is Nothing Then
    My.Settings.FooBars = New System.Collections.Specialized.StringCollection
End If

Typically, the Settings collection will only need to be initialized the first time the application runs. An alternate remedy is to add an initial value to your collection in Project -> Settings | FooBars , save the project, then remove the fake value.

Key Points

You probably forgot the New operator.

أو

Something you assumed would perform flawlessly to return an initialized object to your code, did not.

Don't ignore compiler warnings (ever) and use Option Strict On (always).

MSDN NullReference Exception

Question

لدي بعض التعليمات البرمجية وعندما يتم تنفيذها ، يتم طرح NullReferenceException قائلاً:

مرجع كائن لم يتم تعيين إلى مثيل كائن.

ماذا يعني هذا ، وماذا يمكنني فعله لإصلاح هذا الخطأ؟




On the matter of "what should I do about it" , there can be many answers.

A more "formal" way of preventing such error conditions while developing is applying design by contract in your code. This means you need to set class invariants , and/or even function/method preconditions and postconditions on your system, while developing.

In short, class invariants ensure that there will be some constraints in your class that will not get violated in normal use (and therefore, the class will not get in an inconsistent state). Preconditions mean that data given as input to a function/method must follow some constraints set and never violate them, and postconditions mean that a function/method output must follow the set constraints again without ever violating them. Contract conditions should never be violated during execution of a bug-free program, therefore design by contract is checked in practice in debug mode, while being disabled in releases , to maximize the developed system performance.

This way, you can avoid NullReferenceException cases that are results of violation of the constraints set. For example, if you use an object property X in a class and later try to invoke one of its methods and X has a null value, then this will lead to NullReferenceException :

public X { get; set; }

public void InvokeX()
{
    X.DoSomething(); // if X value is null, you will get a NullReferenceException
}

But if you set "property X must never have a null value" as method precondition, then you can prevent the scenario described before:

//Using code contracts:
[ContractInvariantMethod]
protected void ObjectInvariant () 
{
    Contract.Invariant ( X != null );
    //...
}

For this cause, Code Contracts project exists for .NET applications.

Alternatively, design by contract can be applied using assertions .

UPDATE: It is worth mentioning that the term was coined by Bertrand Meyer in connection with his design of the Eiffel programming language .




It means that the variable in question is pointed at nothing. I could generate this like so:

SqlConnection connection = null;
connection.Open();

That will throw the error because while I've declared the variable " connection ", it's not pointed to anything. When I try to call the member " Open ", there's no reference for it to resolve, and it will throw the error.

To avoid this error:

  1. Always initialize your objects before you try to do anything with them.
  2. If you're not sure whether the object is null, check it with object == null .

JetBrains' Resharper tool will identify every place in your code that has the possibility of a null reference error, allowing you to put in a null check. This error is the number one source of bugs, IMHO.




Reference types default to null to indicate that they are not referencing any object. Hence, if you try and access the object that is being referenced and there isn't one, you will get a NullReferenceException .

For Ex:

SqlConnection connection = null;
connection.Open();

When you run this code, you will get :

System.NullReferenceException: Object reference not set to an instance of an object.

You can avoid this error by coding like this:

if (connection != null){
    connection.Open();
}

Note: In order to avoid this error you should always initialize your objects before you try to do anything with them.




Interestingly, none of the answers on this page mention the two edge cases, hope no one minds if I add them:

Edge case #1: concurrent access to a Dictionary

Generic dictionaries in .NET are not thread-safe and they sometimes might throw a NullReference or even (more frequent) a KeyNotFoundException when you try to access a key from two concurrent threads. The exception is quite misleading in this case.

Edge case #2: unsafe code

If a NullReferenceException is thrown by unsafe code, you might look at your pointer variables, and check them for IntPtr.Zero or something. Which is the same thing ("null pointer exception"), but in unsafe code, variables are often cast to value-types/arrays, etc., and you bang your head against the wall, wondering how a value-type can throw this exception.

(Another reason for non-using unsafe code unless you need it, by the way)




You can fix NullReferenceException in a clean way using Null-conditional Operators in c#6 and write less code to handle null checks.

It's used to test for null before performing a member access (?.) or index (?[) operation.

مثال

  var name = p?.Spouse?.FirstName;

ما يعادل:

    if (p != null)
    {
        if (p.Spouse != null)
        {
            name = p.Spouse.FirstName;
        }
    }

The result is that the name will be null when p is null or when p.Spouse is null.

Otherwise, the variable name will be assigned the value of the p.Spouse.FirstName.

For More details : Null-conditional Operators




Be aware that regardless of the scenario, the cause is always the same in .NET:

You are trying to use a reference variable whose value is Nothing / null . When the value is Nothing / null for the reference variable, that means it is not actually holding a reference to an instance of any object that exists on the heap.

You either never assigned something to the variable, never created an instance of the value assigned to the variable, or you set the variable equal to Nothing / null manually, or you called a function that set the variable to Nothing / null for you.




TL;DR: Try using Html.Partial instead of Renderpage

I was getting Object reference not set to an instance of an object when I tried to render a View within a View by sending it a Model, like this:

@{
    MyEntity M = new MyEntity();
}
@RenderPage("_MyOtherView.cshtml", M); // error in _MyOtherView, the Model was Null

Debugging showed the model was Null inside MyOtherView. Until I changed it to:

@{
    MyEntity M = new MyEntity();
}
@Html.Partial("_MyOtherView.cshtml", M);

وعملت.

Furthermore, the reason I didn't have Html.Partial to begin with was because Visual Studio sometimes throws error-looking squiggly lines under Html.Partial if it's inside a differently constructed foreach loop, even though it's not really an error:

@inherits System.Web.Mvc.WebViewPage
@{
    ViewBag.Title = "Entity Index";
    List<MyEntity> MyEntities = new List<MyEntity>();
    MyEntities.Add(new MyEntity());
    MyEntities.Add(new MyEntity());
    MyEntities.Add(new MyEntity());
}
<div>
    @{
        foreach(var M in MyEntities)
        {
            // Squiggly lines below. Hovering says: cannot convert method group 'partial' to non-delegate type Object, did you intend to envoke the Method?
            @Html.Partial("MyOtherView.cshtml");
        }
    }
</div>

But I was able to run the application with no problems with this "error". I was able to get rid of the error by changing the structure of the foreach loop to look like this:

@foreach(var M in MyEntities){
    ...
}

Although I have a feeling it was because Visual Studio was misreading the ampersands and brackets.




You are using the object that contains the null value reference. So it's giving a null exception. In the example the string value is null and when checking its length, the exception occurred.

مثال:

string value = null;
if (value.Length == 0) // <-- Causes exception
{
    Console.WriteLine(value); // <-- Never reached
}

The exception error is:

Unhandled Exception:

System.NullReferenceException: Object reference not set to an instance of an object. at Program.Main()




Another general case where one might receive this exception involves mocking classes during unit testing. Regardless of the mocking framework being used, you must ensure that all appropriate levels of the class hierarchy are properly mocked. In particular, all properties of HttpContext which are referenced by the code under test must be mocked.

See " NullReferenceException thrown when testing custom AuthorizationAttribute " for a somewhat verbose example.




Literally the easiest way to fix a NullReferenceExeption has two ways. If you have a GameObject for example with a script attached and a variable named rb (rigidbody) this variable will start null when you start your game.
This is why you get a NullReferenceExeption because the computer does not have data stored in that variable.

I'll be using a RigidBody variable as an example.
We can add data really easily actually in a few ways:

  1. Add a RigidBody to your object with AddComponent > Physics > Rigidbody
    Then go into your script and type rb = GetComponent<Rigidbody>();
    This line of code works best under your Start() or Awake() functions.
  2. يمكنك إضافة مكون برمجيًا وتعيين المتغير في نفس الوقت مع سطر واحد من التعليمات البرمجية: rb = AddComponent<RigidBody>();

ملاحظات إضافية: إذا كنت تريد الوحدة لإضافة مكون إلى الكائن الخاص بك وكنت قد نسيت أن تضيف أحد ، يمكنك الكتابة [RequireComponent(typeof(RigidBody))]فوق تعريف الفصل (المساحة تحت كل استخداماتك).
استمتع واستمتع بالألعاب!




If you have not initialized a reference type, and you want to set or read one of its properties, it will throw a NullReferenceException .

مثال:

Person p = null;
p.Name = "Harry"; // NullReferenceException occurs here.

You can simply avoid this by checking if the variable is not null:

Person p = null;
if (p!=null)
{
    p.Name = "Harry"; // Not going to run to this point
}

To fully understand why a NullReferenceException is thrown, it is important to know the difference between value types and reference types .

So, if you're dealing with value types , NullReferenceExceptions can not occur. Though you need to keep alert when dealing with reference types !

Only reference types, as the name is suggesting, can hold references or point literally to nothing (or 'null'). Whereas value types always contain a value.

Reference types (these ones must be checked):

  • dynamic
  • موضوع
  • خيط

Value types (you can simply ignore these ones):

  • Numeric types
  • Integral types
  • Floating-point types
  • decimal
  • منطقي
  • User defined structs



While what causes a NullReferenceExceptions and approaches to avoid/fix such an exception have been addressed in other answers, what many programmers haven't learned yet is how to independently debug such exceptions during development.

In Visual Studio this is usually easy thanks to the Visual Studio Debugger .

First, make sure that the correct error is going to be caught - see How do I allow breaking on 'System.NullReferenceException' in VS2010? Note 1

Then either Start with Debugging (F5) or Attach [the VS Debugger] to Running Process . On occasion it may be useful to use Debugger.Break , which will prompt to launch the debugger.

Now, when the NullReferenceException is thrown (or unhandled) the debugger will stop (remember the rule set above?) on the line on which the exception occurred. Sometimes the error will be easy to spot.

For instance, in the following line the only code that can cause the exception is if myString evaluates to null. This can be verified by looking at the Watch Window or running expressions in the Immediate Window .

var x = myString.Trim();

In more advanced cases, such as the following, you'll need to use one of the techniques above (Watch or Immediate Windows) to inspect the expressions to determine if str1 was null or if str2 was null.

var x = str1.Trim() + str2.Trim();

Once where the exception is throw has been located, it's usually trivial to reason backwards to find out where the null value was [incorrectly] introduced --

Take the time required to understand the cause of the exception. Inspect for null expressions. Inspect the previous expressions which could have resulted in such null expressions. Add breakpoints and step through the program as appropriate. Use the debugger.

1 If Break on Throws is too aggressive and the debugger stops on an NPE in the .NET or 3rd-party library, Break on User-Unhandled can be used to limit the exceptions caught. Additionally, VS2012 introduces Just My Code which I recommend enabling as well.

If you are debugging with Just My Code enabled, the behavior is slightly different. With Just My Code enabled, the debugger ignores first-chance common language runtime (CLR) exceptions that are thrown outside of My Code and do not pass through My Code




Well, in simple terms:

You are trying to access an object that isn't created or currently not in memory.

So how to tackle this:

  1. Debug and let the debugger break... It will directly take you to the variable that is broken... Now your task is to simply fix this.. Using the new keyword in the appropriate place.

  2. If it is caused on some database commands because the object isn't present then all you need to do is do a null check and handle it:

    if (i == null) {
        // Handle this
    }
    
  3. The hardest one .. if the GC collected the object already... This generally occurs if you are trying to find an object using strings... That is, finding it by name of the object then it may happen that the GC might already cleaned it up... This is hard to find and will become quite a problem... A better way to tackle this is do null checks wherever necessary during the development process. This will save you a lot of time.

By finding by name I mean some framework allow you to FIndObjects using strings and the code might look like this: FindObject("ObjectName");




If one is getting this message during saving or compiling the build, just close all the files and then open any file to compile and save.

For me the reason was that I had rename the file and old file was still open.