मैं 64-बिट मशीन पर 32-बिट मोड में VBScript कैसे चलाऊं?




64bit 32-bit (6)

मेरे पास एक पाठ फ़ाइल है जो कि .vbs के साथ समाप्त होती है जिसे मैंने निम्नलिखित में लिखा है:

Set Conn = CreateObject("ADODB.Connection")
Conn.Provider = "Microsoft.ACE.OLEDB.12.0"
Conn.Properties("Data Source") = "C:\dummy.accdb"
Conn.Properties("Jet OLEDB:Database Password") = "pass"
Conn.Open
Conn.Close
Set Conn = Nothing
  • जब मैं इसे विंडोज 32-बिट मशीन पर निष्पादित करता हूं, तो यह बिना किसी धारणा (अपेक्षित) के चलता है और समाप्त होता है।
  • जब मैं इसे विंडोज 64-बिट मशीन पर निष्पादित करता हूं तो यह त्रुटि हो जाती है

    प्रदाता नहीं मिल सकता है। यह ठीक से स्थापित नहीं हो सकता है।

लेकिन यह स्थापित है। मुझे लगता है कि समस्या की जड़ यह है कि प्रदाता 32-बिट प्रदाता है, जहां तक ​​मुझे पता है कि यह 64-बिट के रूप में मौजूद नहीं है।

यदि मैं अपनी 64-बिट मशीन (एएसपी फ़ाइल के रूप में) पर IIS के माध्यम से VBScript चलाता हूं, तो मैं यह चुन सकता हूं कि यह 32-बिट मोड में चलना चाहिए। यह तो प्रदाता मिल सकता है।

मैं इसे विंडोज 64-बिट पर प्रदाता कैसे खोज सकता हूं? क्या मैं किसी भी तरह 32-बिट मोड में चलाने के लिए CScript (जो .vbs टेक्स्ट फ़ाइल निष्पादित करता है) बता सकता हूं?


   ' ***************
   ' *** 64bit check
   ' ***************
   ' check to see if we are on 64bit OS -> re-run this script with 32bit cscript
   Function RestartWithCScript32(extraargs)
   Dim strCMD, iCount
   strCMD = r32wShell.ExpandEnvironmentStrings("%SYSTEMROOT%") & "\SysWOW64\cscript.exe"
   If NOT r32fso.FileExists(strCMD) Then strCMD = "cscript.exe" ' This may not work if we can't find the SysWOW64 Version
   strCMD = strCMD & Chr(32) & Wscript.ScriptFullName & Chr(32)
   If Wscript.Arguments.Count > 0 Then
    For iCount = 0 To WScript.Arguments.Count - 1
     if Instr(Wscript.Arguments(iCount), " ") = 0 Then ' add unspaced args
      strCMD = strCMD & " " & Wscript.Arguments(iCount) & " "
     Else
      If Instr("/-\", Left(Wscript.Arguments(iCount), 1)) > 0 Then ' quote spaced args
       If InStr(WScript.Arguments(iCount),"=") > 0 Then
        strCMD = strCMD & " " & Left(Wscript.Arguments(iCount), Instr(Wscript.Arguments(iCount), "=") ) & """" & Mid(Wscript.Arguments(iCount), Instr(Wscript.Arguments(iCount), "=") + 1) & """ "
       ElseIf Instr(WScript.Arguments(iCount),":") > 0 Then
        strCMD = strCMD & " " & Left(Wscript.Arguments(iCount), Instr(Wscript.Arguments(iCount), ":") ) & """" & Mid(Wscript.Arguments(iCount), Instr(Wscript.Arguments(iCount), ":") + 1) & """ "
       Else
        strCMD = strCMD & " """ & Wscript.Arguments(iCount) & """ "
       End If
      Else
       strCMD = strCMD & " """ & Wscript.Arguments(iCount) & """ "
      End If
     End If
    Next
   End If
   r32wShell.Run strCMD & " " & extraargs, 0, False
   End Function

   Dim r32wShell, r32env1, r32env2, r32iCount
   Dim r32fso
   SET r32fso = CreateObject("Scripting.FileSystemObject")
   Set r32wShell = WScript.CreateObject("WScript.Shell")
   r32env1 = r32wShell.ExpandEnvironmentStrings("%PROCESSOR_ARCHITECTURE%")
   If r32env1 <> "x86" Then ' not running in x86 mode
    For r32iCount = 0 To WScript.Arguments.Count - 1
     r32env2 = r32env2 & WScript.Arguments(r32iCount) & VbCrLf
    Next
    If InStr(r32env2,"restart32") = 0 Then RestartWithCScript32 "restart32" Else MsgBox "Cannot find 32bit version of cscript.exe or unknown OS type " & r32env1
    Set r32wShell = Nothing
    WScript.Quit
   End If
   Set r32wShell = Nothing
   Set r32fso = Nothing
   ' *******************
   ' *** END 64bit check
   ' *******************

अपनी स्क्रिप्ट की शुरुआत में उपरोक्त कोड रखें और बाद का कोड 32bit मोड में 32bit ODBC ड्राइवरों तक पहुंच जाएगा। Source


http://support.microsoft.com/kb/896456 का पालन करें

32-बिट कमांड प्रॉम्प्ट शुरू करने के लिए, इन चरणों का पालन करें:

* Click Start, click Run, type %windir%\SysWoW64\cmd.exe, and then click OK.

फिर टाइप करें

cscript vbscriptfile.vbs

64-बिट मशीन पर 32-बिट स्क्रिप्ट चलाने के लिए वैकल्पिक विधि:% windir% \ syswow64 \ cscript.exe vbscriptfile.vbs


हम "सिस्टम 32" को "sysWOW64" कुंजी के डिफ़ॉल्ट मान "कंप्यूटर \ HKLM \ SOFTWARE] \ Classes \ VBSFile \ Shell \ Open \ Command" में बदलकर vbscript को हमेशा 32 बिट मोड के साथ चला सकते हैं।


' C:\Windows\System32\WScript.exe = WScript.exe
Dim ScriptHost : ScriptHost = Mid(WScript.FullName, InStrRev(WScript.FullName, "\") + 1, Len(WScript.FullName))

Dim oWs : Set oWs = CreateObject("WScript.Shell")
Dim oProcEnv : Set oProcEnv = oWs.Environment("Process")

' Am I running 64-bit version of WScript.exe/Cscript.exe? So, call script again in x86 script host and then exit.
If InStr(LCase(WScript.FullName), LCase(oProcEnv("windir") & "\System32\")) And oProcEnv("PROCESSOR_ARCHITECTURE") = "AMD64" Then
    ' rebuild arguments
    If Not WScript.Arguments.Count = 0 Then
        Dim sArg, Arg
        sArg = ""
        For Each Arg In Wscript.Arguments
              sArg = sArg & " " & """" & Arg & """"
        Next
    End If

    Dim sCmd : sCmd = """" &  oProcEnv("windir") & "\SysWOW64\" & ScriptHost & """" & " """ & WScript.ScriptFullName & """" & sArg
    WScript.Echo "Call " & sCmd
    oWs.Run sCmd
    WScript.Quit
End If

यदि आपके पास cscript निष्पादन योग्य चलाने पर नियंत्रण है तो X:\windows\syswow64\cscript.exe संस्करण चलाएं जो कि 32 बिट कार्यान्वयन है।