vbscript मैं वर्तमान में चुनी गई फ़ाइल का पथ कैसे प्राप्त करूं?




selection explorer (2)

फाइल एक्सप्लोरर में वर्तमान में चुनी गई फ़ाइल के पथ को प्राप्त करने के लिए VBScript का एक फ़ंक्शन है? यदि हां, तो फ़ंक्शन क्या है? मुझे कुछ पसंद है

Set fileObj = CreateObject("Scripting.FileSystemObject")
dim filepath 
filepath = fileObj.GetCurrentSelection() 'doesn´t exist
dim result
result = filepath 'communicate with LiveCode

इसके द्वारा कोशिश करो आप वर्तमान में चुनी गई फ़ाइल का पथ प्राप्त कर सकते हैं। आपको भी इसकी आवश्यकता है

Set objFS=CreateObject("Scripting.FileSystemObject")
    Set objArgs = WScript.Arguments
    strFile= objArgs(0)
    Set objFile = objFS.OpenTextFile(strFile)
    Set objFile = objFS.GetFile(strFile)
    WScript.Echo objFile.Path

मैंने एक साधारण उदाहरण लिखा था
ध्यान रखें कि एक से अधिक खुली खिड़कियां एक्सप्लोरर विंडो हो सकती है और यह उन सभी को सूचीबद्ध करेगा।

Function GetSelectedFiles() 'Returns paths as array of strings
    Dim FileList, Window, SelectedItem
    'avoid duplicates by storing paths in dictionary keys
    Set FileList = CreateObject("Scripting.Dictionary")

    With CreateObject("Shell.Application")
        For Each Window In .Windows
            'skip IE Windows
            If InStr(1, Window.FullName, "iexplore.exe", vbTextCompare) = 0 Then
                For Each SelectedItem In Window.Document.SelectedItems
                    FileList(SelectedItem.Path) = Null
                Next
            End If
        Next
    End With

    GetSelectedFiles = FileList.Keys 'array of paths
End Function

MsgBox  "Click OK after selecting the items",  _
        vbOKOnly Or vbInformation, "Select a few items"

Dim SelectedFiles
    SelectedFiles =  GetSelectedFiles

MsgBox  "You selected: " & vbNewLine  & vbNewLine & _
         Join(SelectedFiles, vbNewLine), vbOKOnly Or vbInformation, "Selected Items"

'loop through array
'Dim FileItem
'For Each FileItem In SelectedFiles
'   WScript.Echo FileItem
'Next