Terraform 0.11

azurerm_redis_firewall_rule




terraform

azurerm_redis_firewall_rule

एक प्रीमियम रेडिस कैश से जुड़े फ़ायरवॉल नियम का प्रबंधन करता है।

उदाहरण उपयोग

resource "random_id" "server" {
  keepers = {
    azi_id = 1
  }

  byte_length = 8
}

resource "azurerm_resource_group" "test" {
  name     = "redis-resourcegroup"
  location = "West Europe"
}

resource "azurerm_redis_cache" "test" {
  name                = "redis${random_id.server.hex}"
  location            = "${azurerm_resource_group.test.location}"
  resource_group_name = "${azurerm_resource_group.test.name}"
  capacity            = 1
  family              = "P"
  sku_name            = "Premium"
  enable_non_ssl_port = false

  redis_configuration {
    maxclients         = 256
    maxmemory_reserved = 2
    maxmemory_delta    = 2
    maxmemory_policy   = "allkeys-lru"
  }
}

resource "azurerm_redis_firewall_rule" "test" {
  name                = "someIPrange"
  redis_cache_name    = "${azurerm_redis_cache.test.name}"
  resource_group_name = "${azurerm_resource_group.test.name}"
  start_ip            = "1.2.3.4"
  end_ip              = "2.3.4.5"
}

तर्क संदर्भ

निम्नलिखित तर्क समर्थित हैं:

  • name - (आवश्यक) फ़ायरवॉल नियम का नाम। इस परिवर्तन से एक नया संसाधन बनने के लिए बाध्य होता है।

  • redis_cache_name - (आवश्यक) redis_cache_name कैश का नाम। इस परिवर्तन से एक नया संसाधन बनने के लिए बाध्य होता है।

  • resource_group_name - (आवश्यक) संसाधन समूह का नाम जिसमें यह Redis Cache मौजूद है।

  • start_ip - (आवश्यक) श्रेणी में शामिल न्यूनतम आईपी पता

  • end_ip - (आवश्यक) श्रेणी में शामिल उच्चतम IP पता।

संदर्भ संदर्भित करता है

निम्नलिखित विशेषताएँ निर्यात की जाती हैं:

  • id - रेडिस फ़ायरवॉल नियम आईडी।

आयात

Redis फ़ायरवॉल नियम resource id का उपयोग करके आयात किया जा सकता है, जैसे

terraform import azurerm_redis_firewall_rule.rule1 /subscriptions/00000000-0000-0000-0000-000000000000/resourceGroups/group1/providers/Microsoft.Cache/Redis/cache1/firewallRules/rule1