Terraform 0.11

opentelekomcloud_networking_network_v2




terraform

opentelekomcloud_networking_network_v2

OpenTelekomCloud के भीतर V2 न्यूट्रॉन नेटवर्क संसाधन का प्रबंधन करता है।

उदाहरण उपयोग

resource "opentelekomcloud_networking_network_v2" "network_1" {
  name           = "network_1"
  admin_state_up = "true"
}

resource "opentelekomcloud_networking_subnet_v2" "subnet_1" {
  name       = "subnet_1"
  network_id = "${opentelekomcloud_networking_network_v2.network_1.id}"
  cidr       = "192.168.199.0/24"
  ip_version = 4
}

resource "opentelekomcloud_compute_secgroup_v2" "secgroup_1" {
  name        = "secgroup_1"
  description = "a security group"

  rule {
    from_port   = 22
    to_port     = 22
    ip_protocol = "tcp"
    cidr        = "0.0.0.0/0"
  }
}

resource "opentelekomcloud_networking_port_v2" "port_1" {
  name               = "port_1"
  network_id         = "${opentelekomcloud_networking_network_v2.network_1.id}"
  admin_state_up     = "true"
  security_group_ids = ["${opentelekomcloud_compute_secgroup_v2.secgroup_1.id}"]

  fixed_ip {
    "subnet_id"  = "${opentelekomcloud_networking_subnet_v2.subnet_1.id}"
    "ip_address" = "192.168.199.10"
  }
}

resource "opentelekomcloud_compute_instance_v2" "instance_1" {
  name            = "instance_1"
  security_groups = ["${opentelekomcloud_compute_secgroup_v2.secgroup_1.name}"]

  network {
    port = "${opentelekomcloud_networking_port_v2.port_1.id}"
  }
}

तर्क संदर्भ

निम्नलिखित तर्क समर्थित हैं:

  • region - (वैकल्पिक) V2 नेटवर्किंग क्लाइंट प्राप्त करने के लिए क्षेत्र। न्यूट्रॉन नेटवर्क बनाने के लिए एक नेटवर्किंग क्लाइंट की आवश्यकता होती है। यदि छोड़ दिया जाता है, तो प्रदाता के region तर्क का उपयोग किया जाता है। इसे बदलने से एक नया नेटवर्क तैयार होता है।

  • name - (वैकल्पिक) नेटवर्क का नाम। इसे बदलने से मौजूदा नेटवर्क का नाम अपडेट होता है।

  • shared - (वैकल्पिक) निर्दिष्ट करता है कि नेटवर्क संसाधन को किसी किरायेदार द्वारा एक्सेस किया जा सकता है या नहीं। इसे बदलने से मौजूदा नेटवर्क के साझाकरण में परिवर्तन होता है।

  • tenant_id - (वैकल्पिक) नेटवर्क का स्वामी। आवश्यक है यदि व्यवस्थापक किसी अन्य किरायेदार के लिए नेटवर्क बनाना चाहता है। इसे बदलने से एक नया नेटवर्क तैयार होता है।

  • admin_state_up - (वैकल्पिक) नेटवर्क की प्रशासनिक स्थिति। स्वीकार्य मूल्य "सच्चे" और "झूठे" हैं। इस मान को बदलने से मौजूदा नेटवर्क की स्थिति अपडेट होती है।

  • segments - (वैकल्पिक) एक या एक से अधिक प्रदाता खंड वस्तुओं की एक सरणी।

  • value_specs - (वैकल्पिक) अतिरिक्त विकल्पों का मानचित्र।

segments खंड का समर्थन करता है:

  • physical_network - वह फ़ेसिकल नेटवर्क जहां यह नेटवर्क लागू किया गया है।
  • segmentation_id - भौतिक नेटवर्क पर एक अलग सेगमेंट।
  • network_type - भौतिक नेटवर्क का प्रकार।

संदर्भ संदर्भित करता है

निम्नलिखित विशेषताएँ निर्यात की जाती हैं:

  • region - उपर्युक्त तर्क देखें।
  • name - उपर्युक्त तर्क देखें।
  • shared - उपर्युक्त तर्क देखें।
  • tenant_id - उपर्युक्त तर्क देखें।
  • admin_state_up - उपर्युक्त तर्क देखें।

आयात

नेटवर्क को id का उपयोग करके आयात किया जा सकता है, जैसे

$ terraform import opentelekomcloud_networking_network_v2.network_1 d90ce693-5ccf-4136-a0ed-152ce412b6b9