sql - मैं Microsoft Access में विभिन्न संदर्भों में VBA में मापदंडों का उपयोग कैसे करूं?




ms-access access-vba (2)

मैंने SQL इंजेक्शन के बारे में बहुत कुछ पढ़ा है, और मापदंडों का उपयोग करके, bobby-tables.com जैसे स्रोतों से। हालाँकि, मैं एक्सेस में एक जटिल एप्लिकेशन के साथ काम कर रहा हूं, जिसमें सभी प्रकार के स्थानों में स्ट्रिंग के संगति के साथ बहुत सारे गतिशील एसक्यूएल हैं।

इसमें निम्नलिखित चीजें हैं जिन्हें मैं बदलना चाहता हूं, और त्रुटियों से बचने के लिए और मुझे जैक ओ'कोनेल जैसे एकल उद्धरणों के साथ नामों को संभालने की अनुमति देने के लिए पैरामीटर जोड़ना है।

यह उपयोगकर्ता है:

  • SQL कमांड निष्पादित करने के लिए DoCmd.RunSQL
  • डीएओ रिकॉर्ड्स
  • ADODB रिकॉर्ड्स
  • प्रपत्र और रिपोर्ट, DoCmd.OpenForm और DoCmd.OpenReport साथ खोले DoCmd.OpenReport , जहां WhereCondition तर्क में स्ट्रिंग DoCmd.OpenReport का उपयोग किया गया है
  • डोमेन एग्रीगेट जैसे DLookUp जो स्ट्रिंग DLookUp का उपयोग करता है

प्रश्नों को अधिकतर इस तरह संरचित किया जाता है:

DoCmd.RunSQL "INSERT INTO Table1(Field1) SELECT Field1 FROM Table2 WHERE ID = " & Me.SomeTextbox

इन विभिन्न प्रकार के प्रश्नों के लिए मापदंडों का उपयोग करने के लिए मेरे पास क्या विकल्प हैं?

यह प्रश्न एक संसाधन के रूप में अभिप्रेत है, अक्सर मैं विभिन्न पोस्ट पर मापदंडों की टिप्पणी का उपयोग कैसे करता हूं


प्रश्नों में मापदंडों का उपयोग करने के कई तरीके हैं। मैं उनमें से अधिकांश के लिए उदाहरण प्रदान करने की कोशिश करूंगा, और जहां वे लागू होते हैं।

सबसे पहले, हम अभिगम के लिए अद्वितीय समाधानों पर चर्चा करेंगे, जैसे कि फॉर्म, रिपोर्ट और डोमेन एग्रीगेट। फिर, हम DAO और ADO के बारे में बात करेंगे।

मापदंडों और रिपोर्टों से मान का उपयोग मापदंडों के रूप में

प्रवेश में, आप सीधे अपने SQL कोड में प्रपत्रों और रिपोर्टों पर नियंत्रण के वर्तमान मूल्य का उपयोग कर सकते हैं। यह मापदंडों की आवश्यकता को सीमित करता है।

आप निम्न तरीके से नियंत्रण का उल्लेख कर सकते हैं:

एक फार्म पर एक सरल नियंत्रण के लिए Forms!MyForm!MyTextbox

Forms!MyForm!MySubform.Form!MyTextbox एक Forms!MyForm!MySubform.Form!MyTextbox पर नियंत्रण के लिए Forms!MyForm!MySubform.Form!MyTextbox

Reports!MyReport!MyTextbox किसी रिपोर्ट पर नियंत्रण के लिए Reports!MyReport!MyTextbox

नमूना कार्यान्वयन:

DoCmd.RunSQL "INSERT INTO Table1(Field1) SELECT Forms!MyForm!MyTextbox" 'Inserts a single value
DoCmd.RunSQL "INSERT INTO Table1(Field1) SELECT Field1 FROM Table2 WHERE ID = Forms!MyForm!MyTextbox" 'Inserts from a different table

यह निम्नलिखित उपयोगों के लिए उपलब्ध है:

