windows - फ़ाइल नाम में उपयोग करने के लिए उपयुक्त प्रारूप में, मैं विंडोज कमांड लाइन पर वर्तमान डेटाटाइम कैसे प्राप्त करूं?




datetime command-line (18)

क्षेत्रीय स्वतंत्र तिथि समय पार्सिंग

%DATE% और dir कमांड का आउटपुट प्रारूप क्षेत्रीय रूप से निर्भर है और इस प्रकार न तो मजबूत और न ही स्मार्ट। date.exe ( date.exe हिस्सा) किसी भी UnxUtils प्रारूप में किसी दिनांक और समय की जानकारी प्रदान करता है। आप date.exe साथ किसी भी फ़ाइल से दिनांक / समय की जानकारी निकाल सकते हैं।

उदाहरण: (एक cmd-script में% के बजाय %% का उपयोग करें)

date.exe +"%Y-%m-%d"
2009/12/22

date.exe +"%T"
18:55:03

date.exe +"%Y%m%d %H%M%S: Any text"
200 9 2222 185503: कोई भी पाठ

date.exe +"Text: %y/%m/%d-any text-%H.%M"
पाठ: 0 9/12/22-कोई भी पाठ -18.55

Command: date.exe +"%m-%d """%H %M %S """"
07-22 "18:55:03" `

संदर्भ फ़ाइल से दिनांक / समय की जानकारी:
date.exe -rc:\file.txt +"The timestamp of file.txt is: %Y-%m-%d %H:%M:%S"

वर्ष, महीने, दिन, समय की जानकारी प्राप्त करने के लिए इसे एक सीएमडी स्क्रिप्ट में उपयोग करना:

for /f "tokens=1,2,3,4,5,6* delims=," %%i in ('C:\Tools\etc\date.exe +"%%y,%%m,%%d,%%H,%%M,%%S"') do set yy=%%i& set mo=%%j& set dd=%%k& set hh=%%l& set mm=%%m& set ss=%%n

किसी भी आवश्यक प्रारूप में टाइमस्टैम्प प्राप्त करने के लिए इसे एक सीएमडी स्क्रिप्ट में उपयोग करना:

for /f "tokens=*" %%i in ('C:\Tools\etc\date.exe +"%%y-%%m-%%d %%H:%%M:%%S"') do set timestamp=%%i

किसी संदर्भ फ़ाइल से दिनांक / समय की जानकारी निकालना।

for /f "tokens=1,2,3,4,5,6* delims=," %%i in ('C:\Tools\etc\date.exe -r file.txt +"%%y,%%m,%%d,%%H,%%M,%%S"') do set yy=%%i& set mo=%%j& set dd=%%k& set hh=%%l& set mm=%%m& set ss=%%n

फ़ाइल में अपनी तिथि / समय की जानकारी जोड़ना:

for /f "tokens=*" %%i in ('C:\Tools\etc\date.exe -r file.txt +"%%y-%%m-%%d.%%H%%M%%S"') do ren file.txt file.%%i.txt

date.exe date.exe का date.exe जिसे कोई इंस्टॉलेशन की आवश्यकता नहीं है।

नोट: किसी भी निर्देशिका में date.exe को कॉपी date.exe जो खोज पथ में है, अन्य स्क्रिप्ट विफल होने का कारण बन सकता है जो Windows अंतर्निहित date कमांड का उपयोग करता है।

अपडेट करें: अब यह 2016 है, इसके लिए मैं PowerShell का उपयोग तब तक करूँगा जब तक कि वास्तव में इसके उपयोग के साथ क्षेत्रीय सेटिंग्स के मुद्दे के कारण वास्तव में एक आकर्षक पीछे-संगत कारण नहीं है। @ Npocmaka के https://stackoverflow.com/a/19799236/8479

एक विंडोज कमांड लाइन स्टेटमेंट क्या है जिसका उपयोग मैं वर्तमान प्रारूप को एक प्रारूप में प्राप्त करने के लिए कर सकता हूं जिसे मैं फ़ाइल नाम में डाल सकता हूं?

मैं एक .bat फ़ाइल रखना चाहता हूं जो नाम के हिस्से के रूप में वर्तमान दिनांक और समय के साथ एक संग्रह में एक निर्देशिका को Code_2008-10-14_2257.zip , उदाहरण के लिए, Code_2008-10-14_2257.zip . Code_2008-10-14_2257.zip । क्या मशीन के क्षेत्रीय सेटिंग्स से स्वतंत्र, क्या मैं इसे आसान तरीके से कर सकता हूं?

मुझे डेट प्रारूप के बारे में वास्तव में कोई फर्क नहीं पड़ता, आदर्श रूप में यह yyyy-mm-dd होगा, लेकिन कुछ भी आसान है ठीक है।

अब तक मुझे यह मिल गया है, जो मेरी मशीन पर मुझे Tue_10_14_2008_230050_91 देता है:

rem Get the datetime in a format that can go in a filename.
set _my_datetime=%date%_%time%
set _my_datetime=%_my_datetime: =_%
set _my_datetime=%_my_datetime::=%
set _my_datetime=%_my_datetime:/=_%
set _my_datetime=%_my_datetime:.=_%

rem Now use the timestamp by in a new ZIP file name.
"d:\Program Files\7-Zip\7z.exe" a -r Code_%_my_datetime%.zip Code

मैं इसके साथ रह सकता हूं, लेकिन यह थोड़ा सा गुस्सा लगता है। आदर्श रूप से यह पहले से उल्लिखित स्वरूप होगा और प्रारूपित होगा।

मैं विंडोज सर्वर 2003 और विंडोज एक्सपी प्रोफेशनल का उपयोग कर रहा हूँ। मैं इसे प्राप्त करने के लिए अतिरिक्त उपयोगिताओं को स्थापित नहीं करना चाहता हूं (हालांकि मुझे एहसास है कि कुछ ऐसे हैं जो अच्छी तिथि स्वरूपण करेंगे)।


इस कोड की पहली चार पंक्तियां आपको विंडोज एक्सपी प्रोफेशनल और उच्चतर में वाई वाई डीडी एमएम वाई वाई वाई एच सेक सेक वैरिएबल प्रदान करेंगी।

@echo off
for /f "tokens=2 delims==" %%a in ('wmic OS Get localdatetime /value') do set "dt=%%a"
set "YY=%dt:~2,2%" & set "YYYY=%dt:~0,4%" & set "MM=%dt:~4,2%" & set "DD=%dt:~6,2%"
set "HH=%dt:~8,2%" & set "Min=%dt:~10,2%" & set "Sec=%dt:~12,2%"

set "datestamp=%YYYY%%MM%%DD%" & set "timestamp=%HH%%Min%%Sec%" & set "fullstamp=%YYYY%-%MM%-%DD%_%HH%%Min%-%Sec%"
echo datestamp: "%datestamp%"
echo timestamp: "%timestamp%"
echo fullstamp: "%fullstamp%"
pause

एक पंक्ति में दिनांक समय प्राप्त करने का एक तरीका यहां दिया गया है:

for /f "tokens=2,3,4,5,6 usebackq delims=:/ " %a in ('%date% %time%') do echo %c-%a-%b %d%e

अमेरिका में यह "yyyy-mm-dd hhmm" आउटपुट करेगा। विभिन्न क्षेत्रीय सेटिंग्स के परिणामस्वरूप अलग-अलग% दिनांक% आउटपुट होंगे, लेकिन आप टोकन ऑर्डर को संशोधित कर सकते हैं।

यदि आप एक अलग प्रारूप चाहते हैं, तो टोकन को पुनर्व्यवस्थित करके या अलग (या नहीं) विभाजक का उपयोग करके गूंज विवरण संशोधित करें।


एक लाइनर दिनांक और समय प्राप्त करने के लिए मैथ्यू जॉनसन का एक-लाइनर समाधान स्पष्ट और उपयोगी है।

हालांकि बैच फ़ाइल के भीतर से काम करने के लिए इसे एक साधारण संशोधन की आवश्यकता है:

for /f "tokens=2,3,4,5,6 usebackq delims=:/ " %%a in ('%date% %time%') do echo %%c-%%a-%%b %%d%%e

और यहां समय के लिए एक समान बैच फ़ाइल है।

:: http://.com/questions/203090/how-to-get-current-datetime-on-windows-command-line-in-a-suitable-format-for-usi
:: Works on any NT/2k machine independent of regional time settings
::
:: Gets the time in ISO 8601 24-hour format
::
:: Note that %time% gets you fractions of seconds, and time /t doesn't, but gets you AM/PM if your locale supports that.
:: Since ISO 8601 does not care about AM/PM, we use %time%
::
    @ECHO off
    SETLOCAL ENABLEEXTENSIONS
    for /f "tokens=1-4 delims=:,.-/ " %%i in ('echo %time%') do (
      set 'hh'=%%i
      set 'mm'=%%j
      set 'ss'=%%k
      set 'ff'=%%l)
    ENDLOCAL & SET v_Hour=%'hh'%& SET v_Minute=%'mm'%& SET v_Second=%'ss'%& SET v_Fraction=%'ff'%

    ECHO Now is Hour: [%V_Hour%] Minute: [%V_Minute%] Second: [%v_Second%] Fraction: [%v_Fraction%]
    set timestring=%V_Hour%%V_Minute%%v_Second%.%v_Fraction%
    echo %timestring%

    :EOF

--jeroen


कमांड लाइन में वर्तमान दिन प्राप्त करने के लिए कृपया निम्न स्क्रिप्ट का उपयोग करें:

echo %Date:~0,3%day

दो और तरीके जो समय सेटिंग पर निर्भर नहीं हैं (दोनों से लिया गया : स्थानीयकरण से डेटा / समय कैसे प्राप्त होता है:) । और दोनों को सप्ताह का दिन भी मिलता है और उनमें से कोई भी व्यवस्थापक अनुमतियों की आवश्यकता नहीं है !:

  1. MAKECAB - हर विंडोज सिस्टम पर काम करेगा (तेज़, लेकिन एक छोटी अस्थायी फ़ाइल बनाता है) (फॉक्सिड्रिव स्क्रिप्ट):

    @echo off
    pushd "%temp%"
    makecab /D RptFileName=~.rpt /D InfFileName=~.inf /f nul >nul
    for /f "tokens=3-7" %%a in ('find /i "makecab"^<~.rpt') do (
       set "current-date=%%e-%%b-%%c"
       set "current-time=%%d"
       set "weekday=%%a"
    )
    del ~.*
    popd
    echo %weekday% %current-date% %current-time%
    pause
    

    गेट-डेट फ़ंक्शन के बारे में अधिक जानकारी

  2. रोबोकॉपी - यह विंडोज एक्सपी और विंडोज सर्वर 2003 के लिए मूल कमांड नहीं है, लेकिन इसे माइक्रोसॉफ्ट साइट से डाउनलोड किया जा सकता है। लेकिन विंडोज विस्टा और ऊपर से सब कुछ में अंतर्निहित है:

    @echo off
    setlocal
    for /f "skip=8 tokens=2,3,4,5,6,7,8 delims=: " %%D in ('robocopy /l * \ \ /ns /nc /ndl /nfl /np /njh /XF * /XD *') do (
     set "dow=%%D"
     set "month=%%E"
     set "day=%%F"
     set "HH=%%G"
     set "MM=%%H"
     set "SS=%%I"
     set "year=%%J"
    )
    
    echo Day of the week: %dow%
    echo Day of the month : %day%
    echo Month : %month%
    echo hour : %HH%
    echo minutes : %MM%
    echo seconds : %SS%
    echo year : %year%
    endlocal
    

    और तीन और तरीके जो अन्य विंडोज स्क्रिप्ट भाषाओं का उपयोग करते हैं। वे आपको अधिक लचीलापन देंगे जैसे कि आप वर्ष का सप्ताह, मिलसेकंड में समय और इसी तरह के समय प्राप्त कर सकते हैं।

  3. जेस्क्रिप्ट / बैच हाइब्रिड ( .bat रूप में सहेजने की आवश्यकता है)। जेस्क्रिप्ट विंडोज स्क्रिप्ट होस्ट के हिस्से के रूप में एनटी और उपरोक्त प्रत्येक सिस्टम फॉर्म पर उपलब्ध है ( हालांकि रजिस्ट्री के माध्यम से इसे अक्षम किया जा सकता है यह एक दुर्लभ मामला है ):

    @if (@X)==(@Y) @end /* ---Harmless hybrid line that begins a JScript comment
    
    @echo off
    cscript //E:JScript //nologo "%~f0"
    exit /b 0
    *------------------------------------------------------------------------------*/
    
    function GetCurrentDate() {
            // Today date time which will used to set as default date.
            var todayDate = new Date();
            todayDate = todayDate.getFullYear() + "-" +
                           ("0" + (todayDate.getMonth() + 1)).slice(-2) + "-" +
                           ("0" + todayDate.getDate()).slice(-2) + " " + ("0" + todayDate.getHours()).slice(-2) + ":" +
                           ("0" + todayDate.getMinutes()).slice(-2);
    
            return todayDate;
        }
    
    WScript.Echo(GetCurrentDate());
    
  4. वीएससीआरआईपीटी / बैच हाइब्रिड ( क्या एक अस्थायी फ़ाइल का उपयोग किये बिना बैच फ़ाइल के भीतर वीबीस्क्रिप्ट को एम्बेड और निष्पादित करना संभव है? ) जेस्क्रिप्ट के समान मामला, लेकिन संकरण इतना सही नहीं है:

    :sub echo(str) :end sub
    echo off
    '>nul 2>&1|| copy /Y %windir%\System32\doskey.exe %windir%\System32\'.exe >nul
    '& echo current date:
    '& cscript /nologo /E:vbscript "%~f0"
    '& exit /b
    
    '0 = vbGeneralDate - Default. Returns date: mm/dd/yy and time if specified: hh:mm:ss PM/AM.
    '1 = vbLongDate - Returns date: weekday, monthname, year
    '2 = vbShortDate - Returns date: mm/dd/yy
    '3 = vbLongTime - Returns time: hh:mm:ss PM/AM
    '4 = vbShortTime - Return time: hh:mm
    
    WScript.echo  Replace(FormatDateTime(Date,1),", ","-")
    
  5. PowerShell - प्रत्येक मशीन पर स्थापित किया जा सकता है जिसमें .NET - माइक्रोसॉफ्ट से डाउनलोड ( v1 , v2 , v3 (केवल विंडोज 7 और ऊपर के लिए))। यह विंडोज 7 / विंडोज सर्वर 2008 और ऊपर से सबकुछ डिफ़ॉल्ट रूप से स्थापित है:

    C:\> powershell get-date -format "{dd-MMM-yyyy HH:mm}"
    

    बैच फ़ाइल से इसका उपयोग करने के लिए:

    for /f "delims=" %%# in ('powershell get-date -format "{dd-MMM-yyyy HH:mm}"') do @set _date=%%#
    
  6. स्वयं संकलित jscript.net/batch (.NET के बिना विंडोज मशीन कभी नहीं देखी, इसलिए मुझे लगता है कि यह एक सुंदर पोर्टेबल है):

    @if (@X)==(@Y) @end /****** silent line that start JScript comment ******
    
    @echo off
    ::::::::::::::::::::::::::::::::::::
    :::       Compile the script    ::::
    ::::::::::::::::::::::::::::::::::::
    setlocal
    if exist "%~n0.exe" goto :skip_compilation
    
    set "frm=%SystemRoot%\Microsoft.NET\Framework\"
    
    :: Searching the latest installed .NET framework
    for /f "tokens=* delims=" %%v in ('dir /b /s /a:d /o:-n "%SystemRoot%\Microsoft.NET\Framework\v*"') do (
        if exist "%%v\jsc.exe" (
            rem :: the javascript.net compiler
            set "jsc=%%~dpsnfxv\jsc.exe"
            goto :break_loop
        )
    )
    echo jsc.exe not found && exit /b 0
    :break_loop
    
    
    call %jsc% /nologo /out:"%~n0.exe" "%~dpsfnx0"
    ::::::::::::::::::::::::::::::::::::
    :::       End of compilation    ::::
    ::::::::::::::::::::::::::::::::::::
    :skip_compilation
    
    "%~n0.exe"
    
    exit /b 0
    
    
    ****** End of JScript comment ******/
    import System;
    import System.IO;
    
    var dt=DateTime.Now;
    Console.WriteLine(dt.ToString("yyyy-MM-dd hh:mm:ss"));
    
  7. लॉगमैन यह सप्ताह के साल और दिन नहीं प्राप्त कर सकता है। यह तुलनात्मक रूप से धीमा है और एक अस्थायी फ़ाइल भी बनाता है और उस समय टिकटों पर आधारित है जो लॉगमैन अपनी लॉग फाइलों पर रखता है। यह विंडोज एक्सपी और ऊपर से सबकुछ पर काम करेगा। यह शायद किसी के द्वारा कभी भी उपयोग नहीं किया जाएगा - लेकिन मुझे एक और तरीका है ...

    @echo off
    setlocal
    del /q /f %temp%\timestampfile_*
    
    Logman.exe stop ts-CPU 1>nul 2>&1
    Logman.exe delete ts-CPU 1>nul 2>&1
    
    Logman.exe create counter ts-CPU  -sc 2 -v mmddhhmm -max 250 -c "\Processor(_Total)\%% Processor Time" -o %temp%\timestampfile_ >nul
    Logman.exe start ts-CPU 1>nul 2>&1
    
    Logman.exe stop ts-CPU >nul 2>&1
    Logman.exe delete ts-CPU >nul 2>&1
    for /f "tokens=2 delims=_." %%t in  ('dir /b %temp%\timestampfile_*^&del /q/f %temp%\timestampfile_*') do set timestamp=%%t
    
    echo %timestamp%
    echo MM: %timestamp:~0,2%
    echo dd: %timestamp:~2,2%
    echo hh: %timestamp:~4,2%
    echo mm: %timestamp:~6,2%
    
    endlocal
    exit /b 0
    
  8. डब्लूएमआईसी के साथ एक और तरीका जो साल के सप्ताह और सप्ताह के दिन भी देता है, लेकिन मिलीसेकंड नहीं (मिलीसेकंड के लिए फॉक्सिड्राइव के जवाब की जांच करें):

    for /f %%# in ('wMIC Path Win32_LocalTime Get /Format:value') do @for /f %%@ in ("%%#") do @set %%@
    echo %day%
    echo %DayOfWeek%
    echo %hour%
    echo %minute%
    echo %month%
    echo %quarter%
    echo %second%
    echo %weekinmonth%
    echo %year%
    
  9. विभिन्न भाषा सेटिंग्स के साथ तेज़ और संगत होने के कुछ प्रयासों के साथ TYPEPERF का उपयोग करना और जितनी जल्दी हो सके:

    @echo off
    setlocal
    
    :: Check if Windows is Windows XP and use Windows XP valid counter for UDP performance
    ::if defined USERDOMAIN_roamingprofile (set "v=v4") else (set "v=")
    
    for /f "tokens=4 delims=. " %%# in ('ver') do if %%# GTR 5 (set "v=v4") else ("v=")
    set "mon="
    for /f "skip=2 delims=," %%# in ('typeperf "\UDP%v%\*" -si 0 -sc 1') do (
       if not defined mon (
          for /f "tokens=1-7 delims=.:/ " %%a in (%%#) do (
            set mon=%%a
            set date=%%b
            set year=%%c
            set hour=%%d
            set minute=%%e
            set sec=%%f
            set ms=%%g
          )
       )
    )
    echo %year%.%mon%.%date%
    echo %hour%:%minute%:%sec%.%ms%
    endlocal
    
  10. एमएसएचटीए जावास्क्रिप्ट विधियों को ऊपर # 3 में प्रदर्शित जेस्क्रिप्ट विधि के समान कॉल करने की अनुमति देता है। ध्यान रखें कि महीने के मूल्यों से जुड़े जावास्क्रिप्ट की दिनांक वस्तु गुण 0 से 11 तक, 1 से 12 तक नहीं हैं। इसलिए 9 का मान अक्टूबर का मतलब है।

    <!-- : Batch portion
    
    @echo off
    setlocal
    
    for /f "delims=" %%I in ('mshta "%~f0"') do set "now.%%~I"
    
    rem Display all variables beginning with "now."
    set now.
    
    goto :EOF
    
    end batch / begin HTA -->
    
    <script>
        resizeTo(0,0)
        var fso = new ActiveXObject('Scripting.FileSystemObject').GetStandardStream(1),
            now = new Date(),
            props=['getDate','getDay','getFullYear','getHours','getMilliseconds','getMinutes',
                'getMonth','getSeconds','getTime','getTimezoneOffset','getUTCDate','getUTCDay',
                'getUTCFullYear','getUTCHours','getUTCMilliseconds','getUTCMinutes','getUTCMonth',
                'getUTCSeconds','getYear','toDateString','toGMTString','toLocaleDateString',
                'toLocaleTimeString','toString','toTimeString','toUTCString','valueOf'],
            output = [];
    
        for (var i in props) {output.push(props[i] + '()=' + now[props[i]]())}
        close(fso.Write(output.join('\n')));
    </script>
    

बस इस लाइन का प्रयोग करें:

PowerShell -Command "get-date"

मैंने बैच फ़ाइल के साथ से जवाब बदल दिया है , इसलिए यह डच भाषा के साथ भी काम करता है।
डच - हम जैसे हैं - %date% , date/t , और मूल बैच-फ़ाइल को तोड़ने वाली date में कुछ बदलाव हैं।

यह अच्छा होगा अगर कुछ लोग इसे अन्य विंडोज लोकेशंस के खिलाफ भी देख सकें, और परिणामों की रिपोर्ट करें।
यदि बैच-फ़ाइल आपके स्थान पर विफल हो जाती है, तो कृपया कमांड प्रॉम्प्ट पर इन दो कथनों का आउटपुट शामिल करें:
echo:^|date
date/t

यह बैच-फ़ाइल से प्राप्त आउटपुट का एक नमूना है:

C:\temp>set-date-cmd.bat
Today is Year: [2011] Month: [01] Day: [03]
20110103

टिप्पणियों के साथ संशोधित कोड यहां क्यों है:

:: https://.com/questions/203090/how-to-get-current-datetime-on-windows-command-line-in-a-suitable-format-for-usi
:: Works on any NT/2k machine independent of regional date settings
::
:: 20110103 - adapted by [email protected] for Dutch locale
:: Dutch will get jj as year from echo:^|date, so the '%%c' trick does not work as it will fill 'jj', but we want 'yy'
:: luckily, all countries seem to have year at the end: http://en.wikipedia.org/wiki/Calendar_date
::            set '%%c'=%%k
::            set 'yy'=%%k
::
:: In addition, date will display the current date before the input prompt using dashes
:: in Dutch, but using slashes in English, so there will be two occurances of the outer loop in Dutch
:: and one occurence in English.
:: This skips the first iteration:
::        if "%%a" GEQ "A"
::
:: echo:^|date
:: Huidige datum: ma 03-01-2011
:: Voer de nieuwe datum in: (dd-mm-jj)
:: The current date is: Mon 01/03/2011
:: Enter the new date: (mm-dd-yy)
::
:: date/t
:: ma 03-01-2011
:: Mon 01/03/2011
::
:: The assumption in this batch-file is that echo:^|date will return the date format
:: using either mm and dd or dd and mm in the first two valid tokens on the second line, and the year as the last token.
::
:: The outer loop will get the right tokens, the inner loop assigns the variables depending on the tokens.
:: That will resolve the order of the tokens.
::
@ECHO off
    set v_day=
    set v_month=
    set v_year=

    SETLOCAL ENABLEEXTENSIONS
    if "%date%A" LSS "A" (set toks=1-3) else (set toks=2-4)
::DEBUG echo toks=%toks%
      for /f "tokens=2-4 delims=(-)" %%a in ('echo:^|date') do (
::DEBUG echo first token=%%a
        if "%%a" GEQ "A" (
          for /f "tokens=%toks% delims=.-/ " %%i in ('date/t') do (
            set '%%a'=%%i
            set '%%b'=%%j
            set 'yy'=%%k
          )
        )
      )
      if %'yy'% LSS 100 set 'yy'=20%'yy'%
      set Today=%'yy'%-%'mm'%-%'dd'%

    ENDLOCAL & SET v_year=%'yy'%& SET v_month=%'mm'%& SET v_day=%'dd'%

    ECHO Today is Year: [%V_Year%] Month: [%V_Month%] Day: [%V_Day%]
    set datestring=%V_Year%%V_Month%%V_Day%
    echo %datestring%

    :EOF

--jeroen


मैंने यही उपयोग किया है:

::Date Variables - replace characters that are not legal as part of filesystem file names (to produce name like "backup_04.15.08.7z")
SET DT=%date%
SET DT=%DT:/=.%
SET DT=%DT:-=.%

यदि आप बैकअप को 7-ज़िप अभिलेखागार में स्वचालित करने के लिए और विचार चाहते हैं, तो मेरे पास एक निःशुल्क / खुली परियोजना है जिसका आप उपयोग या विचारों के लिए समीक्षा कर सकते हैं: http://wittman.org/ziparcy/


यहां alt.msdos.batch.nt से एक संस्करण है जो स्थानीय-स्वतंत्र रूप से काम करता है।

इसे एक टेक्स्ट फ़ाइल में रखें, उदाहरण के लिए GetDate.cmd

-----------8<------8<------------ snip -- snip ----------8<-------------
    :: Works on any NT/2k machine independent of regional date settings
    @ECHO off
    SETLOCAL ENABLEEXTENSIONS
    if "%date%A" LSS "A" (set toks=1-3) else (set toks=2-4)
    for /f "tokens=2-4 delims=(-)" %%a in ('echo:^|date') do (
      for /f "tokens=%toks% delims=.-/ " %%i in ('date/t') do (
        set '%%a'=%%i
        set '%%b'=%%j
        set '%%c'=%%k))
    if %'yy'% LSS 100 set 'yy'=20%'yy'%
    set Today=%'yy'%-%'mm'%-%'dd'% 
    ENDLOCAL & SET v_year=%'yy'%& SET v_month=%'mm'%& SET v_day=%'dd'%

    ECHO Today is Year: [%V_Year%] Month: [%V_Month%] Day: [%V_Day%]

    :EOF
-----------8<------8<------------ snip -- snip ----------8<-------------

कोड को काम करने के लिए कोड त्रुटि संदेश को stderr में प्राप्त करने के लिए, मुझे एकल उद्धरण जोड़ना था, जो %% ए, %% बी और %% c के लिए चर असाइनमेंट को जोड़ता था। मेरा लोकेल (पीटी) लूपिंग / पार्सिंग में एक चरण में त्रुटियों का कारण बन रहा था जहां "सेट = 20" जैसी चीजें निष्पादित की जा रही थीं। उद्धरण असाइनमेंट स्टेटमेंट के बाईं ओर एक टोकन (हालांकि खाली) उत्पन्न करते हैं।

नकारात्मकता गन्दा लोकेल परिवर्तनीय नाम है: 'yy', 'mm' और 'dd'। लेकिन हे, कौन परवाह करता है!


संक्षिप्त जवाब :

 :: Start - Run , type:
 cmd /c "powershell get-date -format ^"{yyyy-MM-dd HH:mm:ss}^"|clip"

 :: click into target media, Ctrl + V to paste the result 

लंबा जवाब

    @echo off
    :: START USAGE  ==================================================================
    ::SET THE NICETIME 
    :: SET NICETIME=BOO
    :: CALL GetNiceTime.cmd 

    :: ECHO NICETIME IS %NICETIME%

    :: echo nice time is %NICETIME%
    :: END USAGE  ==================================================================

    echo set hhmmsss
    :: this is Regional settings dependant so tweak this according your current settings
    for /f "tokens=1-3 delims=:" %%a in ('echo %time%') do set hhmmsss=%%a%%b%%c 
    ::DEBUG ECHO hhmmsss IS %hhmmsss%
    ::DEBUG PAUSE
    echo %yyyymmdd%
        :: this is Regional settings dependant so tweak this according your current settings
    for /f "tokens=1-3 delims=." %%D in ('echo %DATE%') do set  yyyymmdd=%%F%%E%%D
    ::DEBUG ECHO yyyymmdd IS %yyyymmdd%
    ::DEBUG PAUSE


    set NICETIME=%yyyymmdd%_%hhmmsss%
    ::DEBUG echo THE NICETIME IS %NICETIME%

    ::DEBUG PAUSE

MMDDYYYY प्रारूप में वर्तमान दिनांक प्राप्त करने के लिए विंडोज बैच फ़ाइल (.bat) देखें:

@echo off
For /f "tokens=2-4 delims=/ " %%a in ('date /t') do (set mydate=%%c-%%a-%%b)
For /f "tokens=1-2 delims=/:" %%a in ('time /t') do (set mytime=%%a%%b)
echo %mydate%_%mytime%

यदि आप 24 घंटे / सैन्य प्रारूप में समय पसंद करते हैं, तो आप इसके साथ दूसरी फॉर लाइन को प्रतिस्थापित कर सकते हैं:

For /f "tokens=1-2 delims=/:" %%a in ("%TIME%") do (set mytime=%%a%%b)

सी:>। \ Date.bat
2008-10-14_0642

यदि आप क्षेत्र के दिन / महीने के आदेश से स्वतंत्र रूप से तिथि चाहते हैं, तो आप स्रोत के रूप में "WMIC os LocalDateTime प्राप्त करें" का उपयोग कर सकते हैं, क्योंकि यह आईएसओ ऑर्डर में है:

@echo off
for /F "usebackq tokens=1,2 delims==" %%i in (`wmic os get LocalDateTime /VALUE 2^>NUL`) do if '.%%i.'=='.LocalDateTime.' set ldt=%%j
set ldt=%ldt:~0,4%-%ldt:~4,2%-%ldt:~6,2% %ldt:~8,2%:%ldt:~10,2%:%ldt:~12,6%
echo Local date is [%ldt%]

सी:> test.cmd
स्थानीय तिथि है [2012-06-19 10: 23: 47.048]


Given a known locality, for reference in functional form. The ECHOTIMESTAMP call shows how to get the timestamp into a variable ( DTS in this example.)

@ECHO off

CALL :ECHOTIMESTAMP
GOTO END

:TIMESTAMP
SETLOCAL  EnableDelayedExpansion
    SET DATESTAMP=!DATE:~10,4!-!DATE:~4,2!-!DATE:~7,2!
    SET TIMESTAMP=!TIME:~0,2!-!TIME:~3,2!-!TIME:~6,2!
    SET DTS=!DATESTAMP: =0!-!TIMESTAMP: =0!
ENDLOCAL & SET "%~1=%DTS%"
GOTO :EOF

:ECHOTIMESTAMP
SETLOCAL
    CALL :TIMESTAMP DTS
    ECHO %DTS%
ENDLOCAL
GOTO :EOF

:END

EXIT /b 0

And saved to file, timestamp.bat, here's the output:


I know that there are numerous ways mentioned already. But here is my way to break it down to understand how it is done. Hopefully, it is helpful for someone who like step by step method.

:: Check your local date format
echo %date%

    :: Output is Mon 08/15/2016

:: get day (start index, number of characters)
::         (index starts with zero)
set myday=%DATE:~0,4%
echo %myday%
    :: output is Mon 

:: get month
set mymonth=%DATE:~4,2%
echo %mymonth%
    :: output is 08

:: get date 
set mydate=%DATE:~7,2% 
echo %mydate%
    :: output is 15

:: get year
set myyear=%DATE:~10,4%
echo %myyear%
    :: output is 2016

Regional independent solution generating the ISO date format:

rem save the existing format definition
for /f "skip=2 tokens=3" %%a in ('reg query "HKCU\Control Panel\International" /v sShortDate') do set FORMAT=%%a
rem set ISO specific format definition
reg add "HKCU\Control Panel\International" /v sShortDate /t REG_SZ /f /d yyyy-MM-dd 1>nul:
rem query the date in the ISO specific format 
set ISODATE=%DATE%
rem restore previous format definition
reg add "HKCU\Control Panel\International" /v sShortDate /t REG_SZ /f /d %FORMAT% 1>nul:

What could still be optimized: Other processes might get confused if using the date format in the short period while it is modified. So parsing the output according to the existing format string could be 'safer' - but will be more complicated


"d:\Program Files\7-Zip\7z.exe" a -r code_%date:~10,4%-%date:~4,2%-%date:~7,2%.zip

:: GetDate.cmd -> Uses WMIC.exe to get current date and time in ISO 8601 format
:: - Sets environment variables %_isotime% and %_now% to current time
:: - On failure, clears these environment variables
:: Inspired on -> https://ss64.com/nt/syntax-getdate.html
:: - (cX) 2017 [email protected]
:: - http://.com/questions/203090
@echo off

set _isotime=
set _now=

:: Check that WMIC.exe is available
WMIC.exe Alias /? >NUL 2>&1 || goto _WMIC_MISSING_

if not (%1)==() goto _help
SetLocal EnableDelayedExpansion

:: Use WMIC.exe to retrieve date and time
FOR /F "skip=1 tokens=1-6" %%G IN ('WMIC.exe Path Win32_LocalTime Get Day^,Hour^,Minute^,Month^,Second^,Year /Format:table') DO (
    IF "%%~L"=="" goto  _WMIC_done_
        set _yyyy=%%L
        set _mm=00%%J
        set _dd=00%%G
        set _hour=00%%H
        set _minute=00%%I
        set _second=00%%K
)
:_WMIC_done_

::   1    2     3       4      5      6
:: %%G  %%H    %%I     %%J    %%K    %%L
:: Day  Hour  Minute  Month  Second  Year
:: 27   9     35      4      38      2017

:: Remove excess leading zeroes
        set _mm=%_mm:~-2%
        set _dd=%_dd:~-2%
        set _hour=%_hour:~-2%
        set _minute=%_minute:~-2%
        set _second=%_second:~-2%
:: Syntax -> %variable:~num_chars_to_skip,num_chars_to_keep%

:: Set date/time in ISO 8601 format:
        Set _isotime=%_yyyy%-%_mm%-%_dd%T%_hour%:%_minute%:%_second%
:: -> http://google.com/search?num=100&q=ISO+8601+format

if 1%_hour% LSS 112 set _now=%_isotime:~0,10% %_hour%:%_minute%:%_second%am
if 1%_hour% LSS 112 goto _skip_12_
    set /a _hour=1%_hour%-12
    set _hour=%_hour:~-2%
    set _now=%_isotime:~0,10% %_hour%:%_minute%:%_second%pm
    :: -> https://ss64.com/nt/if.html
    :: -> http://google.com/search?num=100&q=SetLocal+EndLocal+Windows
    :: 'if () else ()' will NOT set %_now% correctly !?
:_skip_12_

EndLocal & set _isotime=%_isotime% & set _now=%_now%
goto _out

:_WMIC_MISSING_
echo.
echo WMIC.exe command not available
echo - WMIC.exe needs Administrator privileges to run in Windows
echo - Usually the path to WMIC.exe is "%windir%\System32\wbem\WMIC.exe"

:_help
echo.
echo GetDate.cmd: Uses WMIC.exe to get current date and time in ISO 8601 format
echo.
echo    %%_now%%     environment variable set to current date and time
echo    %%_isotime%% environment variable to current time in ISO format
echo    set _today=%%_isotime:~0,10%%
echo.

:_out
:: EOF: GetDate.cmd




batch-file