asp.net - वर्तमान HTTPContext में एक नया एएसपी.NET सत्र उत्पन्न करना




session-state sessionid (4)

एमवीसी 4 के लिए कृपया यह कोड है:

 System.Web.SessionState.SessionIDManager manager = new System.Web.SessionState.SessionIDManager();
            HttpContext Context = System.Web.HttpContext.Current;
            string oldId = manager.GetSessionID(Context);
            string newId = manager.CreateSessionID(Context);
            bool isAdd = false, isRedir = false;
            manager.SaveSessionID(Context, newId, out isRedir, out isAdd);
            HttpApplication ctx = (HttpApplication)System.Web.HttpContext.Current.ApplicationInstance;
            HttpModuleCollection mods = ctx.Modules;
            System.Web.SessionState.SessionStateModule ssm = (SessionStateModule)mods.Get("Session");
            System.Reflection.FieldInfo[] fields = ssm.GetType().GetFields(BindingFlags.NonPublic | BindingFlags.Instance);
            SessionStateStoreProviderBase store = null;
            System.Reflection.FieldInfo rqIdField = null, rqLockIdField = null, rqStateNotFoundField = null;
            foreach (System.Reflection.FieldInfo field in fields)
            {
                if (field.Name.Equals("_store")) store = (SessionStateStoreProviderBase)field.GetValue(ssm);
                if (field.Name.Equals("_rqId")) rqIdField = field;
                if (field.Name.Equals("_rqLockId")) rqLockIdField = field;
                if (field.Name.Equals("_rqSessionStateNotFound")) rqStateNotFoundField = field;
            }
            object lockId = rqLockIdField.GetValue(ssm);
            if ((lockId != null) && (oldId != null)) store.ReleaseItemExclusive(Context, oldId, lockId);
            rqStateNotFoundField.SetValue(ssm, true);
            rqIdField.SetValue(ssm, newId);

पाइपलाइन में हमारे कुछ उत्पादों के खिलाफ प्रवेश परीक्षा के परिणामस्वरूप, उस समय क्या होना चाहिए जब एक 'आसान' समस्या ठीक करने के लिए कठिन हो रही है।

यह निश्चित रूप से नहीं होना चाहिए, मेरा मतलब है कि वर्तमान HTTPContext लिए एक नया नया सत्र क्यों उत्पन्न करना इतना कठिन होगा? विचित्र! वैसे भी- मैंने "बस इसे करने" के लिए एक छोटी सी छोटी उपयोगिता कक्षा लिखी है:

(कोड स्वरूपण / हाइलाइटिंग / विजुअल बेसिक के लिए क्षमा चाहते हैं मुझे कुछ गलत करना होगा)


Imports System.Web
Imports System.Web.SessionState

Public Class SwitchSession

    Public Shared Sub SetNewSession(ByVal context As HttpContext)
        ' This value will hold the ID managers action to creating a response cookie
        Dim cookieAdded As Boolean
        ' We use the current session state as a template
        Dim state As HttpSessionState = context.Session
        ' We use the default ID manager to generate a new session id
        Dim idManager As New SessionIDManager()
        ' We also start with a new, fresh blank state item collection
        Dim items As New SessionStateItemCollection()
        ' Static objects are extracted from the current session context
        Dim staticObjects As HttpStaticObjectsCollection = _
            SessionStateUtility.GetSessionStaticObjects(context)
        ' We construct the replacement session for the current, some parameters are new, others are taken from previous session
        Dim replacement As New HttpSessionStateContainer( _
                 idManager.CreateSessionID(context), _
                 items, _
                 staticObjects, _
                 state.Timeout, _
                 True, _
                 state.CookieMode, _
                 state.Mode, _
                 state.IsReadOnly)
        ' Finally we strip the current session state from the current context
        SessionStateUtility.RemoveHttpSessionStateFromContext(context)
        ' Then we replace the assign the active session state using the replacement we just constructed
        SessionStateUtility.AddHttpSessionStateToContext(context, replacement)
        ' Make sure we clean out the responses of any other inteferring cookies
        idManager.RemoveSessionID(context)
        ' Save our new cookie session identifier to the response
        idManager.SaveSessionID(context, replacement.SessionID, False, cookieAdded)
    End Sub

End Class

यह अनुरोध के शेष के लिए ठीक काम करता है, और सही ढंग से नए सत्र के रूप में स्वयं को पहचानता है (उदाहरण के लिए HTTPContext.Current.Session.SessionID नए जेनरेट किए गए सत्र पहचानकर्ता को लौटाता है)।

आश्चर्य की बात है कि, जब अगला अनुरोध सर्वर को हिट करता है, तो HTTPContext.Session (एक HTTPSessionState ऑब्जेक्ट) स्वयं को सही SessionID साथ पहचानता है, लेकिन IsNewSession को True सेट किया गया है, और यह खाली है, पिछले अनुरोध में सेट किए गए सभी सत्र मानों को खोना ।

