[excel] VBA का उपयोग कर फ़ोल्डर में फ़ाइलों के माध्यम से लूप?


Answers

Dir जंगली कार्ड लेता है ताकि आप test अप फ्रंट के लिए फ़िल्टर जोड़ने और प्रत्येक फ़ाइल का परीक्षण करने से बचने में एक बड़ा अंतर डाल सकें

Sub LoopThroughFiles()
    Dim StrFile As String
    StrFile = Dir("c:\testfolder\*test*")
    Do While Len(StrFile) > 0
        Debug.Print StrFile
        StrFile = Dir
    Loop
End Sub
Question

मैं Excel 2010 में vba का उपयोग कर निर्देशिका की फ़ाइलों के माध्यम से लूप करना चाहता हूं।

लूप में, मुझे इसकी आवश्यकता होगी

  • फ़ाइल नाम, और
  • जिस तारीख को फ़ाइल स्वरूपित किया गया था।

मैंने निम्नलिखित कोडों को कोड किया है जो फ़ोल्डर में 50 से अधिक फाइलें नहीं हैं, अन्यथा यह हास्यास्पद रूप से धीमा है (मुझे इसे 10000 फाइलों के साथ फ़ोल्डर के साथ काम करने की आवश्यकता है)। इस कोड की एकमात्र समस्या यह है कि file.name को देखने के लिए ऑपरेशन बहुत अधिक समय लेता है।

कोड जो काम करता है लेकिन waaaaayay बहुत धीमा है (प्रति 100 फाइलों में 15 सेकंड):


