Terraform 0.11 - azurerm_public_ip

डेटा स्रोत: azurerm_public_ip




terraform

डेटा स्रोत: azurerm_public_ip

मौजूदा Azure सार्वजनिक IP पते के गुणों तक पहुँचने के लिए इस डेटा स्रोत का उपयोग करें।

उदाहरण उपयोग (एक मौजूदा संदर्भ)

data "azurerm_public_ip" "test" {
  name = "name_of_public_ip"
  resource_group_name = "name_of_resource_group"
}

output "domain_name_label" {
  value = "${data.azurerm_public_ip.test.domain_name_label}"
}

output "public_ip_address" {
  value = "${data.azurerm_public_ip.test.ip_address}"
}

उदाहरण का उपयोग (नए वीएम के गतिशील सार्वजनिक आईपी को पुनः प्राप्त करें)

resource "azurerm_resource_group" "test" {
  name     = "test-resources"
  location = "West US 2"
}

resource "azurerm_virtual_network" "test" {
  name                = "test-network"
  address_space       = ["10.0.0.0/16"]
  location            = "${azurerm_resource_group.test.location}"
  resource_group_name = "${azurerm_resource_group.test.name}"
}

resource "azurerm_subnet" "test" {
  name                 = "acctsub"
  resource_group_name  = "${azurerm_resource_group.test.name}"
  virtual_network_name = "${azurerm_virtual_network.test.name}"
  address_prefix       = "10.0.2.0/24"
}

resource "azurerm_public_ip" "test" {
  name                         = "test-pip"
  location                     = "${azurerm_resource_group.test.location}"
  resource_group_name          = "${azurerm_resource_group.test.name}"
  public_ip_address_allocation = "Dynamic"
  idle_timeout_in_minutes      = 30

  tags {
    environment = "test"
  }
}

resource "azurerm_network_interface" "test" {
  name                = "test-nic"
  location            = "${azurerm_resource_group.test.location}"
  resource_group_name = "${azurerm_resource_group.test.name}"

  ip_configuration {
    name                          = "testconfiguration1"
    subnet_id                     = "${azurerm_subnet.test.id}"
    private_ip_address_allocation = "static"
    private_ip_address            = "10.0.2.5"
    public_ip_address_id          = "${azurerm_public_ip.test.id}"
  }
}

resource "azurerm_virtual_machine" "test" {
  name                  = "test-vm"
  location              = "${azurerm_resource_group.test.location}"
  resource_group_name   = "${azurerm_resource_group.test.name}"
  network_interface_ids = ["${azurerm_network_interface.test.id}"]

  # ...
}

data "azurerm_public_ip" "test" {
  name                = "${azurerm_public_ip.test.name}"
  resource_group_name = "${azurerm_virtual_machine.test.resource_group_name}"
}

output "public_ip_address" {
  value = "${data.azurerm_public_ip.test.ip_address}"
}

तर्क संदर्भ

  • name - (आवश्यक) सार्वजनिक आईपी पते का नाम निर्दिष्ट करता है।
  • resource_group_name - (आवश्यक) संसाधन समूह का नाम निर्दिष्ट करता है।

संदर्भ संदर्भित करता है

  • domain_name_label - डोमेन नाम के लिए लेबल।
  • idle_timeout_in_minutes - TCP निष्क्रिय कनेक्शन के लिए टाइमआउट निर्दिष्ट करता है।
  • fqdn - पब्लिक आईपी के साथ जुड़े ए DNS रिकॉर्ड का पूरी तरह से योग्य डोमेन नाम। यह domainNameLabel और क्षेत्रीय डीएनएस ज़ोन का संयोजन है।
  • ip_address - IP पता मान जो आवंटित किया गया था।
  • tags - संसाधनों को सौंपा गया टैग का मानचित्रण।