Terraform 0.11

aws_route53_query_log




terraform

aws_route53_query_log

एक मार्ग53 क्वेरी लॉगिंग कॉन्फ़िगरेशन संसाधन प्रदान करता है।

उदाहरण उपयोग

# Example CloudWatch log group in us-east-1

provider "aws" {
  alias  = "us-east-1"
  region = "us-east-1"
}

resource "aws_cloudwatch_log_group" "aws_route53_example_com" {
  provider = "aws.us-east-1"

  name              = "/aws/route53/${aws_route53_zone.example_com.name}"
  retention_in_days = 30
}

# Example CloudWatch log resource policy to allow Route53 to write logs
# to any log group under /aws/route53/*

data "aws_iam_policy_document" "route53-query-logging-policy" {
  statement {
    actions = [
      "logs:CreateLogStream",
      "logs:PutLogEvents",
    ]

    resources = ["arn:aws:logs:*:*:log-group:/aws/route53/*"]

    principals {
      identifiers = ["route53.amazonaws.com"]
      type        = "Service"
    }
  }
}

resource "aws_cloudwatch_log_resource_policy" "route53-query-logging-policy" {
  provider = "aws.us-east-1"

  policy_document = "${data.aws_iam_policy_document.route53-query-logging-policy.json}"
  policy_name     = "route53-query-logging-policy"
}

# Example Route53 zone with query logging

resource "aws_route53_zone" "example_com" {
  name = "example.com"
}

resource "aws_route53_query_log" "example_com" {
  depends_on = ["aws_cloudwatch_log_resource_policy.route53-query-logging-policy"]

  cloudwatch_log_group_arn = "${aws_cloudwatch_log_group.aws_route53_example_com.arn}"
  zone_id                  = "${aws_route53_zone.example_com.zone_id}"
}

तर्क संदर्भ

निम्नलिखित तर्क समर्थित हैं:

  • cloudwatch_log_group_arn - (आवश्यक) क्लाउड लॉग समूह ARN को क्वेरी लॉग भेजने के लिए।
  • zone_id - (आवश्यक) रूट 53 को क्वेरी लॉग को सक्षम करने के लिए ज़ोन आईडी होस्ट किया गया।

संदर्भ संदर्भित करता है

उपरोक्त सभी तर्कों के अलावा, निम्नलिखित विशेषताएँ निर्यात की जाती हैं:

  • id - क्वेरी लॉगिंग कॉन्फ़िगरेशन आईडी

आयात

मार्ग53 क्वेरी लॉगिंग कॉन्फ़िगरेशन को अपनी आईडी, जैसे का उपयोग करके आयात किया जा सकता है

$ terraform import aws_route53_query_log.example_com xxxxxxxx-xxxx-xxxx-xxxx-xxxxxxxxxxxx