[Windows] 배치 파일에 명령 줄 매개 변수를 전달하려면 어떻게합니까?


Answers

여기 내가 어떻게하는지.

@fake-command /u %1 /p %2

명령 행은 다음과 같습니다.

test.cmd admin P@55w0rd > test-log.txt

% 1은 첫 번째 매개 변수 인 % 2에 적용되며 (여기 까다로운 부분이 있습니다) 두 번째 매개 변수에 적용됩니다. 이런 식으로 9 개의 매개 변수를 전달할 수 있습니다.

Question

나는 cmd (또는 bat) 파일에 파일을 하드 코딩하는 대신 실행시 ID와 암호를 전달해야합니다.

명령 행은 다음과 같습니다.

test.cmd admin P@55w0rd > test-log.txt



친구가 최근에이 주제에 관해 나에게 묻기 때문에 명령 파일 인수를 배치 파일로 처리하는 방법을 게시 할 것이라고 생각했습니다.

이 기법은 약간의 오버 헤드가 있지만, 배치 파일을 이해하기 쉽고 빠르게 구현할 수 있습니다. 다음 구조를 지원하는 것은 물론 :

>template.bat [-f] [--flag] [/f] [--namedvalue value] arg1 [arg2][arg3][...]

그것의 jist는 :init , :parse:main 함수를 가지고 있습니다.

사용 예

>template.bat /?
test v1.23
This is a sample batch file template,
providing command-line arguments and flags.

USAGE:
test.bat [flags] "required argument" "optional argument"

/?, --help           shows this help
/v, --version        shows the version
/e, --verbose        shows detailed output
-f, --flag value     specifies a named parameter value

>template.bat          <- throws missing argument error
(same as /?, plus..)
****                                   ****
****    MISSING "REQUIRED ARGUMENT"    ****
****                                   ****

>template.bat -v
1.23

>template.bat --version
test v1.23
This is a sample batch file template,
providing command-line arguments and flags.

>template.bat -e arg1
**** DEBUG IS ON
UnNamedArgument:    "arg1"
UnNamedOptionalArg: not provided
NamedFlag:          not provided

>template.bat --flag "my flag" arg1 arg2
UnNamedArgument:    "arg1"
UnNamedOptionalArg: "arg2"
NamedFlag:          "my flag"

>template.bat --verbose "argument #1" --flag "my flag" second
**** DEBUG IS ON
UnNamedArgument:    "argument #1"
UnNamedOptionalArg: "second"
NamedFlag:          "my flag"

template.bat

@::!/dos/rocks
@echo off
goto :init

:header
    echo %__NAME% v%__VERSION%
    echo This is a sample batch file template,
    echo providing command-line arguments and flags.
    echo.
    goto :eof

:usage
    echo USAGE:
    echo   %__BAT_NAME% [flags] "required argument" "optional argument" 
    echo.
    echo.  /?, --help           shows this help
    echo.  /v, --version        shows the version
    echo.  /e, --verbose        shows detailed output
    echo.  -f, --flag value     specifies a named parameter value
    goto :eof

:version
    if "%~1"=="full" call :header & goto :eof
    echo %__VERSION%
    goto :eof

:missing_argument
    call :header
    call :usage
    echo.
    echo ****                                   ****
    echo ****    MISSING "REQUIRED ARGUMENT"    ****
    echo ****                                   ****
    echo.
    goto :eof

:init
    set "__NAME=%~n0"
    set "__VERSION=1.23"
    set "__YEAR=2017"

    set "__BAT_FILE=%~0"
    set "__BAT_PATH=%~dp0"
    set "__BAT_NAME=%~nx0"

    set "OptHelp="
    set "OptVersion="
    set "OptVerbose="

    set "UnNamedArgument="
    set "UnNamedOptionalArg="
    set "NamedFlag="

:parse
    if "%~1"=="" goto :validate

    if /i "%~1"=="/?"         call :header & call :usage "%~2" & goto :end
    if /i "%~1"=="-?"         call :header & call :usage "%~2" & goto :end
    if /i "%~1"=="--help"     call :header & call :usage "%~2" & goto :end

    if /i "%~1"=="/v"         call :version      & goto :end
    if /i "%~1"=="-v"         call :version      & goto :end
    if /i "%~1"=="--version"  call :version full & goto :end

    if /i "%~1"=="/e"         set "OptVerbose=yes"  & shift & goto :parse
    if /i "%~1"=="-e"         set "OptVerbose=yes"  & shift & goto :parse
    if /i "%~1"=="--verbose"  set "OptVerbose=yes"  & shift & goto :parse

    if /i "%~1"=="--flag"     set "NamedFlag=%~2"   & shift & shift & goto :parse

    if not defined UnNamedArgument     set "UnNamedArgument=%~1"     & shift & goto :parse
    if not defined UnNamedOptionalArg  set "UnNamedOptionalArg=%~1"  & shift & goto :parse

    shift
    goto :parse

