Terraform 0.11

azurerm_key_vault_key




terraform

azurerm_key_vault_key

कुंजी वॉल्ट कुंजी का प्रबंधन करता है।

उदाहरण उपयोग

data "azurerm_client_config" "current" {}

resource "azurerm_resource_group" "test" {
  name     = "my-resource-group"
  location = "West US"
}

resource "random_id" "server" {
  keepers = {
    ami_id = 1
  }
  byte_length = 8
}

resource "azurerm_key_vault" "test" {
  name                = "${format("%s%s", "kv", random_id.server.hex)}"
  location            = "${azurerm_resource_group.test.location}"
  resource_group_name = "${azurerm_resource_group.test.name}"
  tenant_id           = "${data.azurerm_client_config.current.tenant_id}"

  sku {
    name = "premium"
  }

  access_policy {
    tenant_id = "${data.azurerm_client_config.current.tenant_id}"
    object_id = "${data.azurerm_client_config.current.service_principal_object_id}"

    key_permissions = [
      "create",
      "get",
    ]

    secret_permissions = [
      "set",
    ]
  }

  tags {
    environment = "Production"
  }
}

resource "azurerm_key_vault_key" "generated" {
  name      = "generated-certificate"
  vault_uri = "${azurerm_key_vault.test.vault_uri}"
  key_type  = "RSA"
  key_size  = 2048

  key_opts = [
    "decrypt",
    "encrypt",
    "sign",
    "unwrapKey",
    "verify",
    "wrapKey",
  ]
}

तर्क संदर्भ

निम्नलिखित तर्क समर्थित हैं:

  • name - (आवश्यक) कुंजी तिजोरी का नाम निर्दिष्ट करता है। इस परिवर्तन से एक नया संसाधन बनने के लिए बाध्य होता है।

  • vault_uri - (आवश्यक) azurerm_key_vault संसाधन पर उपलब्ध कुंजी तिजोरी उदाहरण का उपयोग करने के लिए उपयोग किए गए URI को निर्दिष्ट करता है।

  • key_type - (आवश्यक) इस कुंजी वॉल्ट कुंजी के लिए उपयोग करने के लिए कुंजी प्रकार निर्दिष्ट करता है। संभावित मूल्य EC (एलिप्टिक कर्व), Oct (ऑक्टेट), RSA और RSA-HSM । इस परिवर्तन से एक नया संसाधन बनने के लिए बाध्य होता है।

  • key_size - (आवश्यक) बाइट्स में बनाने के लिए कुंजी का आकार निर्दिष्ट करता है। उदाहरण के लिए, 1024 या 2048। इस परिवर्तन से एक नया संसाधन बनने के लिए बाध्य होता है।

  • key_opts - (आवश्यक) JSON वेब कुंजी संचालन की एक सूची। संभावित मानों में शामिल हैं: decrypt , encrypt , sign , unwrapKey , wrapKey और wrapKey । कृपया ध्यान दें कि ये मान केस संवेदी हैं।

  • tags - (वैकल्पिक) संसाधन को असाइन करने के लिए टैग की मैपिंग।

संदर्भ संदर्भित करता है

निम्नलिखित विशेषताएँ निर्यात की जाती हैं:

  • id - कुंजी तिजोरी कुंजी आईडी।
  • version - कुंजी वॉल्ट कुंजी का वर्तमान संस्करण।
  • n - इस कुंजी तिजोरी की RSA मापांक।
  • e - आरएसए सार्वजनिक कुंजी इस कुंजी तिजोरी की।

आयात

कुंजी वॉल्ट कुंजी जो सक्षम है, को resource id , जैसे का उपयोग करके आयात किया जा सकता है

terraform import azurerm_key_vault_key.test https://example-keyvault.vault.azure.net/keys/example/fdf067c93bbb4b22bff4d8b7a9a56217