[sql] 将列添加到表,然后在事务内更新它



Answers

我几乎同意Remus,但您可以使用SET XACT_ABORT ON和XACT_STATE执行此操作

基本上

  • SET XACT_ABORT ON将在出错和ROLLBACK时中止每个批处理
  • 每批由GO分隔
  • 执行错误时会跳转到下一批
  • 使用XACT_STATE()将测试事务是否仍然有效

像Red Gate SQL Compare这样的工具使用这种技术

就像是:

SET XACT_ABORT ON
GO
BEGIN TRANSACTION
GO

IF COLUMNPROPERTY(OBJECT_ID('Color'), 'CodeID', ColumnId) IS NULL
   ALTER TABLE Color ADD CodeID [uniqueidentifier] NULL
GO

IF XACT_STATE() = 1
  UPDATE Color
  SET CodeID= 'B6D266DC-B305-4153-A7AB-9109962255FC'
  WHERE [Name] = 'Red'
GO

IF XACT_STATE() = 1
 COMMIT TRAN
--else would be rolled back

我也删除了默认值。 对于GUID值,没有值= NULL。 它的意思是独一无二的:不要试图将每一行设置为全零,因为它会以泪水结束......

Question

我正在创建一个将在MS SQL服务器中运行的脚本。 此脚本将运行多个语句,并且需要是事务性的,如果其中一个语句失败,则停止整体执行并回滚任何更改。

在发出ALTER TABLE语句以向表中添加列然后更新新添加的列时,我在创建此事务模型时遇到问题。 为了立即访问新添加的列,我使用GO命令执行ALTER TABLE语句,然后调用我的UPDATE语句。 我面临的问题是我不能在IF语句中发出GO命令。 IF语句在我的事务模型中很重要。 这是我尝试运行的脚本的示例代码。 另请注意,发出GO命令会丢弃@errorCode变量,并且需要在使用之前在代码中声明(这不在下面的代码中)。

BEGIN TRANSACTION

DECLARE @errorCode INT
SET @errorCode = @@ERROR

-- **********************************
-- * Settings
-- **********************************
IF @errorCode = 0
BEGIN
 BEGIN TRY
  ALTER TABLE Color ADD [CodeID] [uniqueidentifier] NOT NULL DEFAULT ('{00000000-0000-0000-0000-000000000000}')
  GO
 END TRY
 BEGIN CATCH
  SET @errorCode = @@ERROR
 END CATCH
END

IF @errorCode = 0
BEGIN
 BEGIN TRY
  UPDATE Color
  SET CodeID= 'B6D266DC-B305-4153-A7AB-9109962255FC'
  WHERE [Name] = 'Red'
 END TRY
 BEGIN CATCH
  SET @errorCode = @@ERROR
 END CATCH
END

-- **********************************
-- * Check @errorCode to issue a COMMIT or a ROLLBACK
-- **********************************
IF @errorCode = 0
BEGIN
 COMMIT
 PRINT 'Success'
END
ELSE 
BEGIN
 ROLLBACK
 PRINT 'Failure'
END

所以我想知道的是如何解决这个问题,发出ALTER TABLE语句来添加一个列然后更新该列,所有这些都在作为事务单元执行的脚本中。







你没有GO试过吗?

通常,您不应在同一脚本中混合表更改和数据更改。






Related