xml डुप्लिकेट तत्वों को निकालने के लिए XSLT को ट्रांसफ़ॉर्म करना आवश्यक है-किसी विशेषता द्वारा सॉर्ट किया गया I




xpath biztalk (5)

एक्सएसएलटी 1.0 के साथ इस समस्या का इष्टतम समाधान मुएंचियन समूह का उपयोग करना होगा। (यह देखते हुए कि तत्वों को पहले से ही मान्य फ़ॉर्मेट के द्वारा सॉर्ट किया गया है) निम्नलिखित स्टाइलशीट को चाल करना चाहिए:

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="xml" indent="yes"/>

  <xsl:key name="element-key" match="/SomeData/*" use="name()" />

  <xsl:template match="/SomeData">
    <xsl:copy>
      <xsl:for-each select="*[generate-id() = generate-id(key('element-key', name()))]">
        <xsl:copy-of select="(. | following-sibling::*[name() = name(current())])[last()]" />
      </xsl:for-each>
    </xsl:copy>
  </xsl:template>

</xsl:stylesheet>

अपने नमूना एक्सएमएल के विरुद्ध चलते हुए मुझे इसका परिणाम मिला है:

<?xml version="1.0" encoding="utf-8"?>
<SomeData>
  <A ValidFromDate="2012-01-19">A_2</A>
  <B ValidFromDate="2012-01-19">B_3</B>
  <C ValidFromDate="2011-01-20">C_2</C>
</SomeData>

मेरे पास XML का एक भयानक टुकड़ा है, जिसे मुझे बिज़्टेक के माध्यम से संसाधित करने की आवश्यकता है, और मैंने इसे नीचे इस उदाहरण में सामान्य करने में कामयाब रहा है मैं कोई XSLT निंजा नहीं हूं, लेकिन वेब और वीएस -2010 डीबगर के बीच, मैं एक्सएसएल के आसपास अपना रास्ता खोज सकता हूं।

अब मुझे डुप्लिकेट तत्वों को "weed out" करने के लिए XSLT के एक चतुर बिट की जरूरत है और केवल नवीनतम वाले को ही रखें, जैसा कि वैलडफ़ॉर्मडेट विशेषता में तिथि के अनुसार तय किया गया है।

ValidFromDate विशेषता XSD का है: तिथि प्रकार।

<SomeData>
  <A ValidFromDate="2011-12-01">A_1</A>
  <A ValidFromDate="2012-01-19">A_2</A>
  <B CalidFromDate="2011-12-03">B_1</B>
  <B ValidFromDate="2012-01-17">B_2</B>
  <B ValidFromDate="2012-01-19">B_3</B>
  <C ValidFromDate="2012-01-20">C_1</C>
  <C ValidFromDate="2011-01-20">C_2</C>
</SomeData>

परिवर्तन के बाद मैं केवल इन पंक्तियों को रखना चाहता हूं:

<SomeData>
  <A ValidFromDate="2012-01-19">A_2</A>
  <B ValidFromDate="2012-01-19">B_3</B>
  <C ValidFromDate="2012-01-20">C_1</C>
</SomeData>

किसी भी सुराग के रूप में मैं कैसे XSL को एक साथ रखा? मैंने एक समाधान ढूंढने की कोशिश कर इंटरनेट को खाली कर दिया है, और मैंने बहुत चालाक XSL सॉर्टिंग स्क्रिप्टों की कोशिश की है, लेकिन मुझे कोई भी महसूस नहीं हुआ कि मुझे सही दिशा में ले जाया गया।


@ValidFromDate आदेश के आधार पर:

XSLT:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="xml" indent="yes"/>

  <xsl:key name="k" match="*" use="name()"/>

  <xsl:template match="SomeData">
    <xsl:copy>
      <xsl:apply-templates select="*[generate-id() = 
                           generate-id(key('k', name()))]"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="*">
    <xsl:apply-templates select="key('k', name())" mode="a">
      <xsl:sort select="@ValidFromDate" order="descending"/>
    </xsl:apply-templates>
  </xsl:template>

  <xsl:template match="*" mode="a">
    <xsl:if test="position() = 1">
      <xsl:copy-of select="."/>
    </xsl:if>
  </xsl:template>