DoCmd.RunSQL का उपयोग करते समय, सामान्य प्रश्न (GUI में), फार्म और रिपोर्ट रिकॉर्ड स्रोतों, फॉर्म और रिपोर्ट फिल्टर, डोमेन समुच्चय, DoCmd.OpenForm और DoCmd.OpenReport

यह निम्नलिखित उपयोगों के लिए उपलब्ध नहीं है:

DAO या ADODB का उपयोग करके प्रश्नों को निष्पादित करते समय (उदाहरण के लिए रिकॉर्डसेट, CurrentDb.Execute )

TempVars को मापदंडों के रूप में उपयोग करना

Access में TempVars विश्व स्तर पर उपलब्ध चर हैं, जिन्हें VBA में सेट किया जा सकता है या मैक्रो का उपयोग कर सकते हैं। उन्हें कई प्रश्नों के लिए पुन: उपयोग किया जा सकता है।

नमूना कार्यान्वयन:

TempVars!MyTempVar = Me.MyTextbox.Value 'Note: .Value is required
DoCmd.RunSQL "INSERT INTO Table1(Field1) SELECT Field1 FROM Table2 WHERE ID = TempVars!MyTempVar"
TempVars.Remove "MyTempVar" 'Unset TempVar when you're done using it

TempVars के लिए उपलब्धता रूपों और रिपोर्टों से मूल्यों के समान है: ADO और DAO के लिए उपलब्ध नहीं है, अन्य उपयोगों के लिए उपलब्ध है।

जब मैं प्रपत्रों को खोलने के संदर्भ में प्रपत्रों या रिपोर्टों को खोलने के लिए पैरामीटर का उपयोग करने के लिए TempVars की सलाह देता हूं, क्योंकि अगर यह खोलने वाली वस्तु बंद हो जाती है, तो TemVVars उपलब्ध रहते हैं। मैं हर फॉर्म या रिपोर्ट के लिए अद्वितीय TempVar नामों का उपयोग करने की सलाह देता हूं, जब फॉर्म या रिपोर्ट को ताज़ा करते समय अजीबता से बचने के लिए।

मापदंडों के रूप में कस्टम फ़ंक्शन (यूडीएफ) का उपयोग करना

बहुत TempVars की तरह, आप मानों को संग्रहीत और पुनर्प्राप्त करने के लिए एक कस्टम फ़ंक्शन और स्थिर चर का उपयोग कर सकते हैं।

नमूना कार्यान्वयन:

Option Compare Database
Option Explicit

Private ThisDate As Date


Public Function GetThisDate() As Date
    If ThisDate = #12:00:00 AM# Then
        ' Set default value.
        ThisDate = Date
    End If 
    GetThisDate = ThisDate
End Function


Public Function SetThisDate(ByVal NewDate As Date) As Date
    ThisDate = NewDate
    SetThisDate = ThisDate
End Function

और फिर:

SetThisDate SomeDateValue ' Will store SomeDateValue in ThisDate.
DoCmd.RunSQL "INSERT INTO Table1(Field1) SELECT Field1 FROM Table2 WHERE [SomeDateField] = GetThisDate()"

इसके अलावा, एक वैकल्पिक पैरामीटर के साथ एक एकल फ़ंक्शन को निजी स्थिर वैरिएबल के मान को स्थापित करने और प्राप्त करने दोनों के लिए बनाया जा सकता है:

Public Function ThisValue(Optional ByVal Value As Variant) As Variant
    Static CurrentValue As Variant
    ' Define default return value.
    Const DefaultValue  As Variant = Null

    If Not IsMissing(Value) Then
        ' Set value.
        CurrentValue = Value
    ElseIf IsEmpty(CurrentValue) Then
        ' Set default value
        CurrentValue = DefaultValue
    End If
    ' Return value.
    ThisValue = CurrentValue
End Function

मान सेट करने के लिए:

ThisValue "Some text value"

मान प्राप्त करने के लिए:

CurrentValue = ThisValue

एक प्रश्न में:

