[windows] 如何將命令行參數傳遞給批處理文件?



Answers

這是我如何做到的。

@fake-command /u %1 /p %2

以下是命令行的外觀:

test.cmd admin P@55w0rd > test-log.txt

%1適用於第一個參數%2(這裡是棘手的部分)適用於第二個參數。 用這種方法最多可以傳遞9個參數。

Question

我需要在運行時將id和密碼傳遞給cmd(或bat)文件,而不是將它們硬編碼到文件中。

以下是命令行的外觀:

test.cmd admin P@55w0rd > test-log.txt



要在命令行中引用設置變量,您需要使用“%a%”,例如:

      set a=100 
      echo %a%  
      output = 100 

注意:這適用於Windows 7專業版。




FOR %%A IN (%*) DO (
    REM Now your batch file handles %%A instead of %1
    REM No need to use SHIFT anymore.
    ECHO %%A
)

這將遍歷批處理參數(%*),無論它們是否被引用,然後回顯每個參數。




最近有朋友問我關於這個問題,所以我想我會發佈如何處理批處理文件中的命令行參數。

這種技術會帶來一些額外的開銷,但它使我的批處理文件非常容易理解並且很快實現。 以及支持以下結構:

>template.bat [-f] [--flag] [/f] [--namedvalue value] arg1 [arg2][arg3][...]

它的主要特點是:init:parse:main函數。

用法示例

>template.bat /?
test v1.23
This is a sample batch file template,
providing command-line arguments and flags.

USAGE:
test.bat [flags] "required argument" "optional argument"

/?, --help           shows this help
/v, --version        shows the version
/e, --verbose        shows detailed output
-f, --flag value     specifies a named parameter value

>template.bat          <- throws missing argument error
(same as /?, plus..)
****                                   ****
****    MISSING "REQUIRED ARGUMENT"    ****
****                                   ****

>template.bat -v
1.23

>template.bat --version
test v1.23
This is a sample batch file template,
providing command-line arguments and flags.

>template.bat -e arg1
**** DEBUG IS ON
UnNamedArgument:    "arg1"
UnNamedOptionalArg: not provided
NamedFlag:          not provided

>template.bat --flag "my flag" arg1 arg2
UnNamedArgument:    "arg1"
UnNamedOptionalArg: "arg2"
NamedFlag:          "my flag"

>template.bat --verbose "argument #1" --flag "my flag" second
**** DEBUG IS ON
UnNamedArgument:    "argument #1"
UnNamedOptionalArg: "second"
NamedFlag:          "my flag"

template.bat

@::!/dos/rocks
@echo off
goto :init

:header
    echo %__NAME% v%__VERSION%
    echo This is a sample batch file template,
    echo providing command-line arguments and flags.
    echo.
    goto :eof

:usage
    echo USAGE:
    echo   %__BAT_NAME% [flags] "required argument" "optional argument" 
    echo.
    echo.  /?, --help           shows this help
    echo.  /v, --version        shows the version
    echo.  /e, --verbose        shows detailed output
    echo.  -f, --flag value     specifies a named parameter value
    goto :eof

:version
    if "%~1"=="full" call :header & goto :eof
    echo %__VERSION%
    goto :eof

:missing_argument
    call :header
    call :usage
    echo.
    echo ****                                   ****
    echo ****    MISSING "REQUIRED ARGUMENT"    ****
    echo ****                                   ****
    echo.
    goto :eof

:init
    set "__NAME=%~n0"
    set "__VERSION=1.23"
    set "__YEAR=2017"

    set "__BAT_FILE=%~0"
    set "__BAT_PATH=%~dp0"
    set "__BAT_NAME=%~nx0"

    set "OptHelp="
    set "OptVersion="
    set "OptVerbose="

    set "UnNamedArgument="
    set "UnNamedOptionalArg="
    set "NamedFlag="