:validate
    if not defined UnNamedArgument call :missing_argument & goto :end

:main
    if defined OptVerbose (
        echo **** DEBUG IS ON
    )

    echo UnNamedArgument:    "%UnNamedArgument%"

    if defined UnNamedOptionalArg      echo UnNamedOptionalArg: "%UnNamedOptionalArg%"
    if not defined UnNamedOptionalArg  echo UnNamedOptionalArg: not provided

    if defined NamedFlag               echo NamedFlag:          "%NamedFlag%"
    if not defined NamedFlag           echo NamedFlag:          not provided

:end
    call :cleanup
    exit /B

:cleanup
    REM The cleanup function is only really necessary if you
    REM are _not_ using SETLOCAL.
    set "__NAME="
    set "__VERSION="
    set "__YEAR="

    set "__BAT_FILE="
    set "__BAT_PATH="
    set "__BAT_NAME="

    set "OptHelp="
    set "OptVersion="
    set "OptVerbose="

    set "UnNamedArgument="
    set "UnNamedArgument2="
    set "NamedFlag="

    goto :eof



FOR %%A IN (%*) DO (
    REM Now your batch file handles %%A instead of %1
    REM No need to use SHIFT anymore.
    ECHO %%A
)

이렇게하면 배치 매개 변수 (% *)가 반복되거나 따옴표가 붙은 다음 각 매개 변수가 에코됩니다.




명령 줄에서 set 변수를 참조하려면 "% a %"를 사용해야합니다. 예를 들면 다음과 같습니다.

      set a=100 
      echo %a%  
      output = 100 

참고 :이 기능은 Windows 7 Pro에서 작동합니다.




그것을 복잡하게 할 필요가 없습니다. 단순히 명령 % 1 % 2 매개 변수입니다. 예를 들어,

@echo off

xcopy %1 %2 /D /E /C /Q /H /R /K /Y /Z

echo copied %1 to %2

pause

"일시 중지"는 배치 파일이 수행 한 작업을 표시하고 사용자가 ANY 키를 누르기를 기다립니다. xx.bat 파일을 Windows 폴더에 저장하십시오.

이를 사용하려면 다음과 같이 입력하십시오.

xx c:\f\30\*.* f:\sites\30

이 배치 파일은 파일 만 복사하는 것, 최신 파일 등 모든 필요한 매개 변수를 처리합니다. Windows 이전부터 사용했습니다. 파일의 이름을 보길 원한다면, 복사 될 때 Q 매개 변수를 생략하십시오.




배치 매개 변수에 액세스하는 것은 % 1, % 2, ... % 9 또는 % *,
그러나 내용이 단순한 경우에만.

오류를 생성하지 않고 % 1에 액세스 할 수 없으므로 "&"^& 와 같은 복잡한 내용에 대한 간단한 방법은 없습니다.

set  var=%1
set "var=%1"
set  var=%~1
set "var=%~1"

선이 펼쳐집니다.

set  var="&"&
set "var="&"&"
set  var="&"&
set "var="&"&"

& 하나가 따옴표 밖에 있기 때문에 각 줄은 실패합니다.

매개 변수의 주목할만한 버전을 임시 파일에서 읽음으로써 해결할 수 있습니다.

@echo off
SETLOCAL DisableDelayedExpansion

SETLOCAL
for %%a in (1) do (
    set "prompt="
    echo on
    for %%b in (1) do rem * #%1#
    @echo off
) > param.txt
ENDLOCAL

for /F "delims=" %%L in (param.txt) do (
  set "param1=%%L"
)
SETLOCAL EnableDelayedExpansion
set "param1=!param1:*#=!"
set "param1=!param1:~0,-2!"
echo %%1 is '!param1!'

트릭은 echo on 문을 사용한 후 echo on 를 활성화하고 % 1을 확장하는 것입니다 (% 2 .. % *에서도 작동 함).
따라서 "&"& 조차도 오류가 발생하지 않고 에코 될 수 있습니다.

그러나 echo on 의 출력을 리디렉션 할 수 있으려면 두 개의 FOR-LOOPS가 필요합니다.

추가 문자 * # 는 /와 같은 내용에 대해 안전하도록 사용됩니다. (REM에 도움이 될 것입니다).
또는 라인 끝의 캐럿 ^은 여러 줄 문자로 사용할 수 있습니다.

그런 다음 파일에서 rem 매개 변수 출력을 읽지 만 신중하게 읽습니다.
FOR / F는 지연된 확장 기능을 해제해야하며 그렇지 않으면 "!" 파괴 될 것이다.
param1에서 여분의 문자를 제거하면 알 수 있습니다.

param1을 안전한 방법으로 사용하려면 지연된 확장을 사용하십시오.