ThisValue "SomeText"  ' Set value to filter on.
DoCmd.RunSQL "INSERT INTO Table1(Field1) SELECT Field1 FROM Table2 WHERE [SomeField] = ThisValue()"

DoCmd.SetParameter का उपयोग करना

DoCmd.SetParameter उपयोग सीमित हैं, इसलिए मैं संक्षिप्त हूं। यह आपको DoCmd.OpenForm , DoCmd.OpenReport और कुछ अन्य DoCmd स्टेटमेंट्स में उपयोग के लिए एक पैरामीटर सेट करने की अनुमति देता है, लेकिन यह DoCmd.RunSQL , फ़िल्टर, DAO और ADO के साथ काम नहीं करता है।

नमूना कार्यान्वयन

DoCmd.SetParameter "MyParameter", Me.MyTextbox
DoCmd.OpenForm "MyForm",,, "ID = MyParameter"

DAO का उपयोग करना

DAO में, हम क्वेरी बनाने, पैरामीटर सेट करने के लिए DAO.QueryDef ऑब्जेक्ट का उपयोग कर सकते हैं, और फिर किसी DAO.QueryDef को DAO.QueryDef सकते हैं या क्वेरी निष्पादित कर सकते हैं। आप पहले क्वेरीज़ SQL सेट करते हैं, फिर पैरामीटर सेट करने के लिए QueryDef.Parameters संग्रह का उपयोग करते हैं।

मेरे उदाहरण में, मैं अंतर्निहित पैरामीटर प्रकारों का उपयोग करने जा रहा हूं। यदि आप उन्हें स्पष्ट करना चाहते हैं, तो अपनी क्वेरी में PARAMETERS घोषणा जोड़ें।

नमूना कार्यान्वयन

'Execute query, unnamed parameters
With CurrentDb.CreateQueryDef("", "INSERT INTO Table1(Field1) SELECT Field1 FROM Table2 WHERE Field1 = ?p1 And Field2 = ?p2")
    .Parameters(0) = Me.Field1
    .Parameters(1) = Me.Field2
    .Execute
End With

'Open recordset, named parameters
Dim rs As DAO.Recordset
With CurrentDb.CreateQueryDef("", "SELECT Field1 FROM Table2 WHERE Field1 = FirstParameter And Field2 = SecondParameter")
    .Parameters!FirstParameter = Me.Field1 'Bang notation
    .Parameters("SecondParameter").Value = Me.Field2 'More explicit notation
    Set rs = .OpenRecordset
End With

हालांकि यह केवल डीएओ में उपलब्ध है, आप डीएओ रिकॉर्डसेट में कई चीजों को सेट कर सकते हैं ताकि उन्हें पैरामीटर का उपयोग कर सकें, जैसे कि फॉर्म रिकॉर्डर, सूची बॉक्स रिकॉर्डसेट और कॉम्बो बॉक्स रिकॉर्डसेट। हालाँकि, चूंकि एक्सेस पाठ का उपयोग करता है, और रिकॉर्डसेट का नहीं, जब सॉर्टिंग और फ़िल्टरिंग करते हैं, तो वे चीजें समस्याग्रस्त साबित हो सकती हैं यदि आप करते हैं।

ADO का उपयोग करना

आप ADODB.Command ऑब्जेक्ट का उपयोग करके ADO में पैरामीटर का उपयोग कर सकते हैं। पैरामीटर बनाने के लिए Command.CreateParameter का उपयोग करें, और फिर उन्हें Command.Parameters संग्रह में जोड़ें।

आप स्पष्ट रूप से पैरामीटर घोषित करने के लिए ADO में .Parameters संग्रह का उपयोग कर सकते हैं, या एक पैरामीटर सरणी पास कर सकते हैं।

ADO नामांकित मापदंडों का समर्थन नहीं करता है। जब आप एक नाम पास कर सकते हैं, तो यह संसाधित नहीं होता है।

नमूना कार्यान्वयन:

