Terraform 0.11

google_compute_url_map




terraform

google_compute_url_map

GCE के भीतर एक URL मैप संसाधन का प्रबंधन करता है। अधिक जानकारी के लिए आधिकारिक दस्तावेज और API

उदाहरण उपयोग

resource "google_compute_url_map" "foobar" {
  name        = "urlmap"
  description = "a description"

  default_service = "${google_compute_backend_service.home.self_link}"

  host_rule {
    hosts        = ["mysite.com"]
    path_matcher = "allpaths"
  }

  path_matcher {
    name            = "allpaths"
    default_service = "${google_compute_backend_service.home.self_link}"

    path_rule {
      paths   = ["/home"]
      service = "${google_compute_backend_service.home.self_link}"
    }

    path_rule {
      paths   = ["/login"]
      service = "${google_compute_backend_service.login.self_link}"
    }

    path_rule {
      paths   = ["/static"]
      service = "${google_compute_backend_bucket.static.self_link}"
    }
  }

  test {
    service = "${google_compute_backend_service.home.self_link}"
    host    = "hi.com"
    path    = "/home"
  }
}

resource "google_compute_backend_service" "login" {
  name        = "login-backend"
  port_name   = "http"
  protocol    = "HTTP"
  timeout_sec = 10

  health_checks = ["${google_compute_http_health_check.default.self_link}"]
}

resource "google_compute_backend_service" "home" {
  name        = "home-backend"
  port_name   = "http"
  protocol    = "HTTP"
  timeout_sec = 10

  health_checks = ["${google_compute_http_health_check.default.self_link}"]
}

resource "google_compute_http_health_check" "default" {
  name               = "test"
  request_path       = "/"
  check_interval_sec = 1
  timeout_sec        = 1
}

resource "google_compute_backend_bucket" "static" {
  name        = "static-asset-backend-bucket"
  bucket_name = "${google_storage_bucket.static.name}"
  enable_cdn  = true
}

resource "google_storage_bucket" "static" {
  name     = "static-asset-bucket"
  location = "US"
}

तर्क संदर्भ

निम्नलिखित तर्क समर्थित हैं:

  • default_service - (आवश्यक) बैकएंड सेवा या बैकेंड बकेट का उपयोग करने के लिए जब दिए गए नियमों में से कोई भी मेल नहीं खाता।

  • name - (आवश्यक) संसाधन के लिए एक अनूठा नाम, जीसीई द्वारा आवश्यक। इस परिवर्तन से एक नया संसाधन बनने के लिए बाध्य होता है।

  • description - (वैकल्पिक) इस संसाधन का एक संक्षिप्त विवरण।

  • host_rule - (वैकल्पिक) मेजबान नियमों की एक सूची। इस प्रकार के कई ब्लॉक की अनुमति है। संरचना नीचे प्रलेखित है।

  • path_matcher - (वैकल्पिक) मिलान करने के लिए पथों की एक सूची। संरचना नीचे प्रलेखित है।

  • project - (वैकल्पिक) उस परियोजना की आईडी जिसमें संसाधन है। यदि यह प्रदान नहीं किया जाता है, तो प्रदाता परियोजना का उपयोग किया जाता है।

  • test - (वैकल्पिक) प्रदर्शन करने के लिए परीक्षण। इस प्रकार के कई ब्लॉक की अनुमति है। संरचना नीचे प्रलेखित है।

host_rule ब्लॉक का समर्थन करता है:

  • hosts (आवश्यक) - मिलान करने के लिए होस्ट पैटर्न की सूची।

  • description - (वैकल्पिक) मेजबान नियम का एक वैकल्पिक विवरण।

  • path_matcher - (आवश्यक) इस होस्ट नियम को लागू करने के लिए path_matcher का नाम।

path_matcher ब्लॉक का समर्थन करता है:

  • name - (आवश्यक) path_matcher संसाधन का नाम।

  • default_service - (आवश्यक) बैकएंड सेवा या बैकेंड बाल्टी का उपयोग करने के लिए यदि दिए गए पथों में से कोई भी मेल नहीं खाता है।

  • description - (वैकल्पिक) मेजबान नियम का एक वैकल्पिक विवरण।

  • path_rule - (वैकल्पिक) पथ नियमों की एक सूची। इस प्रकार के कई ब्लॉक की अनुमति है। संरचना नीचे प्रलेखित है।

path_rule ब्लॉक का समर्थन करता है:

  • paths - (आवश्यक) के विरुद्ध मिलान करने के लिए paths की सूची।

  • service - (आवश्यक) यदि दिए गए रास्तों में से कोई भी मेल खाता है तो बैकएंड सेवा या बैकेंड बकेट का उपयोग करें

test ब्लॉक का समर्थन करता है:

  • service - (आवश्यक) बैकएंड सेवा या बैकेंड बकेट लिंक जो इस परीक्षण से मेल खाना चाहिए।

  • host - (आवश्यक) URL के होस्ट घटक का परीक्षण किया जा रहा है।

  • path - (आवश्यक) URL के पथ घटक का परीक्षण किया जा रहा है।

  • description - (वैकल्पिक) इस परीक्षण का एक वैकल्पिक विवरण।

संदर्भ संदर्भित करता है

ऊपर सूचीबद्ध तर्कों के अलावा, निम्नलिखित गणना की गई विशेषताएँ निर्यात की जाती हैं:

  • fingerprint - इस संसाधन के लिए अद्वितीय फिंगरप्रिंट।

  • map_id - GCE को संसाधन की असाइन की गई आईडी है।

  • self_link - निर्मित संसाधन का URI।

आयात

URL मैप को name का उपयोग करके आयात किया जा सकता है, जैसे

$ terraform import google_compute_url_map.html.foobar foobar

वर्तमान में host_rule , path_matcher और test आयात अभी समर्थित नहीं है।