Terraform 0.11

google_compute_vpn_tunnel




terraform

google_compute_vpn_tunnel

GCE नेटवर्क के लिए VPN टनल का प्रबंधन करता है। अधिक जानकारी के लिए, documentation पढ़ें।

उदाहरण उपयोग

resource "google_compute_network" "network1" {
  name = "network1"
}

resource "google_compute_subnetwork" "subnet1" {
  name          = "subnet1"
  network       = "${google_compute_network.network1.self_link}"
  ip_cidr_range = "10.120.0.0/16"
  region        = "us-central1"
}

resource "google_compute_vpn_gateway" "target_gateway" {
  name    = "vpn1"
  network = "${google_compute_network.network1.self_link}"
  region  = "${google_compute_subnetwork.subnet1.region}"
}

resource "google_compute_address" "vpn_static_ip" {
  name   = "vpn-static-ip"
  region = "${google_compute_subnetwork.subnet1.region}"
}

resource "google_compute_forwarding_rule" "fr_esp" {
  name        = "fr-esp"
  ip_protocol = "ESP"
  ip_address  = "${google_compute_address.vpn_static_ip.address}"
  target      = "${google_compute_vpn_gateway.target_gateway.self_link}"
}

resource "google_compute_forwarding_rule" "fr_udp500" {
  name        = "fr-udp500"
  ip_protocol = "UDP"
  port_range  = "500-500"
  ip_address  = "${google_compute_address.vpn_static_ip.address}"
  target      = "${google_compute_vpn_gateway.target_gateway.self_link}"
}

resource "google_compute_forwarding_rule" "fr_udp4500" {
  name        = "fr-udp4500"
  ip_protocol = "UDP"
  port_range  = "4500-4500"
  ip_address  = "${google_compute_address.vpn_static_ip.address}"
  target      = "${google_compute_vpn_gateway.target_gateway.self_link}"
}

resource "google_compute_vpn_tunnel" "tunnel1" {
  name          = "tunnel1"
  peer_ip       = "15.0.0.120"
  shared_secret = "a secret message"

  target_vpn_gateway = "${google_compute_vpn_gateway.target_gateway.self_link}"

  local_traffic_selector  = ["${google_compute_subnetwork.subnet1.ip_cidr_range}"]
  remote_traffic_selector = ["172.16.0.0/12"]

  depends_on = [
    "google_compute_forwarding_rule.fr_esp",
    "google_compute_forwarding_rule.fr_udp500",
    "google_compute_forwarding_rule.fr_udp4500",
  ]
}

resource "google_compute_route" "route1" {
  name       = "route1"
  network    = "${google_compute_network.network1.name}"
  dest_range = "15.0.0.0/24"
  priority   = 1000

  next_hop_vpn_tunnel = "${google_compute_vpn_tunnel.tunnel1.self_link}"
}

तर्क संदर्भ

निम्नलिखित तर्क समर्थित हैं:

  • name - (आवश्यक) संसाधन के लिए एक अनूठा नाम, जीसीई द्वारा आवश्यक। इस परिवर्तन से एक नया संसाधन बनने के लिए बाध्य होता है।

  • peer_ip - (आवश्यक) GCE के बाहर बैठा वीपीएन गेटवे। इस परिवर्तन से एक नया संसाधन बनने के लिए बाध्य होता है।

  • shared_secret - (आवश्यक) दो वीपीएन गेटवे के बीच एक पासफ़्रेज़ साझा किया गया। इस परिवर्तन से एक नया संसाधन बनने के लिए बाध्य होता है।

  • target_vpn_gateway - (आवश्यक) GCE के भीतर बैठे वीपीएन गेटवे का लिंक। इस परिवर्तन से एक नया संसाधन बनने के लिए बाध्य होता है।

  • description - (वैकल्पिक) संसाधन का विवरण। इस परिवर्तन से एक नया संसाधन बनने के लिए बाध्य होता है।

  • ike_version - (वैकल्पिक) या तो संस्करण 1 या 2. डिफ़ॉल्ट है। 2. इस परिवर्तन से एक नया संसाधन बनने के लिए ike_version

  • local_traffic_selector - (वैकल्पिक) निर्दिष्ट करता है कि वीपीएन सहकर्मी को CIDR रेंज की घोषणा की गई है। अनिवार्य अगर वीपीएन गेटवे एक कस्टम सबनेटेड नेटवर्क से जुड़ा हो। अधिक जानकारी के लिए Google दस्तावेज़ देखें।

  • remote_traffic_selector - (वैकल्पिक) निर्दिष्ट करता है कि CIDR में कौन सी वीपीएन सुरंग है जो रिमोट साइड पर जा सकती है। अनिवार्य अगर वीपीएन गेटवे एक कस्टम सबनेटेड नेटवर्क से जुड़ा हो। अधिक जानकारी के लिए Google दस्तावेज़ देखें।

  • router - (वैकल्पिक) डायनामिक रूटिंग के लिए उपयोग किए जाने वाले क्षेत्र में क्लाउड राउटर का नाम। अधिक जानकारी के लिए Google दस्तावेज़ देखें।

  • project - (वैकल्पिक) उस परियोजना की आईडी जिसमें संसाधन है। यदि यह प्रदान नहीं किया जाता है, तो प्रदाता परियोजना का उपयोग किया जाता है।

  • region - (वैकल्पिक) इस सुरंग में जिस क्षेत्र में बैठना चाहिए। यदि निर्दिष्ट नहीं है, तो परियोजना क्षेत्र का उपयोग किया जाएगा। इस परिवर्तन से एक नया संसाधन बनने के लिए बाध्य होता है।

संदर्भ संदर्भित करता है

ऊपर सूचीबद्ध तर्कों के अलावा, निम्नलिखित गणना की गई विशेषताएँ निर्यात की जाती हैं:

  • detailed_status - वीपीएन सुरंग की स्थिति के बारे में जानकारी।

  • self_link - निर्मित संसाधन का URI।