</xsl:stylesheet>

पर लागू:

<SomeData>
  <A ValidFromDate="2011-12-01">A_1</A>
  <A ValidFromDate="2012-01-19">A_2</A>
  <B CalidFromDate="2011-12-03">B_1</B>
  <B ValidFromDate="2012-01-17">B_2</B>
  <B ValidFromDate="2012-01-19">B_3</B>
  <C ValidFromDate="2012-01-20">C_1</C>
  <C ValidFromDate="2011-01-20">C_2</C>
</SomeData>

पैदा करता है:

<SomeData>
  <A ValidFromDate="2012-01-19">A_2</A>
  <B ValidFromDate="2012-01-19">B_3</B>
  <C ValidFromDate="2012-01-20">C_1</C>
</SomeData>

पावेल के उत्तर के आधार पर, मैंने निम्नलिखित संशोधन किया, जो उसी परिणाम का उत्पादन करता है:

<xsl:template match="/SomeData">
  <xsl:copy>
    <xsl:copy-of select="*[generate-id() = generate-id(key('element-key', name())[last()])]"/>
  </xsl:copy>
</xsl:template>

अगर वे हर बार एक ही परिणाम का उत्पादन करते हैं, मुझे यह पसंद है क्योंकि यह थोड़ा क्लीनर है


थोड़ा सा आसान और छोटा XSLT 1.0 समाधान @lwburk की तुलना में :

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:key name="kName" match="*/*" use="name()"/>

 <xsl:template match="/">
  <xsl:apply-templates select=
   "*/*[generate-id()
       =
        generate-id(key('kName', name())[1])
       ]
   "/>
 </xsl:template>

 <xsl:template match="*/*">
  <xsl:for-each select="key('kName', name())">
   <xsl:sort select="@ValidFromDate" order="descending"/>
   <xsl:if test="position() = 1">
    <xsl:copy-of select="."/>
   </xsl:if>
  </xsl:for-each>
 </xsl:template>
</xsl:stylesheet>

जब यह परिवर्तन प्रदान किए गए XML दस्तावेज़ पर लागू होता है :

<SomeData>
    <A ValidFromDate="2011-12-01">A_1</A>
    <A ValidFromDate="2012-01-19">A_2</A>
    <B CalidFromDate="2011-12-03">B_1</B>
    <B ValidFromDate="2012-01-17">B_2</B>
    <B ValidFromDate="2012-01-19">B_3</B>
    <C ValidFromDate="2012-01-20">C_1</C>
    <C ValidFromDate="2011-01-20">C_2</C>
</SomeData>

वांछित, सही परिणाम उत्पन्न होता है :

<A ValidFromDate="2012-01-19">A_2</A>
<B ValidFromDate="2012-01-19">B_3</B>
<C ValidFromDate="2012-01-20">C_1</C>

इनपुट ऑर्डर पर निर्भर किए बिना XLST 2.0 समाधान

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:xs="http://www.w3.org/2001/XMLSchema" xmlns:fn="http://www.w3.org/2005/xpath-functions">
    <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
    <xsl:template match="/">
        <SomeData>
            <xsl:for-each-group select="/SomeData/*" group-by="name()">
                    <xsl:for-each select="current-group()">
                        <xsl:sort select="number(substring(attribute(),1,4))" order="descending" data-type="number"/> <!-- year-->
                        <xsl:sort select="number(substring(attribute(),6,2))" order="descending" data-type="number"/> <!-- month-->
                        <xsl:sort select="number(substring(attribute(),9,2))" order="descending" data-type="number"/> <!-- date-->
                        <xsl:if test="position()=1">
                                <xsl:sequence select="."/>
                        </xsl:if>
                    </xsl:for-each>
            </xsl:for-each-group>
        </SomeData>
</xsl:template>
</xsl:stylesheet>




biztalk