Terraform 0.11

aws_s3_bucket_notification




terraform

aws_s3_bucket_notification

एक S3 बाल्टी सूचना संसाधन प्रदान करता है।

उदाहरण उपयोग

SNS Topic में सूचना कॉन्फ़िगरेशन जोड़ें

resource "aws_sns_topic" "topic" {
  name = "s3-event-notification-topic"

  policy = <<POLICY
{
    "Version":"2012-10-17",
    "Statement":[{
        "Effect": "Allow",
        "Principal": {"AWS":"*"},
        "Action": "SNS:Publish",
        "Resource": "arn:aws:sns:*:*:s3-event-notification-topic",
        "Condition":{
            "ArnLike":{"aws:SourceArn":"${aws_s3_bucket.bucket.arn}"}
        }
    }]
}
POLICY
}

resource "aws_s3_bucket" "bucket" {
  bucket = "your_bucket_name"
}

resource "aws_s3_bucket_notification" "bucket_notification" {
  bucket = "${aws_s3_bucket.bucket.id}"

  topic {
    topic_arn     = "${aws_sns_topic.topic.arn}"
    events        = ["s3:ObjectCreated:*"]
    filter_suffix = ".log"
  }
}

SQS कतार में सूचना कॉन्फ़िगरेशन जोड़ें

resource "aws_sqs_queue" "queue" {
  name = "s3-event-notification-queue"

  policy = <<POLICY
{
  "Version": "2012-10-17",
  "Statement": [
    {
      "Effect": "Allow",
      "Principal": "*",
      "Action": "sqs:SendMessage",
      "Resource": "arn:aws:sqs:*:*:s3-event-notification-queue",
      "Condition": {
        "ArnEquals": { "aws:SourceArn": "${aws_s3_bucket.bucket.arn}" }
      }
    }
  ]
}
POLICY
}

resource "aws_s3_bucket" "bucket" {
  bucket = "your_bucket_name"
}

resource "aws_s3_bucket_notification" "bucket_notification" {
  bucket = "${aws_s3_bucket.bucket.id}"

  queue {
    queue_arn     = "${aws_sqs_queue.queue.arn}"
    events        = ["s3:ObjectCreated:*"]
    filter_suffix = ".log"
  }
}

लैम्ब्डा फंक्शन में अधिसूचना कॉन्फ़िगरेशन जोड़ें

resource "aws_iam_role" "iam_for_lambda" {
  name = "iam_for_lambda"

  assume_role_policy = <<EOF
{
  "Version": "2012-10-17",
  "Statement": [
    {
      "Action": "sts:AssumeRole",
      "Principal": {
        "Service": "lambda.amazonaws.com"
      },
      "Effect": "Allow"
    }
  ]
}
EOF
}

resource "aws_lambda_permission" "allow_bucket" {
  statement_id  = "AllowExecutionFromS3Bucket"
  action        = "lambda:InvokeFunction"
  function_name = "${aws_lambda_function.func.arn}"
  principal     = "s3.amazonaws.com"
  source_arn    = "${aws_s3_bucket.bucket.arn}"
}

resource "aws_lambda_function" "func" {
  filename      = "your-function.zip"
  function_name = "example_lambda_name"
  role          = "${aws_iam_role.iam_for_lambda.arn}"
  handler       = "exports.example"
}

resource "aws_s3_bucket" "bucket" {
  bucket = "your_bucket_name"
}

resource "aws_s3_bucket_notification" "bucket_notification" {
  bucket = "${aws_s3_bucket.bucket.id}"

  lambda_function {
    lambda_function_arn = "${aws_lambda_function.func.arn}"
    events              = ["s3:ObjectCreated:*"]
    filter_prefix       = "AWSLogs/"
    filter_suffix       = ".log"
  }
}

ट्रिगर मल्टीपल लैम्ब्डा फ़ंक्शन

resource "aws_iam_role" "iam_for_lambda" {
  name = "iam_for_lambda"

  assume_role_policy = <<EOF
{
  "Version": "2012-10-17",
  "Statement": [
    {
      "Action": "sts:AssumeRole",
      "Principal": {
        "Service": "lambda.amazonaws.com"
      },
      "Effect": "Allow"
    }
  ]
}
EOF
}

resource "aws_lambda_permission" "allow_bucket1" {
  statement_id  = "AllowExecutionFromS3Bucket1"
  action        = "lambda:InvokeFunction"
  function_name = "${aws_lambda_function.func1.arn}"
  principal     = "s3.amazonaws.com"
  source_arn    = "${aws_s3_bucket.bucket.arn}"
}

resource "aws_lambda_function" "func1" {
  filename      = "your-function1.zip"
  function_name = "example_lambda_name1"
  role          = "${aws_iam_role.iam_for_lambda.arn}"
  handler       = "exports.example"
}

resource "aws_lambda_permission" "allow_bucket2" {
  statement_id  = "AllowExecutionFromS3Bucket2"
  action        = "lambda:InvokeFunction"
  function_name = "${aws_lambda_function.func2.arn}"
  principal     = "s3.amazonaws.com"
  source_arn    = "${aws_s3_bucket.bucket.arn}"
}

resource "aws_lambda_function" "func2" {
  filename      = "your-function2.zip"
  function_name = "example_lambda_name2"
  role          = "${aws_iam_role.iam_for_lambda.arn}"
  handler       = "exports.example"
}

resource "aws_s3_bucket" "bucket" {
  bucket = "your_bucket_name"
}

