Terraform 0.11 - azurerm_managed_disk

डेटा स्रोत: azurerm_managed_disk




terraform

डेटा स्रोत: azurerm_managed_disk

मौजूदा Azure प्रबंधित डिस्क के गुणों तक पहुँचने के लिए इस डेटा स्रोत का उपयोग करें।

उदाहरण उपयोग

data "azurerm_managed_disk" "datasourcemd" {
    name = "testManagedDisk"
    resource_group_name = "acctestRG"
}

resource "azurerm_virtual_network" "test" {
  name                = "acctvn"
  address_space       = ["10.0.0.0/16"]
  location            = "West US 2"
  resource_group_name = "acctestRG"
}

resource "azurerm_subnet" "test" {
  name                 = "acctsub"
  resource_group_name  = "acctestRG"
  virtual_network_name = "${azurerm_virtual_network.test.name}"
  address_prefix       = "10.0.2.0/24"
}

resource "azurerm_network_interface" "test" {
  name                = "acctni"
  location            = "West US 2"
  resource_group_name = "acctestRG"

  ip_configuration {
    name                          = "testconfiguration1"
    subnet_id                     = "${azurerm_subnet.test.id}"
    private_ip_address_allocation = "dynamic"
  }
}

resource "azurerm_virtual_machine" "test" {
  name                  = "acctvm"
  location              = "West US 2"
  resource_group_name   = "acctestRG"
  network_interface_ids = ["${azurerm_network_interface.test.id}"]
  vm_size               = "Standard_DS1_v2"

  storage_image_reference {
    publisher = "Canonical"
    offer     = "UbuntuServer"
    sku       = "16.04-LTS"
    version   = "latest"
  }

  storage_os_disk {
    name              = "myosdisk1"
    caching           = "ReadWrite"
    create_option     = "FromImage"
    managed_disk_type = "Standard_LRS"
  }

  storage_data_disk {
    name              = "datadisk_new"
    managed_disk_type = "Standard_LRS"
    create_option     = "Empty"
    lun               = 0
    disk_size_gb      = "1023"
  }

  storage_data_disk {
    name            = "${data.azurerm_managed_disk.datasourcemd.name}"
    managed_disk_id = "${data.azurerm_managed_disk.datasourcemd.id}"
    create_option   = "Attach"
    lun             = 1
    disk_size_gb    = "${data.azurerm_managed_disk.datasourcemd.disk_size_gb}"
  }

  os_profile {
    computer_name  = "hostname"
    admin_username = "testadmin"
    admin_password = "Password1234!"
  }

  os_profile_linux_config {
    disable_password_authentication = false
  }

  tags {
    environment = "staging"
  }
}

तर्क संदर्भ

  • name - (आवश्यक) प्रबंधित डिस्क का नाम निर्दिष्ट करता है।
  • resource_group_name - (आवश्यक) संसाधन समूह का नाम निर्दिष्ट करता है।

संदर्भ संदर्भित करता है

  • storage_account_type - प्रबंधित डिस्क के लिए संग्रहण खाता प्रकार।
  • source_uri - प्रबंधित डिस्क के लिए स्रोत URI
  • source_resource_id - एक मौजूदा प्रबंधित डिस्क की आईडी जिसे वर्तमान संसाधन से बनाया गया था।
  • os_type - प्रबंधित डिस्क के लिए ऑपरेटिंग सिस्टम। वैध मान Linux या Windows
  • disk_size_gb - गीगाबाइट में प्रबंधित डिस्क का आकार।
  • tags - संसाधनों को सौंपे गए टैग की मैपिंग।
  • zones - (वैकल्पिक) एक संग्रह जिसमें उपलब्धता क्षेत्र प्रबंधित डिस्क में आवंटित किया गया है।