Terraform 0.11

google_compute_vpn_gateway




terraform

google_compute_vpn_gateway

GCP में चल रहे एक वीपीएन गेटवे का प्रतिनिधित्व करता है। यह वर्चुअल डिवाइस Google द्वारा प्रबंधित है, लेकिन केवल आपके द्वारा उपयोग किया जाता है।

VpnGateway के बारे में अधिक जानकारी प्राप्त करने के लिए, देखें:

उदाहरण उपयोग

resource "google_compute_network" "network1" {
  name       = "network1"
  ipv4_range = "10.120.0.0/16"
}

resource "google_compute_vpn_gateway" "target_gateway" {
  name    = "vpn1"
  network = "${google_compute_network.network1.self_link}"
  region  = "${var.region}"
}

resource "google_compute_address" "vpn_static_ip" {
  name   = "vpn-static-ip"
  region = "${var.region}"
}

resource "google_compute_forwarding_rule" "fr_esp" {
  name        = "fr-esp"
  region      = "${var.region}"
  ip_protocol = "ESP"
  ip_address  = "${google_compute_address.vpn_static_ip.address}"
  target      = "${google_compute_vpn_gateway.target_gateway.self_link}"
}

resource "google_compute_forwarding_rule" "fr_udp500" {
  name        = "fr-udp500"
  region      = "${var.region}"
  ip_protocol = "UDP"
  port_range  = "500"
  ip_address  = "${google_compute_address.vpn_static_ip.address}"
  target      = "${google_compute_vpn_gateway.target_gateway.self_link}"
}

resource "google_compute_forwarding_rule" "fr_udp4500" {
  name        = "fr-udp4500"
  region      = "${var.region}"
  ip_protocol = "UDP"
  port_range  = "4500"
  ip_address  = "${google_compute_address.vpn_static_ip.address}"
  target      = "${google_compute_vpn_gateway.target_gateway.self_link}"
}

resource "google_compute_vpn_tunnel" "tunnel1" {
  name          = "tunnel1"
  region        = "${var.region}"
  peer_ip       = "15.0.0.120"
  shared_secret = "a secret message"

  target_vpn_gateway = "${google_compute_vpn_gateway.target_gateway.self_link}"

  depends_on = [
    "google_compute_forwarding_rule.fr_esp",
    "google_compute_forwarding_rule.fr_udp500",
    "google_compute_forwarding_rule.fr_udp4500",
  ]
}

resource "google_compute_route" "route1" {
  name       = "route1"
  network    = "${google_compute_network.network1.name}"
  dest_range = "15.0.0.0/24"
  priority   = 1000

  next_hop_vpn_tunnel = "${google_compute_vpn_tunnel.tunnel1.self_link}"
}

तर्क संदर्भ

निम्नलिखित तर्क समर्थित हैं:

  • name - (आवश्यक) संसाधन का नाम। जब संसाधन बनाया जाता है तो क्लाइंट द्वारा प्रदान किया जाता है। नाम 1-63 वर्ण लंबा होना चाहिए, और RFC1035 का अनुपालन करना चाहिए। विशेष रूप से, नाम 1-63 वर्ण लंबा होना चाहिए और नियमित अभिव्यक्ति [az]([-a-z0-9]*[a-z0-9])? से मेल खाना चाहिए [az]([-a-z0-9]*[a-z0-9])? जिसका अर्थ है कि पहला वर्ण एक लोअरकेस अक्षर होना चाहिए, और सभी निम्न वर्णों में डैश, लोअरकेस अक्षर या अंक होना चाहिए, अंतिम वर्ण को छोड़कर, जो डैश नहीं हो सकता है।
  • network - (आवश्यक) यह वीपीएन गेटवे जिस नेटवर्क के लिए ट्रैफ़िक स्वीकार कर रहा है।
  • description - (वैकल्पिक) इस संसाधन का एक वैकल्पिक विवरण।
  • region - (वैकल्पिक) इस प्रवेश द्वार के क्षेत्र में बैठना चाहिए।
  • project (वैकल्पिक) उस परियोजना की आईडी जिसमें संसाधन है। यदि यह प्रदान नहीं किया जाता है, तो प्रदाता परियोजना का उपयोग किया जाता है।

संदर्भ संदर्भित करता है

ऊपर सूचीबद्ध तर्कों के अलावा, निम्नलिखित गणना की गई विशेषताएँ निर्यात की जाती हैं:

  • सृजन_टाइम्स्टैम्प - RFC3339 पाठ प्रारूप में निर्माण टाइमस्टैम्प।
  • self_link - निर्मित संसाधन का URI।

समय समाप्ति

यह संसाधन निम्नलिखित Timeouts कॉन्फ़िगरेशन विकल्प प्रदान करता है:

  • create - डिफ़ॉल्ट 4 मिनट है।
  • delete - डिफ़ॉल्ट 4 मिनट है।

आयात

VpnGateway को इनमें से किसी भी स्वीकृत प्रारूप का उपयोग करके आयात किया जा सकता है:

$ terraform import google_compute_vpn_gateway.default projects/{{project}}/regions/{{region}}/targetVpnGateways/{{name}}
$ terraform import google_compute_vpn_gateway.default {{project}}/{{region}}/{{name}}
$ terraform import google_compute_vpn_gateway.default {{name}}