resource "aws_s3_bucket_notification" "bucket_notification" {
  bucket = "${aws_s3_bucket.bucket.id}"

  lambda_function {
    lambda_function_arn = "${aws_lambda_function.func1.arn}"
    events              = ["s3:ObjectCreated:*"]
    filter_prefix       = "AWSLogs/"
    filter_suffix       = ".log"
  }

  lambda_function {
    lambda_function_arn = "${aws_lambda_function.func2.arn}"
    events              = ["s3:ObjectCreated:*"]
    filter_prefix       = "OtherLogs/"
    filter_suffix       = ".log"
  }
}

SQS कतार में कई अधिसूचना कॉन्फ़िगरेशन जोड़ें

resource "aws_sqs_queue" "queue" {
  name = "s3-event-notification-queue"

  policy = <<POLICY
{
  "Version": "2012-10-17",
  "Statement": [
    {
      "Effect": "Allow",
      "Principal": "*",
      "Action": "sqs:SendMessage",
      "Resource": "arn:aws:sqs:*:*:s3-event-notification-queue",
      "Condition": {
        "ArnEquals": { "aws:SourceArn": "${aws_s3_bucket.bucket.arn}" }
      }
    }
  ]
}
POLICY
}

resource "aws_s3_bucket" "bucket" {
  bucket = "your_bucket_name"
}

resource "aws_s3_bucket_notification" "bucket_notification" {
  bucket = "${aws_s3_bucket.bucket.id}"

  queue {
    id            = "image-upload-event"
    queue_arn     = "${aws_sqs_queue.queue.arn}"
    events        = ["s3:ObjectCreated:*"]
    filter_prefix = "images/"
  }

  queue {
    id            = "video-upload-event"
    queue_arn     = "${aws_sqs_queue.queue.arn}"
    events        = ["s3:ObjectCreated:*"]
    filter_prefix = "videos/"
  }
}

टेराफॉर्म के JSON सिंटैक्स के लिए , queue कुंजी को दो बार परिभाषित करने के बजाय एक सरणी का उपयोग करें।

{
    "bucket": "${aws_s3_bucket.bucket.id}",
    "queue": [
        {
            "id": "image-upload-event",
            "queue_arn": "${aws_sqs_queue.queue.arn}",
            "events": ["s3:ObjectCreated:*"],
            "filter_prefix": "images/"
        },
        {
            "id": "video-upload-event",
            "queue_arn": "${aws_sqs_queue.queue.arn}",
            "events": ["s3:ObjectCreated:*"],
            "filter_prefix": "videos/"
        }
    ]
}

तर्क संदर्भ

निम्नलिखित तर्क समर्थित हैं:

  • bucket - (आवश्यक) अधिसूचना कॉन्फ़िगरेशन डालने के लिए बकेट का नाम।
  • topic - (वैकल्पिक) SNS विषय (नीचे दस्तावेज) के लिए अधिसूचना विन्यास।
  • queue - (वैकल्पिक) SQS कतार (नीचे दस्तावेज) के लिए अधिसूचना विन्यास।
  • lambda_function - (वैकल्पिक, एकाधिक) सूचनाओं को एक लैम्ब्डा फंक्शन (नीचे प्रलेखित) को कॉन्फ़िगर करने के लिए उपयोग किया जाता है।

topic सूचना कॉन्फ़िगरेशन निम्नलिखित का समर्थन करता है:

  • id - (वैकल्पिक) प्रत्येक सूचना विन्यास के लिए विशिष्ट पहचानकर्ता निर्दिष्ट करता है।
  • topic_arn - (आवश्यक) Amazon SNS विषय ARN निर्दिष्ट करता है।
  • events - (आवश्यक) event निर्दिष्ट करता है जिसके लिए सूचनाएं भेजनी हैं।
  • filter_prefix - (वैकल्पिक) ऑब्जेक्ट कुंजी नाम उपसर्ग निर्दिष्ट करता है।
  • filter_suffix - (वैकल्पिक) ऑब्जेक्ट कुंजी नाम प्रत्यय निर्दिष्ट करता है।

queue सूचना कॉन्फ़िगरेशन निम्नलिखित का समर्थन करता है:

  • id - (वैकल्पिक) प्रत्येक सूचना विन्यास के लिए विशिष्ट पहचानकर्ता निर्दिष्ट करता है।
  • queue_arn - (आवश्यक) Amazon SQS कतार ARN निर्दिष्ट करता है।
  • events - (आवश्यक) event निर्दिष्ट करता है जिसके लिए सूचनाएं भेजनी हैं।
  • filter_prefix - (वैकल्पिक) ऑब्जेक्ट कुंजी नाम उपसर्ग निर्दिष्ट करता है।
  • filter_suffix - (वैकल्पिक) ऑब्जेक्ट कुंजी नाम प्रत्यय निर्दिष्ट करता है।

lambda_function अधिसूचना कॉन्फ़िगरेशन निम्न का समर्थन करता है:

  • id - (वैकल्पिक) प्रत्येक सूचना विन्यास के लिए विशिष्ट पहचानकर्ता निर्दिष्ट करता है।
  • lambda_function_arn - (आवश्यक) अमेज़ॅन लैम्ब्डा फ़ंक्शन ARN निर्दिष्ट करता है।
  • events - (आवश्यक) event निर्दिष्ट करता है जिसके लिए सूचनाएं भेजनी हैं।
  • filter_prefix - (वैकल्पिक) ऑब्जेक्ट कुंजी नाम उपसर्ग निर्दिष्ट करता है।
  • filter_suffix - (वैकल्पिक) ऑब्जेक्ट कुंजी नाम प्रत्यय निर्दिष्ट करता है।

आयात

S3 बकेट नोटिफिकेशन को bucket का उपयोग करके आयात किया जा सकता है, जैसे

$ terraform import aws_s3_bucket_notification.bucket_notification bucket-name