Terraform 0.11

azurerm_packet_capture




terraform

azurerm_packet_capture

किसी नेटवर्क वॉचर का उपयोग करके वर्चुअल मशीन के खिलाफ पैकेट कैप्चरिंग कॉन्फ़िगर करता है।

उदाहरण उपयोग

resource "azurerm_resource_group" "test" {
  name = "packet-capture-rg"
  location = "West Europe"
}

resource "azurerm_network_watcher" "test" {
  name                = "network-watcher"
  location            = "${azurerm_resource_group.test.location}"
  resource_group_name = "${azurerm_resource_group.test.name}"
}

resource "azurerm_virtual_network" "test" {
  name = "production-network"
  address_space = ["10.0.0.0/16"]
  location = "${azurerm_resource_group.test.location}"
  resource_group_name = "${azurerm_resource_group.test.name}"
}

resource "azurerm_subnet" "test" {
  name = "internal"
  resource_group_name = "${azurerm_resource_group.test.name}"
  virtual_network_name = "${azurerm_virtual_network.test.name}"
  address_prefix = "10.0.2.0/24"
}

resource "azurerm_network_interface" "test" {
  name = "pctest-nic"
  location = "${azurerm_resource_group.test.location}"
  resource_group_name = "${azurerm_resource_group.test.name}"

  ip_configuration {
    name = "testconfiguration1"
    subnet_id = "${azurerm_subnet.test.id}"
    private_ip_address_allocation = "dynamic"
  }
}

resource "azurerm_virtual_machine" "test" {
  name = "pctest-vm"
  location = "${azurerm_resource_group.test.location}"
  resource_group_name = "${azurerm_resource_group.test.name}"
  network_interface_ids = ["${azurerm_network_interface.test.id}"]
  vm_size = "Standard_F2"

  storage_image_reference {
    publisher = "Canonical"
    offer = "UbuntuServer"
    sku = "16.04-LTS"
    version = "latest"
  }

  storage_os_disk {
    name = "osdisk"
    caching = "ReadWrite"
    create_option = "FromImage"
    managed_disk_type = "Standard_LRS"
  }

  os_profile {
    computer_name = "pctest-vm"
    admin_username = "testadmin"
    admin_password = "Password1234!"
  }

  os_profile_linux_config {
    disable_password_authentication = false
  }
}

resource "azurerm_virtual_machine_extension" "test" {
  name                       = "network-watcher"
  location                   = "${azurerm_resource_group.test.location}"
  resource_group_name        = "${azurerm_resource_group.test.name}"
  virtual_machine_name       = "${azurerm_virtual_machine.test.name}"
  publisher                  = "Microsoft.Azure.NetworkWatcher"
  type                       = "NetworkWatcherAgentLinux"
  type_handler_version       = "1.4"
  auto_upgrade_minor_version = true
}


resource "azurerm_storage_account" "test" {
  name = "pctestsa"
  resource_group_name = "${azurerm_resource_group.test.name}"
  location = "${azurerm_resource_group.test.location}"
  account_tier = "Standard"
  account_replication_type = "LRS"
}

resource "azurerm_packet_capture" "test" {
  name                 = "pctestcapture"
  network_watcher_name = "${azurerm_network_watcher.test.name}"
  resource_group_name  = "${azurerm_resource_group.test.name}"
  target_resource_id   = "${azurerm_virtual_machine.test.id}"

  storage_location {
    storage_account_id = "${azurerm_storage_account.test.id}"
  }

  depends_on = ["azurerm_virtual_machine_extension.test"]
}

तर्क संदर्भ

निम्नलिखित तर्क समर्थित हैं:

  • name - (आवश्यक) इस पैकेट कैप्चर के लिए उपयोग किया जाने वाला नाम। इस परिवर्तन से एक नया संसाधन बनने के लिए बाध्य होता है।

  • network_watcher_name - (आवश्यक) नेटवर्क वॉचर का नाम। इस परिवर्तन से एक नया संसाधन बनने के लिए बाध्य होता है।

  • resource_group_name - (आवश्यक) संसाधन समूह का नाम जिसमें नेटवर्क वॉचर मौजूद है। इस परिवर्तन से एक नया संसाधन बनने के लिए बाध्य होता है।

  • target_resource_id - (आवश्यक) पैकेट से कैप्चर करने के लिए संसाधन की ID। इस परिवर्तन से एक नया संसाधन बनने के लिए बाध्य होता है।

  • maximum_bytes_per_packet - (वैकल्पिक) प्रति पैकेट कैप्चर किए गए बाइट्स की संख्या। शेष बाइट्स को काट दिया जाता है। डिफॉल्ट्स टू 0 (संपूर्ण पैकेट कैप्चर)। इस परिवर्तन से एक नया संसाधन बनने के लिए बाध्य होता है।

  • maximum_bytes_per_session - (वैकल्पिक) बाइट्स में कैप्चर का अधिकतम आकार। 1073741824 (1 जीबी) में चूक। इस परिवर्तन से एक नया संसाधन बनने के लिए बाध्य होता है।

  • maximum_capture_duration - (वैकल्पिक) सेकंड में कैप्चर सत्र की अधिकतम अवधि। 18000 (5 घंटे) के लिए चूक। इस परिवर्तन से एक नया संसाधन बनने के लिए बाध्य होता है।

  • storage_location - (आवश्यक) एक storage_location ब्लॉक जैसा कि नीचे परिभाषित किया गया है। इस परिवर्तन से एक नया संसाधन बनने के लिए बाध्य होता है।

  • filter - (वैकल्पिक) नीचे दिए गए अनुसार एक या अधिक filter ब्लॉक। इस परिवर्तन से एक नया संसाधन बनने के लिए बाध्य होता है।