Sub LoopThroughFiles()
   Dim MyObj As Object, MySource As Object, file As Variant
   Set MySource = MyObj.GetFolder("c:\testfolder\")
   For Each file In MySource.Files
      If InStr(file.name, "test") > 0 Then
         MsgBox "found"
         Exit Sub
      End If
   Next file
End Sub

समस्या सुलझ गयी:

  1. मेरी समस्या को किसी विशेष तरीके से Dir (15000 फ़ाइलों के लिए 20 सेकंड) का उपयोग करके नीचे दिए गए समाधान द्वारा हल किया गया है और FileDateTime का उपयोग करके टाइम स्टैंप की जांच के लिए।
  2. खाते में 20 सेकंड के नीचे से एक और जवाब लेना 1 सेकंड से भी कम हो गया है।



Dir फ़ंक्शन जाने का तरीका है, लेकिन समस्या यह है कि आप नीचे की ओर , जैसा कि यहां बताया गया है, आप Dir फ़ंक्शन का पुन: उपयोग नहीं कर सकते

जिस तरीके से मैंने इसे संभाला है, वह लक्ष्य फ़ोल्डर के लिए सभी उप-फ़ोल्डर प्राप्त करने के लिए Dir फ़ंक्शन का उपयोग करना है और उन्हें सरणी में लोड करना है, फिर सरणी को उस फ़ंक्शन में पास करना है जो रिकर्स करता है।

यहां एक वर्ग है जिसे मैंने लिखा है जो इसे पूरा करता है, इसमें फ़िल्टर खोजने की क्षमता शामिल है। ( आपको हंगेरियन नोटेशन को माफ करना होगा, यह लिखा गया था जब यह सभी क्रोध था। )

Private m_asFilters() As String
Private m_asFiles As Variant
Private m_lNext As Long
Private m_lMax As Long

Public Function GetFileList(ByVal ParentDir As String, Optional ByVal sSearch As String, Optional ByVal Deep As Boolean = True) As Variant
    m_lNext = 0
    m_lMax = 0

    ReDim m_asFiles(0)
    If Len(sSearch) Then
        m_asFilters() = Split(sSearch, "|")
    Else
        ReDim m_asFilters(0)
    End If

    If Deep Then
        Call RecursiveAddFiles(ParentDir)
    Else
        Call AddFiles(ParentDir)
    End If

    If m_lNext Then
        ReDim Preserve m_asFiles(m_lNext - 1)
        GetFileList = m_asFiles
    End If

End Function

Private Sub RecursiveAddFiles(ByVal ParentDir As String)
    Dim asDirs() As String
    Dim l As Long
    On Error GoTo ErrRecursiveAddFiles
    'Add the files in 'this' directory!


    Call AddFiles(ParentDir)

    ReDim asDirs(-1 To -1)
    asDirs = GetDirList(ParentDir)
    For l = 0 To UBound(asDirs)
        Call RecursiveAddFiles(asDirs(l))
    Next l
    On Error GoTo 0
Exit Sub
ErrRecursiveAddFiles:
End Sub
Private Function GetDirList(ByVal ParentDir As String) As String()
    Dim sDir As String
    Dim asRet() As String
    Dim l As Long
    Dim lMax As Long

    If Right(ParentDir, 1) <> "\" Then
        ParentDir = ParentDir & "\"
    End If
    sDir = Dir(ParentDir, vbDirectory Or vbHidden Or vbSystem)
    Do While Len(sDir)
        If GetAttr(ParentDir & sDir) And vbDirectory Then
            If Not (sDir = "." Or sDir = "..") Then
                If l >= lMax Then
                    lMax = lMax + 10
                    ReDim Preserve asRet(lMax)
                End If
                asRet(l) = ParentDir & sDir
                l = l + 1
            End If
        End If
        sDir = Dir
    Loop
    If l Then
        ReDim Preserve asRet(l - 1)
        GetDirList = asRet()
    End If
End Function
Private Sub AddFiles(ByVal ParentDir As String)
    Dim sFile As String
    Dim l As Long

    If Right(ParentDir, 1) <> "\" Then
        ParentDir = ParentDir & "\"
    End If

    For l = 0 To UBound(m_asFilters)
        sFile = Dir(ParentDir & "\" & m_asFilters(l), vbArchive Or vbHidden Or vbNormal Or vbReadOnly Or vbSystem)
        Do While Len(sFile)
            If Not (sFile = "." Or sFile = "..") Then
                If m_lNext >= m_lMax Then
                    m_lMax = m_lMax + 100
                    ReDim Preserve m_asFiles(m_lMax)
                End If
                m_asFiles(m_lNext) = ParentDir & sFile
                m_lNext = m_lNext + 1
            End If
            sFile = Dir
        Loop
    Next l
End Sub



इसको आजमाओ। ( LINK )

Private Sub CommandButton3_Click()

Dim FileExtStr As String
Dim FileFormatNum As Long
Dim xWs As Worksheet
Dim xWb As Workbook
Dim FolderName As String
Application.ScreenUpdating = False
Set xWb = Application.ThisWorkbook
DateString = Format(Now, "yyyy-mm-dd hh-mm-ss")
FolderName = xWb.Path & "\" & xWb.Name & " " & DateString
MkDir FolderName
For Each xWs In xWb.Worksheets
    xWs.Copy
    If Val(Application.Version) < 12 Then
        FileExtStr = ".xls": FileFormatNum = -4143
    Else
        Select Case xWb.FileFormat
            Case 51:
                FileExtStr = ".xlsx": FileFormatNum = 51
            Case 52:
                If Application.ActiveWorkbook.HasVBProject Then
                    FileExtStr = ".xlsm": FileFormatNum = 52
                Else
                    FileExtStr = ".xlsx": FileFormatNum = 51
                End If
            Case 56:
                FileExtStr = ".xls": FileFormatNum = 56
            Case Else:
                FileExtStr = ".xlsb": FileFormatNum = 50
        End Select
    End If
    xFile = FolderName & "\" & Application.ActiveWorkbook.Sheets(1).Name & FileExtStr
    Application.ActiveWorkbook.SaveAs xFile, FileFormat:=FileFormatNum
    Application.ActiveWorkbook.Close False
Next
MsgBox "You can find the files in " & FolderName
Application.ScreenUpdating = True

End Sub





Related