Terraform 0.11

azurestack_virtual_machine




terraform

azurestack_virtual_machine

एक वर्चुअल मशीन बनाएँ।

resource "azurestack_resource_group" "test" {
  name     = "acctestrg"
  location = "West US 2"
}

resource "azurestack_virtual_network" "test" {
  name                = "acctvn"
  address_space       = ["10.0.0.0/16"]
  location            = "${azurestack_resource_group.test.location}"
  resource_group_name = "${azurestack_resource_group.test.name}"
}

resource "azurestack_subnet" "test" {
  name                 = "acctsub"
  resource_group_name  = "${azurestack_resource_group.test.name}"
  virtual_network_name = "${azurestack_virtual_network.test.name}"
  address_prefix       = "10.0.2.0/24"
}

resource "azurestack_network_interface" "test" {
  name                = "acctni"
  location            = "${azurestack_resource_group.test.location}"
  resource_group_name = "${azurestack_resource_group.test.name}"

  ip_configuration {
    name                          = "testconfiguration1"
    subnet_id                     = "${azurestack_subnet.test.id}"
    private_ip_address_allocation = "dynamic"
  }
}

resource "azurestack_managed_disk" "test" {
  name                 = "datadisk_existing"
  location             = "${azurestack_resource_group.test.location}"
  resource_group_name  = "${azurestack_resource_group.test.name}"
  storage_account_type = "Standard_LRS"
  create_option        = "Empty"
  disk_size_gb         = "1023"
}

resource "azurestack_virtual_machine" "test" {
  name                  = "acctvm"
  location              = "${azurestack_resource_group.test.location}"
  resource_group_name   = "${azurestack_resource_group.test.name}"
  network_interface_ids = ["${azurestack_network_interface.test.id}"]
  vm_size               = "Standard_DS1_v2"

  # Uncomment this line to delete the OS disk automatically when deleting the VM
  # delete_os_disk_on_termination = true

  # Uncomment this line to delete the data disks automatically when deleting the VM
  # delete_data_disks_on_termination = true

  storage_image_reference {
    publisher = "Canonical"
    offer     = "UbuntuServer"
    sku       = "16.04-LTS"
    version   = "latest"
  }

  storage_os_disk {
    name              = "myosdisk1"
    caching           = "ReadWrite"
    create_option     = "FromImage"
    managed_disk_type = "Standard_LRS"
  }

  # Optional data disks
  storage_data_disk {
    name              = "datadisk_new"
    managed_disk_type = "Standard_LRS"
    create_option     = "Empty"
    lun               = 0
    disk_size_gb      = "1023"
  }

  storage_data_disk {
    name            = "${azurestack_managed_disk.test.name}"
    managed_disk_id = "${azurestack_managed_disk.test.id}"
    create_option   = "Attach"
    lun             = 1
    disk_size_gb    = "${azurestack_managed_disk.test.disk_size_gb}"
  }

  os_profile {
    computer_name  = "hostname"
    admin_username = "testadmin"
    admin_password = "Password1234!"
  }

  os_profile_linux_config {
    disable_password_authentication = false
  }

  tags {
    environment = "staging"
  }
}
#Assume that custom image has been already created in the 'customimage' resource group
data "azurestack_resource_group" "image" {
  name = "customimage"
}

data "azurestack_image" "image" {
  name                = "myCustomImage"
  resource_group_name = "${data.azurestack_resource_group.image.name}"
}

resource "azurestack_resource_group" "test" {
  name     = "acctestrg"
  location = "West US 2"
}

resource "azurestack_virtual_network" "test" {
  name                = "acctvn"
  address_space       = ["10.0.0.0/16"]
  location            = "${azurestack_resource_group.test.location}"
  resource_group_name = "${azurestack_resource_group.test.name}"
}

resource "azurestack_subnet" "test" {
  name                 = "acctsub"
  resource_group_name  = "${azurestack_resource_group.test.name}"
  virtual_network_name = "${azurestack_virtual_network.test.name}"
  address_prefix       = "10.0.2.0/24"
}

resource "azurestack_network_interface" "test" {
  name                = "acctni"
  location            = "${azurestack_resource_group.test.location}"
  resource_group_name = "${azurestack_resource_group.test.name}"

  ip_configuration {
    name                          = "testconfiguration1"
    subnet_id                     = "${azurestack_subnet.test.id}"
    private_ip_address_allocation = "dynamic"
  }
}