एक storage_location ब्लॉक में शामिल हैं:

  • file_path - (वैकल्पिक) लक्ष्यीकरण VM पर एक मान्य स्थानीय पथ। कैप्चर फ़ाइल (* .cap) का नाम शामिल करना चाहिए। लिनक्स वर्चुअल मशीन के लिए इसे /var/captures शुरू करना होगा।

  • storage_account_id - (वैकल्पिक) पैकेट कैप्चर सेशन को बचाने के लिए स्टोरेज अकाउंट की आईडी

एक filter ब्लॉक में शामिल हैं:

  • local_ip_address - (वैकल्पिक) स्थानीय IP पता फ़िल्टर किया जाना है। संकेतन: एकल पता प्रविष्टि के लिए "127.0.0.1"। रेंज के लिए "127.0.0.1-127.0.0.255"। एकाधिक प्रविष्टियों के लिए "127.0.0.1; 127.0.0.5"। कई श्रेणियां वर्तमान में समर्थित नहीं हैं। वर्तमान में समर्थित नहीं कई प्रविष्टियों के साथ मिक्सिंग रेंज। इस परिवर्तन से एक नया संसाधन बनने के लिए बाध्य होता है।

  • local_port - (वैकल्पिक) जिस स्थानीय पोर्ट को फ़िल्टर किया जाना है। संकेतन: सिंगल पोर्ट एंट्री के लिए "80"। रेंज के लिए "80-85"। "80; 443;" कई प्रविष्टियों के लिए। कई श्रेणियां वर्तमान में समर्थित नहीं हैं। वर्तमान में समर्थित नहीं कई प्रविष्टियों के साथ मिक्सिंग रेंज। इस परिवर्तन से एक नया संसाधन बनने के लिए बाध्य होता है।

  • protocol - (आवश्यक) प्रोटोकॉल को फ़िल्टर किया जाए। संभावित मानों में Any शामिल है, TCP और UDP । इस परिवर्तन से एक नया संसाधन बनने के लिए बाध्य होता है।

  • remote_ip_address - (वैकल्पिक) रिमोट आईपी एड्रेस को फ़िल्टर किया जाना है। संकेतन: एकल पता प्रविष्टि के लिए "127.0.0.1"। रेंज के लिए "127.0.0.1-127.0.0.255"। "127.0.0.1; 127.0.0.5," कई प्रविष्टियों के लिए। कई श्रेणियां वर्तमान में समर्थित नहीं हैं। वर्तमान में समर्थित कई प्रविष्टियों के साथ मिक्सिंग रेंज .. इस परिवर्तन को एक नया संसाधन बनाने के लिए मजबूर करता है।

  • remote_port - (वैकल्पिक) जिस रिमोट पोर्ट को फ़िल्टर किया जाना है। संकेतन: सिंगल पोर्ट एंट्री के लिए "80"। रेंज के लिए "80-85"। "80; 443;" कई प्रविष्टियों के लिए। कई श्रेणियां वर्तमान में समर्थित नहीं हैं। वर्तमान में समर्थित नहीं कई प्रविष्टियों के साथ मिक्सिंग रेंज। इस परिवर्तन से एक नया संसाधन बनने के लिए बाध्य होता है।

संदर्भ संदर्भित करता है

निम्नलिखित विशेषताएँ निर्यात की जाती हैं:

  • id - पैकेट कैप्चर आईडी।

  • storage_location - (आवश्यक) एक storage_location ब्लॉक जैसा कि नीचे परिभाषित किया गया है।

एक storage_location ब्लॉक में शामिल हैं:

  • storage_path - पैकेट कैप्चर को बचाने के लिए स्टोरेज पथ का URI।

आयात

पैकेट कैप्चर को resource id का उपयोग करके आयात किया जा सकता है, जैसे

terraform import azurerm_packet_capture.capture1 /subscriptions/00000000-0000-0000-0000-000000000000/resourceGroups/mygroup1/providers/Microsoft.Network/networkWatchers/watcher1/packetCaptures/capture1