Terraform 0.11

aws_flow_log




terraform

aws_flow_log

एक विशिष्ट नेटवर्क इंटरफ़ेस, सबनेट, या VPC के लिए IP ट्रैफ़िक कैप्चर करने के लिए VPC / Subnet / ENI फ़्लो लॉग प्रदान करता है। लॉग को क्लाउडवॉच लॉग ग्रुप में भेजा जाता है।

उदाहरण उपयोग

resource "aws_flow_log" "test_flow_log" {
  log_group_name = "${aws_cloudwatch_log_group.test_log_group.name}"
  iam_role_arn   = "${aws_iam_role.test_role.arn}"
  vpc_id         = "${aws_vpc.default.id}"
  traffic_type   = "ALL"
}

resource "aws_cloudwatch_log_group" "test_log_group" {
  name = "test_log_group"
}

resource "aws_iam_role" "test_role" {
  name = "test_role"

  assume_role_policy = <<EOF
{
  "Version": "2012-10-17",
  "Statement": [
    {
      "Sid": "",
      "Effect": "Allow",
      "Principal": {
        "Service": "vpc-flow-logs.amazonaws.com"
      },
      "Action": "sts:AssumeRole"
    }
  ]
}
EOF
}

resource "aws_iam_role_policy" "test_policy" {
  name = "test_policy"
  role = "${aws_iam_role.test_role.id}"

  policy = <<EOF
{
  "Version": "2012-10-17",
  "Statement": [
    {
      "Action": [
        "logs:CreateLogGroup",
        "logs:CreateLogStream",
        "logs:PutLogEvents",
        "logs:DescribeLogGroups",
        "logs:DescribeLogStreams"
      ],
      "Effect": "Allow",
      "Resource": "*"
    }
  ]
}
EOF
}

तर्क संदर्भ

निम्नलिखित तर्क समर्थित हैं:

  • log_group_name - (आवश्यक) CloudWatch लॉग समूह का नाम
  • iam_role_arn - (आवश्यक) IAM भूमिका के लिए ARN जो CloudWatch लॉग्स लॉग समूह में फ्लो लॉग पोस्ट करने के लिए उपयोग किया जाता है
  • vpc_id - (वैकल्पिक) संलग्न करने के लिए VPC ID
  • subnet_id - (वैकल्पिक) सबनेट आईडी को संलग्न करने के लिए
  • eni_id - (वैकल्पिक) संलग्न करने के लिए लोचदार नेटवर्क इंटरफ़ेस ID
  • traffic_type - (आवश्यक) ट्रैफ़िक का प्रकार कैप्चर करने के लिए। मान्य मान: ACCEPT , REJECT , ALL

संदर्भ संदर्भित करता है

उपरोक्त सभी तर्कों के अलावा, निम्नलिखित विशेषताएँ निर्यात की जाती हैं:

  • id - फ्लो लॉग आईडी

आयात

id , जैसे का उपयोग करके फ्लो लॉग आयात किए जा सकते हैं

$ terraform import aws_flow_log.test_flow_log fl-1a2b3c4d