Terraform 0.11

azurerm_metric_alertrule




terraform

azurerm_metric_alertrule

Azure Monitor में मीट्रिक-आधारित अलर्ट नियम का प्रबंधन करता है।

उदाहरण उपयोग (वर्चुअल मशीन का CPU प्रतिशत)

resource "azurerm_metric_alertrule" "test" {
  name = "${azurerm_virtual_machine.test.name}-cpu"
  resource_group_name = "${azurerm_resource_group.test.name}"
  location = "${azurerm_resource_group.test.location}"

  description = "An alert rule to watch the metric Percentage CPU"

  enabled = true

  resource_id = "${azurerm_virtual_machine.test.id}"
  metric_name = "Percentage CPU"
  operator = "GreaterThan"
  threshold = 75
  aggregation = "Average"
  period = "PT5M"

  email_action {
    send_to_service_owners = false
    custom_emails = [
      "[email protected]",
    ]
  }

  webhook_action {
    service_uri = "https://example.com/some-url"
      properties = {
        severity = "incredible"
        acceptance_test = "true"
      }
  }
}

उदाहरण उपयोग (SQL डेटाबेस का संग्रहण उपयोग)

resource "azurerm_metric_alertrule" "test" {
  name = "${azurerm_sql_database.test.name}-storage"
  resource_group_name = "${azurerm_resource_group.test.name}"
  location = "${azurerm_resource_group.test.location}"

  description = "An alert rule to watch the metric Storage"

  enabled = true

  resource_id = "${azurerm_sql_database.test.id}"
  metric_name = "storage"
  operator = "GreaterThan"
  threshold = 1073741824
  aggregation = "Maximum"
  period = "PT10M"

  email_action {
    send_to_service_owners = false
    custom_emails = [
      "[email protected]",
    ]
  }

  webhook_action {
    service_uri = "https://example.com/some-url"
      properties = {
        severity = "incredible"
        acceptance_test = "true"
      }
  }
}

तर्क संदर्भ

निम्नलिखित तर्क समर्थित हैं:

  • name - (आवश्यक) चेतावनी नियम का नाम निर्दिष्ट करता है। इस परिवर्तन से एक नया संसाधन बनने के लिए बाध्य होता है।

  • resource_group_name - (आवश्यक) संसाधन समूह का नाम जिसमें अलर्ट नियम बनाना है। इस परिवर्तन से एक नया संसाधन बनने के लिए बाध्य होता है।

  • location - (आवश्यक) समर्थित Azure स्थान निर्दिष्ट करता है जहाँ संसाधन मौजूद है। इस परिवर्तन से एक नया संसाधन बनने के लिए बाध्य होता है।

  • description - (वैकल्पिक) चेतावनी ईमेल में शामिल किए जाने वाले सतर्क नियम का एक क्रिया विवरण।

  • enabled - (वैकल्पिक) यदि true , तो सतर्क नियम सक्षम है। true अवहेलना।

  • resource_id - (आवश्यक) सतर्क नियम द्वारा मॉनिटर किए गए संसाधन की ID।

  • metric_name - (आवश्यक) वह मीट्रिक जो नियम को मॉनिटर करता है उसे परिभाषित करता है।

  • operator - (आवश्यक) ऑपरेटर मीट्रिक डेटा और थ्रेशोल्ड की तुलना करता था। संभावित मूल्य GreaterThan , GreaterThanOrEqual , LessThan , और LessThanOrEqual

  • threshold - (आवश्यक) चेतावनी को सक्रिय करने वाला दहलीज मान।

  • period - (आवश्यक) आईएसओ 8601 अवधि प्रारूप में स्वरूपित समय की अवधि जिसका उपयोग थ्रेशोल्ड पर आधारित चेतावनी गतिविधि की निगरानी के लिए किया जाता है। अवधि 5 मिनट से 1 दिन के बीच होनी चाहिए।

  • aggregation - (आवश्यक) परिभाषित करता है कि समय के साथ मीट्रिक डेटा को कैसे संयोजित किया जाता है। संभावित मूल्य Average , Minimum , Maximum , Total और Last

  • email_action - (वैकल्पिक) नीचे के रूप में एक email_action ब्लॉक।

  • webhook_action - (वैकल्पिक) नीचे के रूप में एक webhook_action ब्लॉक।

  • tags - (वैकल्पिक) संसाधन को असाइन करने के लिए टैग की मैपिंग। इस परिवर्तन से एक नया संसाधन बनने के लिए बाध्य होता है।

email_action निम्नलिखित का समर्थन करता है:

  • send_to_service_owners - (वैकल्पिक) यदि true , तो अलर्ट के ट्रिगर होने पर सदस्यता के प्रशासक (सेवा और सह-व्यवस्थापक) को सूचित किया जाता है। false अवहेलना करता false

  • custom_emails - (वैकल्पिक) चेतावनी ट्रिगर होने पर अधिसूचित किए जाने वाले ईमेल पतों की एक सूची।

webhook_action निम्नलिखित का समर्थन करता है:

  • service_uri - (आवश्यक) चेतावनी ट्रिगर होने पर नोटिफ़िकेशन को POST करने के लिए webhook की सेवा uri।

  • properties - (वैकल्पिक) webhook POST ऑपरेशन पेलोड के साथ शामिल करने के लिए कस्टम गुणों का एक शब्दकोश।

संदर्भ संदर्भित करता है

निम्नलिखित विशेषताएँ निर्यात की जाती हैं:

  • id - अलर्ट नियम की आईडी।

आयात

मीट्रिक resource id नियमों को resource id का उपयोग करके आयात किया जा सकता है, जैसे

terraform import azurerm_metric_alertrule.alertrule1 /subscriptions/00000000-0000-0000-0000-000000000000/resourceGroups/mygroup1/providers/microsoft.insights/alertrules/alertrule1