तो पिछले HTTPSessionState ऑब्जेक्ट को शुरुआती अनुरोध से हटाया जा रहा है, यहां एक इवेंट हैंडलर, एक कॉलबैक, कुछ ऐसा है जो अनुरोधों में सत्र डेटा को HTTPSessionState , या बस कुछ जो मुझे याद आ रहा है?

किसी को साझा करने के लिए कोई जादू मिला?


क्या आप बस सेट नहीं कर सकते:

<sessionState regenerateExpiredSessionId="False" />

web.config में, और फिर अहमद द्वारा सुझाए गए समाधान का उपयोग करें?


जैसा कि जीनर्स का उल्लेख किया जा सकता है - रिलीजइटेम एक्सक्लूसिव स्टोर से पुराने सत्र को नहीं हटाता है और इससे उस सत्र की शुरुआत होती है और अंततः ग्लोबल.एक्सएक्स में सत्र_इंड को समाप्त कर देती है। इससे हमें उत्पादन में बड़ी समस्या हुई, क्योंकि हम सत्र_इंड में थ्रेड पहचान को साफ़ कर रहे हैं, और इसके कारण - उपयोगकर्ता स्वचालित रूप से थ्रेड पर प्रमाणीकरण खो रहे थे।

तो नीचे सही कोड है जो काम करता है।

Dim oHTTPContext As HttpContext = HttpContext.Current

Dim oSessionIdManager As New SessionIDManager
Dim sOldId As String = oSessionIdManager.GetSessionID(oHTTPContext)
Dim sNewId As String = oSessionIdManager.CreateSessionID(oHTTPContext)

Dim bIsRedir As Boolean = False
Dim bIsAdd As Boolean = False
oSessionIdManager.SaveSessionID(oHTTPContext, sNewId, bIsRedir, bIsAdd)

Dim oAppContext As HttpApplication = HttpContext.Current.ApplicationInstance

Dim oModules As HttpModuleCollection = oAppContext.Modules

Dim oSessionStateModule As SessionStateModule = _
  DirectCast(oModules.Get("Session"), SessionStateModule)

Dim oFields() As FieldInfo = _
  oSessionStateModule.GetType.GetFields(BindingFlags.NonPublic Or _
                                        BindingFlags.Instance)

Dim oStore As SessionStateStoreProviderBase = Nothing
Dim oRqIdField As FieldInfo = Nothing
Dim oRqItem As SessionStateStoreData = Nothing
Dim oRqLockIdField As FieldInfo = Nothing
Dim oRqStateNotFoundField As FieldInfo = Nothing

For Each oField As FieldInfo In oFields
    If (oField.Name.Equals("_store")) Then
        oStore = DirectCast(oField.GetValue(oSessionStateModule), _
                            SessionStateStoreProviderBase)
    End If
    If (oField.Name.Equals("_rqId")) Then
        oRqIdField = oField
    End If
    If (oField.Name.Equals("_rqLockId")) Then
        oRqLockIdField = oField
    End If
    If (oField.Name.Equals("_rqSessionStateNotFound")) Then
        oRqStateNotFoundField = oField
    End If
    If (oField.Name.Equals("_rqItem")) Then
        oRqItem = DirectCast(oField.GetValue(oSessionStateModule), _
                             SessionStateStoreData)
    End If
Next

If oStore IsNot Nothing Then

    Dim oLockId As Object = Nothing

    If oRqLockIdField IsNot Nothing Then
        oLockId = oRqLockIdField.GetValue(oSessionStateModule)
    End If

    If (oLockId IsNot Nothing) And (Not String.IsNullOrEmpty(sOldId)) Then
        oStore.ReleaseItemExclusive(oHTTPContext, sOldId, oLockId)
        oStore.RemoveItem(oHTTPContext, sOldId, oLockId, oRqItem)
    End If

    oRqStateNotFoundField.SetValue(oSessionStateModule, True)
    oRqIdField.SetValue(oSessionStateModule, sNewId)

End If

मैं अपना जादू साझा करना चाहता हूं। असल में, नहीं, यह अभी तक जादुई नहीं है .. हमें कोड को और अधिक विकसित करना और विकसित करना चाहिए। मैंने केवल इन कोडों को इन-कुकी, इनप्रोक सत्र मोड में परीक्षण किया। इन पद्धतियों को अपने पृष्ठ के अंदर रखें, और इसे कॉल करें जहां आपको पुन: उत्पन्न करने के लिए आईडी की आवश्यकता है (कृपया अपना वेब ऐप पूर्ण ट्रस्ट पर सेट करें):