'Execute query, unnamed parameters
Dim cmd As ADODB.Command
Set cmd = New ADODB.Command
With cmd
    Set .ActiveConnection = CurrentProject.Connection 'Use a connection to the current database
    .CommandText = "INSERT INTO Table1(Field1) SELECT Field1 FROM Table2 WHERE Field1 = ? And Field2 = ?"
    .Parameters.Append .CreateParameter(, adVarWChar, adParamInput, Len(Me.Field1), Me.Field1) 'adVarWChar for text boxes that may contain unicode
    .Parameters.Append .CreateParameter(, adInteger, adParamInput, 8, Me.Field2) 'adInteger for whole numbers (long or integer)
    .Execute
End With

'Open recordset, implicit parameters
Dim rs As ADODB.Recordset
Dim cmd As ADODB.Command
Set cmd = New ADODB.Command
With cmd
    Set .ActiveConnection = CurrentProject.Connection 'Use a connection to the current database
    .CommandText = "SELECT Field1 FROM Table2 WHERE Field1 = @FirstParameter And Field2 = @SecondParameter"
     Set rs = .Execute(,Array(Me.Field1, Me.Field2))
End With

डीएओ रिकॉर्डसेट खोलने के समान सीमाएं लागू होती हैं। यद्यपि यह तरीका प्रश्नों को निष्पादित करने और रिकॉर्ड करने के लिए सीमित है, आप अपने आवेदन में उन अन्य जगहों का उपयोग कर सकते हैं।


मैंने स्ट्रिंग कंक्रीटिंग की गड़बड़ी के आसपास और नामित मापदंडों की कमी को संभालने के लिए एक काफी बुनियादी क्वेरी बिल्डर वर्ग बनाया है। एक क्वेरी बनाना काफी सरल है।

Public Function GetQuery() As String

    With New MSAccessQueryBuilder
        .QueryBody = "SELECT * FROM tblEmployees"

        .AddPredicate "StartDate > @StartDate OR StatusChangeDate > @StartDate"
        .AddPredicate "StatusIndicator IN (@Active, @LeaveOfAbsence) OR Grade > @Grade"
        .AddPredicate "Salary > @SalaryThreshhold"
        .AddPredicate "Retired = @IsRetired"

        .AddStringParameter "Active", "A"
        .AddLongParameter "Grade", 10
        .AddBooleanParameter "IsRetired", False
        .AddStringParameter "LeaveOfAbsence", "L"
        .AddCurrencyParameter "SalaryThreshhold", 9999.99@
        .AddDateParameter "StartDate", #3/29/2018#

        .QueryFooter = "ORDER BY ID ASC"
        GetQuery = .ToString

    End With

End Function

ToString () विधि का आउटपुट इस तरह दिखता है:

चयन करें * tblEmployees से 1 = 1 और (StartDate> # 3/29/2018 # या StatusChangeDate> # 3/29/2018 #) और (StatusIndicator IN ('' ',' L ') OR ग्रेड> 10) AND () वेतन> 9999.99) और (सेवानिवृत्त = गलत) आईडी एएससी द्वारा आदेश;

प्रत्येक विधेय को जुड़े और / या खंडों को संभालने के लिए Parens में लपेटा जाता है, और उसी नाम के मापदंडों को केवल एक बार घोषित किया जाना है। पूर्ण कोड मेरे github और नीचे पुन: प्रस्तुत किया गया है। मेरे पास Oracle passthrough क्वेरी के लिए एक version जो ADODB मापदंडों का उपयोग करता है। आखिरकार, मैं IQueryBuilder इंटरफ़ेस में दोनों को लपेटना चाहता हूं।

VERSION 1.0 CLASS
BEGIN
  MultiUse = -1  'True
END
Attribute VB_Name = "MSAccessQueryBuilder"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = True
Attribute VB_PredeclaredId = False
Attribute VB_Exposed = True
'@Folder("VBALibrary.Data")
'@Description("Provides tools to construct Microsoft Access SQL statements containing predicates and parameters.")

Option Explicit

Private Const mlngErrorNumber As Long = vbObjectError + 513
Private Const mstrClassName As String = "MSAccessQueryBuilder"
Private Const mstrParameterExistsErrorMessage As String = "A parameter with this name has already been added to the Parameters dictionary."

Private Type TSqlBuilder
    QueryBody As String
    QueryFooter As String
End Type

Private mobjParameters As Object
Private mobjPredicates As Collection
Private this As TSqlBuilder


' =============================================================================
' CONSTRUCTOR / DESTRUCTOR
' =============================================================================

Private Sub Class_Initialize()
    Set mobjParameters = CreateObject("Scripting.Dictionary")
    Set mobjPredicates = New Collection
End Sub


' =============================================================================
' PROPERTIES
' =============================================================================

'@Description("Gets or sets the query statement (SELECT, INSERT, UPDATE, DELETE), exclusive of any predicates.")
Public Property Get QueryBody() As String
    QueryBody = this.QueryBody
End Property
Public Property Let QueryBody(ByVal Value As String)
    this.QueryBody = Value
End Property

'@Description("Gets or sets post-predicate query statements (e.g., GROUP BY, ORDER BY).")
Public Property Get QueryFooter() As String
    QueryFooter = this.QueryFooter
End Property
Public Property Let QueryFooter(ByVal Value As String)
    this.QueryFooter = Value
End Property


' =============================================================================
' PUBLIC METHODS
' =============================================================================

'@Description("Maps a boolean parameter and its value to the query builder.")
'@Param("strName: The parameter's name.")
'@Param("blnValue: The parameter's value.")
Public Sub AddBooleanParameter(ByVal strName As String, ByVal blnValue As Boolean)
    If mobjParameters.Exists(strName) Then
        Err.Raise mlngErrorNumber, mstrClassName & ".AddBooleanParameter", mstrParameterExistsErrorMessage
    Else
        mobjParameters.Add strName, CStr(blnValue)
    End If
End Sub

' =============================================================================

'@Description("Maps a currency parameter and its value to the query builder.")
'@Param("strName: The parameter's name.")
'@Param("curValue: The parameter's value.")
Public Sub AddCurrencyParameter(ByVal strName As String, ByVal curValue As Currency)
    If mobjParameters.Exists(strName) Then
        Err.Raise mlngErrorNumber, mstrClassName & ".AddCurrencyParameter", mstrParameterExistsErrorMessage
    Else
        mobjParameters.Add strName, CStr(curValue)
    End If
End Sub

' =============================================================================

'@Description("Maps a date parameter and its value to the query builder.")
'@Param("strName: The parameter's name.")
'@Param("dtmValue: The parameter's value.")
Public Sub AddDateParameter(ByVal strName As String, ByVal dtmValue As Date)
    If mobjParameters.Exists(strName) Then
        Err.Raise mlngErrorNumber, mstrClassName & ".AddDateParameter", mstrParameterExistsErrorMessage
    Else
        mobjParameters.Add strName, "#" & CStr(dtmValue) & "#"
    End If
End Sub

' =============================================================================

'@Description("Maps a long parameter and its value to the query builder.")
'@Param("strName: The parameter's name.")
'@Param("lngValue: The parameter's value.")
Public Sub AddLongParameter(ByVal strName As String, ByVal lngValue As Long)
    If mobjParameters.Exists(strName) Then
        Err.Raise mlngErrorNumber, mstrClassName & ".AddNumericParameter", mstrParameterExistsErrorMessage
    Else
        mobjParameters.Add strName, CStr(lngValue)
    End If
End Sub

' =============================================================================

'@Description("Adds a predicate to the query's WHERE criteria.")
'@Param("strPredicate: The predicate text to be added.")
Public Sub AddPredicate(ByVal strPredicate As String)
    mobjPredicates.Add "(" & strPredicate & ")"
End Sub

' =============================================================================

'@Description("Maps a string parameter and its value to the query builder.")
'@Param("strName: The parameter's name.")
'@Param("strValue: The parameter's value.")
Public Sub AddStringParameter(ByVal strName As String, ByVal strValue As String)
    If mobjParameters.Exists(strName) Then
        Err.Raise mlngErrorNumber, mstrClassName & ".AddStringParameter", mstrParameterExistsErrorMessage
    Else
        mobjParameters.Add strName, "'" & strValue & "'"
    End If
End Sub

' =============================================================================

'@Description("Parses the query, its predicates, and any parameter values, and outputs an SQL statement.")
'@Returns("A string containing the parsed query.")
Public Function ToString() As String

Dim strPredicatesWithValues As String

    Const strErrorSource As String = "QueryBuilder.ToString"

    If this.QueryBody = vbNullString Then
        Err.Raise mlngErrorNumber, strErrorSource, "No query body is currently defined. Unable to build valid SQL."
    End If
    ToString = this.QueryBody

    strPredicatesWithValues = ReplaceParametersWithValues(GetPredicatesText)
    EnsureParametersHaveValues strPredicatesWithValues

    If Not strPredicatesWithValues = vbNullString Then
        ToString = ToString & " " & strPredicatesWithValues
    End If

    If Not this.QueryFooter = vbNullString Then
        ToString = ToString & " " & this.QueryFooter & ";"
    End If

End Function


' =============================================================================
' PRIVATE METHODS
' =============================================================================

'@Description("Ensures that all parameters defined in the query have been provided a value.")
'@Param("strQueryText: The query text to verify.")
Private Sub EnsureParametersHaveValues(ByVal strQueryText As String)

Dim strUnmatchedParameter As String
Dim lngMatchedPoisition As Long
Dim lngWordEndPosition As Long

    Const strProcedureName As String = "EnsureParametersHaveValues"

    lngMatchedPoisition = InStr(1, strQueryText, "@", vbTextCompare)
    If lngMatchedPoisition <> 0 Then
        lngWordEndPosition = InStr(lngMatchedPoisition, strQueryText, Space$(1), vbTextCompare)
        strUnmatchedParameter = Mid$(strQueryText, lngMatchedPoisition, lngWordEndPosition - lngMatchedPoisition)
    End If

    If Not strUnmatchedParameter = vbNullString Then
        Err.Raise mlngErrorNumber, mstrClassName & "." & strProcedureName, "Parameter " & strUnmatchedParameter & " has not been provided a value."
    End If

End Sub

' =============================================================================

'@Description("Combines each predicate in the predicates collection into a single string statement.")
'@Returns("A string containing the text of all predicates added to the query builder.")
Private Function GetPredicatesText() As String

Dim strPredicates As String
Dim vntPredicate As Variant

    If mobjPredicates.Count > 0 Then
        strPredicates = "WHERE 1 = 1"
        For Each vntPredicate In mobjPredicates
            strPredicates = strPredicates & " AND " & CStr(vntPredicate)
        Next vntPredicate
    End If

    GetPredicatesText = strPredicates

End Function

' =============================================================================

'@Description("Replaces parameters in the predicates statements with their provided values.")
'@Param("strPredicates: The text of the query's predicates.")
'@Returns("A string containing the predicates text with its parameters replaces by their provided values.")
Private Function ReplaceParametersWithValues(ByVal strPredicates As String) As String

Dim vntKey As Variant
Dim strParameterName As String
Dim strParameterValue As String
Dim strPredicatesWithValues As String

    Const strProcedureName As String = "ReplaceParametersWithValues"

    strPredicatesWithValues = strPredicates
    For Each vntKey In mobjParameters.Keys
        strParameterName = CStr(vntKey)
        strParameterValue = CStr(mobjParameters(vntKey))

        If InStr(1, strPredicatesWithValues, "@" & strParameterName, vbTextCompare) = 0 Then
            Err.Raise mlngErrorNumber, mstrClassName & "." & strProcedureName, "Parameter " & strParameterName & " was not found in the query."
        Else
            strPredicatesWithValues = Replace(strPredicatesWithValues, "@" & strParameterName, strParameterValue, 1, -1, vbTextCompare)
        End If
    Next vntKey

    ReplaceParametersWithValues = strPredicatesWithValues

End Function

' =============================================================================




access-vba