:parse
    if "%~1"=="" goto :validate

    if /i "%~1"=="/?"         call :header & call :usage "%~2" & goto :end
    if /i "%~1"=="-?"         call :header & call :usage "%~2" & goto :end
    if /i "%~1"=="--help"     call :header & call :usage "%~2" & goto :end

    if /i "%~1"=="/v"         call :version      & goto :end
    if /i "%~1"=="-v"         call :version      & goto :end
    if /i "%~1"=="--version"  call :version full & goto :end

    if /i "%~1"=="/e"         set "OptVerbose=yes"  & shift & goto :parse
    if /i "%~1"=="-e"         set "OptVerbose=yes"  & shift & goto :parse
    if /i "%~1"=="--verbose"  set "OptVerbose=yes"  & shift & goto :parse

    if /i "%~1"=="--flag"     set "NamedFlag=%~2"   & shift & shift & goto :parse

    if not defined UnNamedArgument     set "UnNamedArgument=%~1"     & shift & goto :parse
    if not defined UnNamedOptionalArg  set "UnNamedOptionalArg=%~1"  & shift & goto :parse

    shift
    goto :parse

:validate
    if not defined UnNamedArgument call :missing_argument & goto :end

:main
    if defined OptVerbose (
        echo **** DEBUG IS ON
    )

    echo UnNamedArgument:    "%UnNamedArgument%"

    if defined UnNamedOptionalArg      echo UnNamedOptionalArg: "%UnNamedOptionalArg%"
    if not defined UnNamedOptionalArg  echo UnNamedOptionalArg: not provided

    if defined NamedFlag               echo NamedFlag:          "%NamedFlag%"
    if not defined NamedFlag           echo NamedFlag:          not provided

:end
    call :cleanup
    exit /B

:cleanup
    REM The cleanup function is only really necessary if you
    REM are _not_ using SETLOCAL.
    set "__NAME="
    set "__VERSION="
    set "__YEAR="

    set "__BAT_FILE="
    set "__BAT_PATH="
    set "__BAT_NAME="

    set "OptHelp="
    set "OptVersion="
    set "OptVerbose="

    set "UnNamedArgument="
    set "UnNamedArgument2="
    set "NamedFlag="

    goto :eof



使用%1,%2,...%9或%*可以很簡單地訪問批處理參數,
但前提是內容簡單。

複雜的內容如"&"^&沒有簡單的方法,因為無法訪問%1而不會產生錯誤。

set  var=%1
set "var=%1"
set  var=%~1
set "var=%~1"

線條擴展為

set  var="&"&
set "var="&"&"
set  var="&"&
set "var="&"&"

並且每條線都會失敗,因為其中一個“ & ”在引號之外。

它可以通過從臨時文件讀取參數的標記版本來解決。

@echo off
SETLOCAL DisableDelayedExpansion

SETLOCAL
for %%a in (1) do (
    set "prompt="
    echo on
    for %%b in (1) do rem * #%1#
    @echo off
) > param.txt
ENDLOCAL

for /F "delims=" %%L in (param.txt) do (
  set "param1=%%L"
)
SETLOCAL EnableDelayedExpansion
set "param1=!param1:*#=!"
set "param1=!param1:~0,-2!"
echo %%1 is '!param1!'

訣竅是在rem語句之後啟用echo on並擴展%1(與%2 ..%*一起使用)。
所以即使是"&"&也可以在不產生錯誤的情況下得到回應,正如它所說的那樣。

但為了能夠重定向回顯的輸出,您需要兩個FOR-LOOPS。

多餘的字符* #用於防止/ /等內容安全。 (會顯示REM的幫助)。
或者在線末尾的插入符號可以作為多行字符,即使在rem

然後仔細閱讀從文件中輸出的rem參數
FOR / F應該使用延遲擴展,否則內容使用“!” 將被銷毀。
刪除了param1中的多餘字符後,你就可以得到它了。

並且要以安全的方式使用param1,請啟用延遲擴展。




沒有必要使它複雜化。 它僅僅是命令%1%2參數,例如,

@echo off

xcopy %1 %2 /D /E /C /Q /H /R /K /Y /Z

echo copied %1 to %2

pause

“暫停”顯示批處理文件已完成的內容,並等待您點擊ANY鍵。 將其保存為Windows文件夾中的xx.bat。

要使用它,請輸入,例如:

xx c:\f\30\*.* f:\sites\30

這個批處理文件負責處理所有必要的參數,比如只複製文件,更新等等。我在Windows之前就已經使用了它。 如果你喜歡看到這些文件的名稱,當它們被複製時,忽略Q參數。




Related