resource "azurestack_managed_disk" "test" {
  name                 = "datadisk_existing"
  location             = "${azurestack_resource_group.test.location}"
  resource_group_name  = "${azurestack_resource_group.test.name}"
  storage_account_type = "Standard_LRS"
  create_option        = "Empty"
  disk_size_gb         = "1023"
}

resource "azurestack_virtual_machine" "test" {
  name                  = "acctvm"
  location              = "${azurestack_resource_group.test.location}"
  resource_group_name   = "${azurestack_resource_group.test.name}"
  network_interface_ids = ["${azurestack_network_interface.test.id}"]
  vm_size               = "Standard_DS1_v2"

  # Uncomment this line to delete the OS disk automatically when deleting the VM
  # delete_os_disk_on_termination = true

  # Uncomment this line to delete the data disks automatically when deleting the VM
  # delete_data_disks_on_termination = true

  storage_image_reference {
    id="${data.azurestack_image.image.id}"
  }

  storage_os_disk {
    name              = "myosdisk1"
    caching           = "ReadWrite"
    create_option     = "FromImage"
    managed_disk_type = "Standard_LRS"
  }

  # Optional data disks
  storage_data_disk {
    name              = "datadisk_new"
    managed_disk_type = "Standard_LRS"
    create_option     = "Empty"
    lun               = 0
    disk_size_gb      = "1023"
  }

  storage_data_disk {
    name            = "${azurestack_managed_disk.test.name}"
    managed_disk_id = "${azurestack_managed_disk.test.id}"
    create_option   = "Attach"
    lun             = 1
    disk_size_gb    = "${azurestack_managed_disk.test.disk_size_gb}"
  }

  os_profile {
    computer_name  = "hostname"
    admin_username = "testadmin"
    admin_password = "Password1234!"
  }

  os_profile_linux_config {
    disable_password_authentication = false
  }

  tags {
    environment = "staging"
  }
}

उदाहरण अप्रबंधित डिस्क के साथ उपयोग

resource "azurestack_resource_group" "test" {
  name     = "acctestrg"
  location = "West US"
}

resource "azurestack_virtual_network" "test" {
  name                = "acctvn"
  address_space       = ["10.0.0.0/16"]
  location            = "${azurestack_resource_group.test.location}"
  resource_group_name = "${azurestack_resource_group.test.name}"
}

resource "azurestack_subnet" "test" {
  name                 = "acctsub"
  resource_group_name  = "${azurestack_resource_group.test.name}"
  virtual_network_name = "${azurestack_virtual_network.test.name}"
  address_prefix       = "10.0.2.0/24"
}

resource "azurestack_network_interface" "test" {
  name                = "acctni"
  location            = "${azurestack_resource_group.test.location}"
  resource_group_name = "${azurestack_resource_group.test.name}"

  ip_configuration {
    name                          = "testconfiguration1"
    subnet_id                     = "${azurestack_subnet.test.id}"
    private_ip_address_allocation = "dynamic"
  }
}

resource "azurestack_storage_account" "test" {
  name                     = "accsa"
  resource_group_name      = "${azurestack_resource_group.test.name}"
  location                 = "${azurestack_resource_group.test.location}"
  account_tier             = "Standard"
  account_replication_type = "LRS"

  tags {
    environment = "staging"
  }
}

resource "azurestack_storage_container" "test" {
  name                  = "vhds"
  resource_group_name   = "${azurestack_resource_group.test.name}"
  storage_account_name  = "${azurestack_storage_account.test.name}"
  container_access_type = "private"
}

resource "azurestack_virtual_machine" "test" {
  name                  = "acctvm"
  location              = "${azurestack_resource_group.test.location}"
  resource_group_name   = "${azurestack_resource_group.test.name}"
  network_interface_ids = ["${azurestack_network_interface.test.id}"]
  vm_size               = "Standard_F2"

  # Uncomment this line to delete the OS disk automatically when deleting the VM
  # delete_os_disk_on_termination = true

  # Uncomment this line to delete the data disks automatically when deleting the VM
  # delete_data_disks_on_termination = true

  storage_image_reference {
    publisher = "Canonical"
    offer     = "UbuntuServer"
    sku       = "16.04-LTS"
    version   = "latest"
  }

  storage_os_disk {
    name          = "myosdisk1"
    vhd_uri       = "${azurestack_storage_account.test.primary_blob_endpoint}${azurestack_storage_container.test.name}/myosdisk1.vhd"
    caching       = "ReadWrite"
    create_option = "FromImage"
  }

  # Optional data disks
  storage_data_disk {
    name          = "datadisk0"
    vhd_uri       = "${azurestack_storage_account.test.primary_blob_endpoint}${azurestack_storage_container.test.name}/datadisk0.vhd"
    disk_size_gb  = "1023"
    create_option = "Empty"
    lun           = 0
  }

  os_profile {
    computer_name  = "hostname"
    admin_username = "testadmin"
    admin_password = "Password1234!"
  }

  os_profile_linux_config {
    disable_password_authentication = false
  }

  tags {
    environment = "staging"
  }
}