void regenerateId()
{
    System.Web.SessionState.SessionIDManager manager = new System.Web.SessionState.SessionIDManager();
    string oldId = manager.GetSessionID(Context);
    string newId = manager.CreateSessionID(Context);
    bool isAdd = false, isRedir = false;
    manager.SaveSessionID(Context, newId, out isRedir, out isAdd);
    HttpApplication ctx = (HttpApplication)HttpContext.Current.ApplicationInstance;
    HttpModuleCollection mods = ctx.Modules;
    System.Web.SessionState.SessionStateModule ssm = (SessionStateModule)mods.Get("Session");
    System.Reflection.FieldInfo[] fields = ssm.GetType().GetFields(BindingFlags.NonPublic | BindingFlags.Instance);
    SessionStateStoreProviderBase store = null;
    System.Reflection.FieldInfo rqIdField = null, rqLockIdField = null, rqStateNotFoundField = null;
    foreach (System.Reflection.FieldInfo field in fields)
    {
        if (field.Name.Equals("_store")) store = (SessionStateStoreProviderBase)field.GetValue(ssm);
        if (field.Name.Equals("_rqId")) rqIdField = field;
        if (field.Name.Equals("_rqLockId")) rqLockIdField = field;
        if (field.Name.Equals("_rqSessionStateNotFound")) rqStateNotFoundField = field;
    }
    object lockId = rqLockIdField.GetValue(ssm);
    if ((lockId != null) && (oldId !=null)) store.ReleaseItemExclusive(Context, oldId, lockId);
    rqStateNotFoundField.SetValue(ssm, true);
    rqIdField.SetValue(ssm, newId);
}

मैं .NET स्रोत कोड (जो http://referencesource.microsoft.com/netframework.aspx में उपलब्ध था) के आसपास खुदाई कर रहा है, और पाया कि सत्र प्रबंधन तंत्र के आंतरिक को हैक किए बिना सत्र आईडी को पुन: उत्पन्न करने का कोई तरीका नहीं है। तो मैं बस यही करता हूं - सत्रस्टेट मॉड्यूल आंतरिक फ़ील्ड हैक करें, इसलिए यह मौजूदा सत्र को एक नई आईडी में सहेज देगा। हो सकता है कि वर्तमान HttpSessionState ऑब्जेक्ट में अभी भी पिछली आईडी है, लेकिन सत्र STATEModule AFAIK ने इसे अनदेखा किया। यह केवल आंतरिक _rqId फ़ील्ड का उपयोग करता है जब इसे कहीं और राज्य को सहेजना पड़ता है। मैंने अन्य तरीकों का प्रयास किया है, जैसे कि रीजननेट आईडी कार्यक्षमता के साथ सत्रस्टेट मॉड्यूल को एक नई कक्षा में कॉपी करना, (मैं इस वर्ग के साथ सत्रस्टेट मॉड्यूल को प्रतिस्थापित करने की योजना बना रहा था), लेकिन असफल रहा क्योंकि वर्तमान में इसमें अन्य आंतरिक वर्गों (जैसे InProcSessionStateStore) के संदर्भ हैं। प्रतिबिंब का उपयोग कर हैकिंग का नकारात्मक पक्ष हमें अपने आवेदन को 'पूर्ण ट्रस्ट' पर सेट करने की आवश्यकता है।

ओह, और यदि आपको वास्तव में वीबी संस्करण की आवश्यकता है, तो इन्हें आजमाएं:

Sub RegenerateID()
    Dim manager
    Dim oldId As String
    Dim newId As String
    Dim isRedir As Boolean
    Dim isAdd As Boolean
    Dim ctx As HttpApplication
    Dim mods As HttpModuleCollection
    Dim ssm As System.Web.SessionState.SessionStateModule
    Dim fields() As System.Reflection.FieldInfo
    Dim rqIdField As System.Reflection.FieldInfo
    Dim rqLockIdField As System.Reflection.FieldInfo
    Dim rqStateNotFoundField As System.Reflection.FieldInfo
    Dim store As SessionStateStoreProviderBase
    Dim field As System.Reflection.FieldInfo
    Dim lockId
    manager = New System.Web.SessionState.SessionIDManager
    oldId = manager.GetSessionID(Context)
    newId = manager.CreateSessionID(Context)
    manager.SaveSessionID(Context, newId, isRedir, isAdd)
    ctx = HttpContext.Current.ApplicationInstance
    mods = ctx.Modules
    ssm = CType(mods.Get("Session"), System.Web.SessionState.SessionStateModule)
    fields = ssm.GetType.GetFields(System.Reflection.BindingFlags.NonPublic Or System.Reflection.BindingFlags.Instance)
    store = Nothing : rqLockIdField = Nothing : rqIdField = Nothing : rqStateNotFoundField = Nothing
    For Each field In fields
        If (field.Name.Equals("_store")) Then store = CType(field.GetValue(ssm), SessionStateStoreProviderBase)
        If (field.Name.Equals("_rqId")) Then rqIdField = field
        If (field.Name.Equals("_rqLockId")) Then rqLockIdField = field
        If (field.Name.Equals("_rqSessionStateNotFound")) Then rqStateNotFoundField = field
    Next
    lockId = rqLockIdField.GetValue(ssm)
    If ((Not IsNothing(lockId)) And (Not IsNothing(oldId))) Then store.ReleaseItemExclusive(Context, oldId, lockId)
    rqStateNotFoundField.SetValue(ssm, True)
    rqIdField.SetValue(ssm, newId)

End Sub




httpsession