Terraform 0.11

aws_config_configuration_recorder_status




terraform

aws_config_configuration_recorder_status

AWS कॉन्फ़िगरेशन कॉन्फ़िगरेशन रिकॉर्डर की स्थिति (रिकॉर्डिंग / रोक) का प्रबंधन करता है।

उदाहरण उपयोग

resource "aws_config_configuration_recorder_status" "foo" {
  name       = "${aws_config_configuration_recorder.foo.name}"
  is_enabled = true
  depends_on = ["aws_config_delivery_channel.foo"]
}

resource "aws_iam_role_policy_attachment" "a" {
  role       = "${aws_iam_role.r.name}"
  policy_arn = "arn:aws:iam::aws:policy/service-role/AWSConfigRole"
}

resource "aws_s3_bucket" "b" {
  bucket = "awsconfig-example"
}

resource "aws_config_delivery_channel" "foo" {
  name           = "example"
  s3_bucket_name = "${aws_s3_bucket.b.bucket}"
}

resource "aws_config_configuration_recorder" "foo" {
  name     = "example"
  role_arn = "${aws_iam_role.r.arn}"
}

resource "aws_iam_role" "r" {
  name = "example-awsconfig"

  assume_role_policy = <<POLICY
{
  "Version": "2012-10-17",
  "Statement": [
    {
      "Action": "sts:AssumeRole",
      "Principal": {
        "Service": "config.amazonaws.com"
      },
      "Effect": "Allow",
      "Sid": ""
    }
  ]
}
POLICY
}

तर्क संदर्भ

निम्नलिखित तर्क समर्थित हैं:

  • name - (आवश्यक) रिकॉर्डर का नाम
  • is_enabled - (आवश्यक) क्या कॉन्फ़िगरेशन रिकॉर्डर को सक्षम या अक्षम किया जाना चाहिए।

आयात

कॉन्फ़िगरेशन रिकॉर्डर स्थिति को कॉन्फ़िगरेशन रिकॉर्डर के नाम का उपयोग करके आयात किया जा सकता है, जैसे

$ terraform import aws_config_configuration_recorder_status.foo example