तर्क संदर्भ

निम्नलिखित तर्क समर्थित हैं:

  • name - (आवश्यक) वर्चुअल मशीन संसाधन का नाम निर्दिष्ट करता है। इस परिवर्तन से एक नया संसाधन बनने के लिए बाध्य होता है।
  • resource_group_name - (आवश्यक) संसाधन समूह का नाम जिसमें वर्चुअल मशीन बनाई जाती है।
  • location - (आवश्यक) समर्थित Azure स्थान निर्दिष्ट करता है जहाँ संसाधन मौजूद है। इस परिवर्तन से एक नया संसाधन बनने के लिए बाध्य होता है।
  • plan - (वैकल्पिक) नीचे दिए गए दस्तावेज के रूप में एक योजना खंड।
  • availability_set_id - (वैकल्पिक) वर्चुअल मशीन बनाने के लिए उपलब्धता सेट की आईडी
  • boot_diagnostics - (वैकल्पिक) नीचे उल्लिखित एक बूट डायग्नोस्टिक्स प्रोफाइल ब्लॉक है।
  • vm_size - (आवश्यक) वर्चुअल मशीन का आकार निर्दिष्ट करता है।
  • storage_image_reference - (वैकल्पिक) नीचे के रूप में एक संग्रहण छवि संदर्भ ब्लॉक प्रलेखित है।
  • storage_os_disk - (आवश्यक) नीचे के रूप में एक स्टोरेज OS डिस्क ब्लॉक।
  • delete_os_disk_on_termination - (वैकल्पिक) VM डिस्क हटाए जाने पर OS डिस्क VHD ब्लॉब या प्रबंधित डिस्क को हटाने में सक्षम करने के लिए ध्वज
  • storage_data_disk - (वैकल्पिक) नीचे संदर्भित के रूप में संग्रहण डेटा डिस्क ब्लॉक की एक सूची।
  • delete_data_disks_on_termination - (वैकल्पिक) संग्रह डेटा डिस्क को हटाने में सक्षम करने के लिए ध्वज VHD ब्लूब या प्रबंधित डिस्क जब VM को हटा दिया जाता है, तो false
  • os_profile - (वैकल्पिक) एक ओएस प्रोफाइल ब्लॉक जैसा कि नीचे प्रलेखित है। जब आवश्यक हो तो FromImage ब्लॉक में create_option FromImage सेट हो FromImage
  • identity - (वैकल्पिक) नीचे दिए गए दस्तावेज के रूप में एक पहचान ब्लॉक।

  • license_type - (वैकल्पिक, जब एक विंडोज़ मशीन) Windows OS लाइसेंस प्रकार निर्दिष्ट करता है। यदि आपूर्ति की जाती है, तो केवल अनुमत मान Windows_Client और Windows_Server

  • os_profile_windows_config - (आवश्यक है, जब एक विंडोज मशीन) एक विंडोज os_profile_windows_config को नीचे प्रलेखित किया गया है।

  • os_profile_linux_config - (आवश्यक है, जब एक लिनक्स मशीन) एक लिनक्स विन्यास नीचे के रूप में प्रलेखित है।

  • os_profile_secrets - (वैकल्पिक) नीचे प्रलेखित गुप्त ब्लॉकों का एक संग्रह।

  • network_interface_ids - (आवश्यक) वर्चुअल मशीन से जुड़े नेटवर्क इंटरफेस के लिए संसाधन आईडी की सूची निर्दिष्ट करता है।

  • primary_network_interface_id - (वैकल्पिक) वर्चुअल मशीन से जुड़े प्राथमिक नेटवर्क इंटरफ़ेस के लिए संसाधन ID निर्दिष्ट करता है।

  • tags - (वैकल्पिक) संसाधन को असाइन करने के लिए टैग की मैपिंग।

अलग-अलग उदाहरण कॉन्फ़िगरेशन के बारे में अधिक जानकारी के लिए, कृपया azure दस्तावेज़ीकरण देखें

Plan निम्नलिखित का समर्थन करती है:

  • name - (आवश्यक) बाजार से छवि का नाम निर्दिष्ट करता है।
  • publisher - (आवश्यक) छवि के प्रकाशक को निर्दिष्ट करता है।
  • product - (आवश्यक) बाजार से छवि के उत्पाद को निर्दिष्ट करता है।

boot_diagnostics निम्नलिखित का समर्थन करता है:

  • enabled : (आवश्यक) क्या वर्चुअल मशीन के लिए बूट डायग्नोस्टिक्स को सक्षम करना है।
  • storage_uri : (आवश्यक) वर्चुअल मशीन की डायग्नोस्टिक फ़ाइलों को रखने के लिए स्टोरेज अकाउंट के लिए बूँद एंडपॉइंट। यह एक भंडारण खाते की जड़ होना चाहिए, न कि भंडारण कंटेनर।

storage_image_reference निम्नलिखित का समर्थन करता है:

  • id - (वैकल्पिक) उदाहरण के लिए, वर्चुअल मशीन बनाने के लिए उपयोग की जाने वाली (कस्टम) छवि की आईडी निर्दिष्ट करता है:
resource "azurestack_image" "test" {
    name = "test"
  ...
}

resource "azurestack_virtual_machine" "test" {
    name = "test"
  ...

    storage_image_reference {
        id = "${azurestack_image.test.id}"
    }

...
  • publisher - (आवश्यक है, जब छवि संसाधन का उपयोग नहीं कर रहा है) वर्चुअल मशीन बनाने के लिए प्रयुक्त छवि के प्रकाशक को निर्दिष्ट करता है। इस परिवर्तन से एक नया संसाधन बनने के लिए बाध्य होता है।
  • offer - (आवश्यक है, जब छवि संसाधन का उपयोग नहीं कर रहा है) वर्चुअल मशीन बनाने के लिए उपयोग की जाने वाली छवि के प्रस्ताव को निर्दिष्ट करता है। इस परिवर्तन से एक नया संसाधन बनने के लिए बाध्य होता है।
  • sku - (आवश्यक है, जब छवि संसाधन का उपयोग नहीं कर रहा है) वर्चुअल मशीन बनाने के लिए उपयोग की गई छवि का SKU निर्दिष्ट करता है। इस परिवर्तन से एक नया संसाधन बनने के लिए बाध्य होता है।
  • version - (ऑप्शनल) वर्चुअल मशीन बनाने के लिए इस्तेमाल की गई इमेज के वर्जन को निर्दिष्ट करता है। इस परिवर्तन से एक नया संसाधन बनने के लिए बाध्य होता है।

storage_os_disk निम्नलिखित का समर्थन करता है:

  • name - (आवश्यक) डिस्क का नाम निर्दिष्ट करता है।
  • vhd_uri - (वैकल्पिक) vhd uri को निर्दिष्ट करता है। इस परिवर्तन से एक नया संसाधन बनने के लिए बाध्य होता है। प्रबंधित डिस्क के साथ उपयोग नहीं किया जा सकता है।
  • managed_disk_type - (वैकल्पिक) बनाने के लिए प्रबंधित डिस्क का प्रकार निर्दिष्ट करता है। मान आपको या तो Standard_LRS या Premium_LRS होना चाहिए। vhd_uri निर्दिष्ट होने पर उपयोग नहीं किया जा सकता है।
  • managed_disk_id - (वैकल्पिक) आईडी द्वारा उपयोग के लिए एक मौजूदा प्रबंधित डिस्क निर्दिष्ट करता है। केवल तभी उपयोग किया जा सकता है जब create_option Attachvhd_uri निर्दिष्ट होने पर उपयोग नहीं किया जा सकता है।
  • create_option - (आवश्यक) निर्दिष्ट करता है कि वर्चुअल मशीन कैसे बनाई जानी चाहिए। संभावित मान Attach (केवल प्रबंधित डिस्क) और FromImage
  • caching - (वैकल्पिक) कैशिंग आवश्यकताओं को निर्दिष्ट करता है।
  • image_uri - (वैकल्पिक) रूप में प्रकाशक_नाम में image_uri निर्दिष्ट करता है: प्रस्ताव: स्कस: संस्करण। image_uri एक कस्टम VM छवि के VHD uri को क्लोन करने के लिए भी निर्दिष्ट कर सकता है। जब एक कस्टम डिस्क छवि का क्लोनिंग किया जाता है तो नीचे दिया गया os_type आवश्यक हो जाता है।
  • os_type - (वैकल्पिक) ऑपरेटिंग सिस्टम को निर्दिष्ट करता है प्रकार, मान्य मान विंडोज़, लिनक्स हैं।
  • disk_size_gb - (वैकल्पिक) गीगाबाइट में ओएस डिस्क के आकार को निर्दिष्ट करता है।

storage_data_disk निम्नलिखित का समर्थन करता है:

  • name - (आवश्यक) डेटा डिस्क का नाम निर्दिष्ट करता है।
  • vhd_uri - (वैकल्पिक) भंडारण में उस स्थान के vhd_uri निर्दिष्ट करता है जहां वर्चुअल मशीन के लिए vhd रखा जाना चाहिए। प्रबंधित डिस्क के साथ उपयोग नहीं किया जा सकता है।
  • managed_disk_type - (वैकल्पिक) बनाने के लिए प्रबंधित डिस्क का प्रकार निर्दिष्ट करता है। मान आपको या तो Standard_LRS या Premium_LRS होना चाहिए। vhd_uri निर्दिष्ट होने पर उपयोग नहीं किया जा सकता है।
  • managed_disk_id - (वैकल्पिक) आईडी द्वारा उपयोग के लिए एक मौजूदा प्रबंधित डिस्क निर्दिष्ट करता है। केवल तभी उपयोग किया जा सकता है जब create_option Attachvhd_uri निर्दिष्ट होने पर उपयोग नहीं किया जा सकता है।
  • create_option - (आवश्यक) निर्दिष्ट करता है कि डेटा डिस्क कैसे बनाई जानी चाहिए। संभावित मूल्य Attach , FromImage और Empty
  • disk_size_gb - (आवश्यक) गीगाबाइट में डेटा डिस्क का आकार निर्दिष्ट करता है।
  • caching - (वैकल्पिक) कैशिंग आवश्यकताओं को निर्दिष्ट करता है।
  • lun - (आवश्यक) डेटा डिस्क की तार्किक इकाई संख्या निर्दिष्ट करता है।

os_profile निम्नलिखित का समर्थन करता है:

  • computer_name - (आवश्यक) वर्चुअल मशीन का नाम निर्दिष्ट करता है।
  • admin_username - (आवश्यक) व्यवस्थापक खाते का नाम निर्दिष्ट करता है।
  • admin_password - (विंडोज के लिए आवश्यक, लिनक्स के लिए वैकल्पिक) व्यवस्थापक खाते का पासवर्ड निर्दिष्ट करता है।
  • custom_data - (वैकल्पिक) मशीन को आपूर्ति करने के लिए कस्टम डेटा निर्दिष्ट करता है। लिनक्स-आधारित सिस्टम पर, इसे क्लाउड-इनिट स्क्रिप्ट के रूप में उपयोग किया जा सकता है। अन्य प्रणालियों पर, इसे डिस्क पर फ़ाइल के रूप में कॉपी किया जाएगा। आंतरिक रूप से, Terraform एपीआई में भेजने से पहले इस मान को आधार बनाएगा। बाइनरी सरणी की अधिकतम लंबाई 65535 बाइट्स है।

identity निम्नलिखित का समर्थन करती है:

  • type - (आवश्यक) वर्चुअल मशीन की पहचान प्रकार निर्दिष्ट करता है। केवल स्वीकार्य मूल्य SystemAssigned । प्रबंधित सेवा को सक्षम करने के लिए वर्चुअल मशीन एक्सटेंशन "ManagedIdentityExtensionForWindows" या "ManagedIdentityExtensionForLinux" को भी वर्चुअल मशीन में जोड़ना होगा। वर्चुअल मशीन बनाए जाने के बाद प्रिंसिपल आईडी को पुनः प्राप्त किया जा सकता है, जैसे
resource "azurestack_virtual_machine" "test" {
  name                = "test"

  identity = {
    type = "SystemAssigned"
  }
}
resource "azurestack_virtual_machine_extension" "test" {
  name                 = "test"
  resource_group_name  = "${azurestack_resource_group.test.name}"
  location             = "${azurestack_resource_group.test.location}"
  virtual_machine_name = "${azurestack_virtual_machine.test.name}"
  publisher            = "Microsoft.ManagedIdentity"
  type                 = "ManagedIdentityExtensionForWindows"
  type_handler_version = "1.0"

  settings = <<SETTINGS
    {
        "port": 50342
    }
SETTINGS
}
output "principal_id" {
  value = "${lookup(azurestack_virtual_machine.test.identity[0], "principal_id")}"
}

os_profile_windows_config निम्नलिखित का समर्थन करता है:

  • provision_vm_agent - (वैकल्पिक) यह मान असत्य को परिभाषित करता है।
  • enable_automatic_upgrades - (वैकल्पिक) यह मान असत्य को enable_automatic_upgrades
  • winrm - (वैकल्पिक) नीचे दस्तावेज के रूप में WinRM कॉन्फ़िगरेशन ब्लॉक का एक संग्रह।
  • additional_unattend_config - (वैकल्पिक) नीचे दस्तावेज के रूप में एक अतिरिक्त अनअटेंडेड कॉन्फ़िगरेशन ब्लॉक।

winrm निम्नलिखित का समर्थन करता है:

  • protocol - (आवश्यक) श्रोता के प्रोटोकॉल को निर्दिष्ट करता है
  • certificate_url - (वैकल्पिक) उस प्रमाणपत्र के URL को निर्दिष्ट करता है जिसके साथ नई वर्चुअल मशीन का प्रावधान किया गया है।

additional_unattend_config निम्नलिखित का समर्थन करता है:

  • pass - (आवश्यक) उस पास का नाम निर्दिष्ट करता है जो सामग्री पर लागू होता है। एकमात्र स्वीकार्य मूल्य oobeSystem
  • component - (आवश्यक) निर्दिष्ट सामग्री के साथ कॉन्फ़िगर करने के लिए घटक का नाम निर्दिष्ट करता है। एकमात्र स्वीकार्य मूल्य Microsoft-Windows-Shell-Setup
  • setting_name - (आवश्यक) उस सेटिंग का नाम निर्दिष्ट करता है जिसके लिए सामग्री लागू होती है। संभावित मान हैं: FirstLogonCommands और AutoLogon
  • content - (वैकल्पिक) आधार -64 एन्कोडेड XML स्वरूपित सामग्री को निर्दिष्ट करता है जो निर्दिष्ट पथ और घटक के लिए unattend.xml फ़ाइल में जोड़ी जाती है।

os_profile_linux_config निम्नलिखित का समर्थन करता है:

  • disable_password_authentication - (आवश्यक) निर्दिष्ट करता है कि क्या पासवर्ड प्रमाणीकरण अक्षम होना चाहिए। यदि false सेट किया गया false , तो एक admin_password निर्दिष्ट किया जाना चाहिए।
  • ssh_keys - (वैकल्पिक) वर्चुअल मशीन पर रखे key_data लिए path और key_data का संग्रह निर्दिष्ट करता है।

os_profile_secrets निम्नलिखित का समर्थन करता है:

  • source_vault_id - (आवश्यक) उपयोग के लिए प्रमुख वॉल्ट निर्दिष्ट करता है।
  • vault_certificates - (आवश्यक) नीचे दस्तावेज के रूप में वॉल्ट प्रमाणपत्र का एक संग्रह

vault_certificates निम्नलिखित का समर्थन करते हैं:

  • https://<vaultEndpoint>/secrets/<secretName>/<secretVersion> - (आवश्यक) https://<vaultEndpoint>/secrets/<secretName>/<secretVersion> के प्रारूप में कुंजी वॉल्ट रहस्यों के URI को निर्दिष्ट करता है। संग्रहित रहस्य JSON ऑब्जेक्ट का Base64 एन्कोडिंग है, जो UTF-8 में एन्कोडेड है, जिसमें सामग्री होना आवश्यक है
{
  "data":"<Base64-encoded-certificate>",
  "dataType":"pfx",
  "password":"<pfx-file-password>"
}
  • certificate_store - (आवश्यक, विंडोज़ मशीनों पर) प्रमाणपत्र मशीन को वर्चुअल मशीन पर निर्दिष्ट करता है जहाँ प्रमाणपत्र जोड़ा जाना चाहिए।

संदर्भ संदर्भित करता है

निम्नलिखित विशेषताएँ निर्यात की जाती हैं:

  • id - वर्चुअल मशीन आईडी।

आयात

वर्चुअल मशीन को resource id का उपयोग करके आयात किया जा सकता है, जैसे

terraform import azurestack_virtual_machine.test /subscriptions/00000000-0000-0000-0000-000000000000/resourceGroups/mygroup1/providers/microsoft.compute/virtualMachines/machine1